Poner un CheckBox en un cuadro de diálogo

MessageDlg(const Msg: string;
           DlgType: TMsgDlgType;
           Buttons: TMsgDlgButtons;
           HelpCtx: Longint): Word;

function MDChecked(const Msg,                  { Mensaje a mostrar }
                   ChkMsg: string;             { Mensaje del CheckBox }
                   var checkedValue : boolean; { Valor del CheckBox }
                   DlgType: TMsgDlgType;       { Tipo del cuadro de diálogo }
                   Buttons: TMsgDlgButtons)    { Botones }
                   : Word;
var
  chk: TCheckBox;
  frm: TForm;
begin
  frm := CreateMessageDialog(Msg, DlgType, Buttons);
  with frm do
  try
    { añadimos el CheckBox en la parte inferior derecha }
    chk := TCheckBox.Create(frm);
    with chk do
    begin
      Checked := checkedValue;
      Caption := chkMsg;
      Left := 8;
      Top := frm.Height - Height - 12;
      Width := frm.width - left - 1;
      Parent := frm;
    end;
    { ampliamos la ventana }
    Height := Height + chk.Height;
    Position := poScreenCenter;
    { la mostramos }
    Result := ShowModal;
    { recuperamos valor del CheckBox }
    checkedValue := chk.Checked;
  finally
    Free;
  end;
end;

var
  chk : boolean; 
begin
...
  if ParametrosApp.MostrarMensaje then
  begin
    chk := false;
    MDChecked('Bla bla bla...', 'No mostrar más este mensaje', chk, mtInformation, [mbOK]);
    { según el valor devuelto del CheckBox, actualizamos parámetros }
    ParametrosApp.MostrarMensaje := not chk;
  end;