6 replies to this topic

[escafandra]

Hace tiempo que no publicaba cosillas y se me a ocurrido un sencillo truco que puede ser muy útil tanto para conocer la versión de nuestra propia aplicación como la de cualquiera otra simplemente conociendo el nombre del ejecutable.

Como en otras ocasiones voy a echar mano de la API de Windows:
GetFileVersionInfoSize
GetFileVersionInfo
VerQueryValue

Aquí un ejemplo de código:

delphi

uses
  Windows, ...;
 
type
TVersion = record
  major: DWORD;
  minor: DWORD;
  release: DWORD;
  build: DWORD;
end;
 
implementation
 
function GetVersion(FileName: String; var Version: TVersion): boolean;
var
  dwHandle: DWORD;
  verInfo: PVSFIXEDFILEINFO;
  Data: Pointer;
  verSize, dataSize: DWORD;
begin
  Result:= false;
  ZeroMemory(@Version, sizeof(TVersion));
  dwHandle:= 0;
  dataSize:= GetFileVersionInfoSize(PCHAR(FileName), dwHandle);
  GetMem(Data, dataSize);
  if GetFileVersionInfo(PCHAR(FileName), dwHandle, dataSize, Data) then
  begin
    if VerQueryValue(Data, '\', Pointer(verInfo), verSize) then
    begin
      if verSize > 0 then
      begin
        if verInfo.dwSignature = $FEEF04BD then
        begin
          Version.major:= verInfo.dwFileVersionMS shr 16;
          Version.minor:= verInfo.dwFileVersionMS and $FFFF;
          Version.release:= verInfo.dwFileVersionLS shr 16;
          Version.build:= verInfo.dwFileVersionLS and $FFFF;
          Result:= true;
        end;
      end;
    end;
  end;
  FreeMem(Data);
end;
 
function GetVersionString(FileName: String): String;
var
  Version: TVersion;
begin
  GetVersion(FileName, Version);
  Result:= Format('%d.%d.%d.%d', [Version.major, Version.minor, Version.release, Version.build]);
end;

Un ejemplo de uso para conocer la versión de nuestra propia App:

delphi

Label1.Caption:= GetVersionString(ParamStr(0));

Saludos.

[seoane]

Eso si utilizas el campo versión del ejecutable, yo por ejemplo tengo la mala costumbre de no hacerlo nunca en mis programas

PD: Me alegro de volver a leerte 

[escafandra]

Eso si utilizas el campo versión del ejecutable, yo por ejemplo tengo la mala costumbre de no hacerlo nunca en mis programas

Qué razón tienes. Yo en ocasiones hago lo mismo pero no se si es una buena costumbre salirse de los estándares. 

PD: Me alegro de volver a leerte 

Lo mismo digo. 


Saludos.

[poliburro]

Que buen truco amigo escafandra. Gracias por compartirlo.

[egostar]

PD: Me alegro de volver a leerte 

Lo mismo digo. 

¿ Tu también te alegras de leerte amigo escafandra ?

Un mal chiste

Yo me alegro de leerlos a los dos

Saludos

[egostar]

Eso si utilizas el campo versión del ejecutable, yo por ejemplo tengo la mala costumbre de no hacerlo nunca en mis programas

Qué razón tienes. Yo en ocasiones hago lo mismo pero no se si es una buena costumbre salirse de los estándares. 

Yo si suelo colocar la versión y demás yerbas, así como también tengo la costumbre de asignar CodeName's a mis desarrollos ante de sacarlos a la luz. 

Saludos

[escafandra]

Ahora le toca a la versión C del truco:

cpp

//---------------------------------------------------------------------------
typedef struct{
  DWORD major;
  DWORD minor;
  DWORD release;
  DWORD build;
} TVersion;
 
bool GetVersion(String FileName, TVersion *Version)
{
  bool Result = false;
  VS_FIXEDFILEINFO *verInfo = 0;
  DWORD dwHandle = 0;
  UINT verSize = 0;
  ZeroMemory(Version, sizeof(TVersion));
  int dataSize = GetFileVersionInfoSize(FileName.c_str(), &dwHandle);
  LPSTR Data = new char[dataSize];
 
  if(GetFileVersionInfo(FileName.c_str(), dwHandle, dataSize, Data)){
    if(VerQueryValue(Data, "\\", (VOID**)&verInfo, &verSize)){
      if(verSize){
        if(verInfo->dwSignature == 0xfeef04bd){
          Version->major = verInfo->dwFileVersionMS >> 16;
          Version->minor = verInfo->dwFileVersionMS & 0xFFFF;
          Version->release = verInfo->dwFileVersionLS >> 16;
          Version->build = verInfo->dwFileVersionLS & 0xFFFF;
          Result = true;
        }
      }
    }
  }
  delete [] Data;
  return Result;
}
 
String GetVersionString(String FileName)
{
  TVersion Version;
  GetVersion(FileName, &Version);
  return Format("%d.%d.%d.%d", ARRAYOFCONST(((int)Version.major, (int)Version.minor, (int)Version.release, (int)Version.build)));
}

Saludos.