7 replies to this topic

[escafandra]

Seguro que muchas veces nos ha fastidiado un S.O. Windows no profesional en el que hemos querido crear políticas para usuarios y no hemos podido por carecer de gpedit.msc.

El truco que os presento nace de la necesidad que he tenido de bloquear /desbloquear el uso de regedit para un usuario en un Windows no profesional. Muestra como crear una política al usuario activo capaz de negarle el uso de regedit o permitírselo. Sirve tanto en un Windows profesional como en la versión home. Está probado en winXP y Win8.

La forma que muestro de actuar es válida para otro tipo de políticas.

En el caso que describo, la clave del registro involucrada es: SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\system
Y el valor para el permiso es DisableRegistryTools  del tipo REG_DWORD y si vale 1, se restringe el uso del regedit.

Con el fin de crear rápidamente todas las claves y subclaves en el registro y poder reutilizar el código, he escrito una función general CreatePathKey

El resto del código muestra como escribir un determinado valor de una clave y como leerlo. En las funciones de manejo del registro no he usado funciones de la librería estándar de C ni de delphi, sólo API, con el fin de poder compilar mini aplicaciones basadas en el código. No uso unicode.

Como viene siendo costumbre en casi todo el código que publico, lo mostraré en C++ y delphi

Lo que sigue es una pequeña aplicación en C++ que tiene un CheckBox para permitir o no el uso de regedit por parte del usuario en curso:

cpp

//---------------------------------------------------------------------------
#include <vcl.h>
#pragma hdrstop
 
#include "Unit1.h"
#include <Shlwapi.h>
 
//---------------------------------------------------------------------------
#pragma package(smart_init)
#pragma resource "*.dfm"
TForm1 *Form1;
 
char* RegistryTools = TEXT("SOFTWARE\\Microsoft\\Windows\\CurrentVersion\\Policies\\system");
 
//---------------------------------------------------------------------------
// Crea una Clave y subclaves de una ruta dada de registro
void CreatePathKey(HKEY RootKey, char* PathKey)
{
  HKEY  hKey;
  DWORD lpdwDisposition;
  int l = lstrlen(PathKey);
  char* fin = PathKey;
  do{
    if(*fin == '\\' || !*fin){
      if(l>1) *fin = 0;
      if(RegOpenKeyEx(RootKey, PathKey, 0, KEY_CREATE_SUB_KEY, &hKey)){
        RegCreateKeyEx(RootKey, PathKey, 0, NULL, REG_OPTION_NON_VOLATILE, KEY_ALL_ACCESS,
                    0, &hKey, &lpdwDisposition);
        RegCloseKey(hKey);
      }
      if(l>1) *fin = '\\';
    }
    fin++;
  } while(l--);
}
 
void DisableRegistryTools(bool Val)
{
  HKEY  hKey;
  DWORD  Data;
  if(!RegOpenKeyEx(HKEY_CURRENT_USER, RegistryTools, 0, KEY_SET_VALUE , &hKey)){
    if(Val) Data = 1;
    else    Data = 0;
    RegSetValueEx(hKey, "DisableRegistryTools", 0, REG_DWORD, (BYTE*)&Data, sizeof(DWORD));
    RegCloseKey(hKey);
  }
}
 
DWORD ReadDisableRegistryTools()
{
  HKEY  hKey;
  DWORD Data = 0;
  DWORD lData = 4;
  if(!RegOpenKeyEx(HKEY_CURRENT_USER, RegistryTools, 0, KEY_READ , &hKey)){
    RegQueryValueEx(hKey, "DisableRegistryTools", 0, 0, (BYTE*)&Data, &lData);
    RegCloseKey(hKey);
  }
  return Data;
}
 
//---------------------------------------------------------------------------
__fastcall TForm1::TForm1(TComponent* Owner)
        : TForm(Owner)
{
  CreatePathKey(HKEY_CURRENT_USER, RegistryTools);
  CheckBox1->Checked = (0 == ReadDisableRegistryTools());
}
 
//---------------------------------------------------------------------------
void __fastcall TForm1::CheckBox1Click(TObject *Sender)
{
  DisableRegistryTools(!CheckBox1->Checked);
  CheckBox1->Checked = (0 == ReadDisableRegistryTools());
}
 
//---------------------------------------------------------------------------

PD: Edito para restaurar el archivo adjunto perdido.

Saludos.

Attached Files

•  RegistryTools.rar   156.82KB   0 downloads

[escafandra]

La misma aplicación escrita en C++ Builder, la expongo ahora en delphi7:

delphi

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;
 
type
  TForm1 = class(TForm)
    CheckBox1: TCheckBox;
    procedure CheckBox1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
const
  RegistryTools = 'SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\system';
 
// Crea una Clave y subclaves de una ruta dada de registro
procedure CreatePathKey(RootKey: HKEY; PathKey: PCHAR);
var
  hKey0: HKEY;
  lpdwDisposition: DWORD;
  SubKey: PCHAR;
  fin, l: integer;
begin
  l:= lstrlen(PathKey);
  SubKey:= VirtualAlloc(0, l+1, MEM_COMMIT, PAGE_READWRITE);
  lstrcpy(SubKey, PathKey);
  fin:= 0;
  repeat
    if (SubKey[fin] = '\') or (SubKey[fin] = #0) then
    begin
      if l > 1 then SubKey[fin]:= #0;
      if RegOpenKeyEx(RootKey, SubKey, 0, KEY_CREATE_SUB_KEY, hKey0)<>ERROR_SUCCESS then
      begin
        RegCreateKeyEx(RootKey, SubKey, 0, nil, REG_OPTION_NON_VOLATILE, KEY_ALL_ACCESS,
                    0, hKey0, @lpdwDisposition);
        RegCloseKey(hKey0);
      end;
    if l > 1 then SubKey[fin]:= '\';
    end;
    inc(fin); dec(l);
  until (l<0);
  VirtualFree(SubKey, 0, MEM_RELEASE);
end;
 
function ReadDisableRegistryTools: DWORD;
var
  hKey0: HKEY;
  lResult: DWORD;
begin
  lResult:= 4;
  Result:= 0;
  if RegOpenKeyEx(HKEY_CURRENT_USER, RegistryTools, 0, KEY_READ, hKey0) = ERROR_SUCCESS then
  begin
    RegQueryValueEx(hKey0, 'DisableRegistryTools', 0, nil, @Result, @lResult);
    RegCloseKey(hKey0);
  end;
end;
 
procedure DisableRegistryTools(Val: boolean);
var
  hKey0: HKEY;
  Data:  DWORD;
begin
  if RegOpenKeyEx(HKEY_CURRENT_USER, RegistryTools, 0, KEY_SET_VALUE, hKey0) = ERROR_SUCCESS then
  begin
    if Val then Data:= 1
    else Data:= 0;
    RegSetValueEx(hKey0, 'DisableRegistryTools', 0, REG_DWORD, @Data, sizeof(DWORD));
    RegCloseKey(hKey0);
  end;
end;
 
 
procedure TForm1.CheckBox1Click(Sender: TObject);
begin
  DisableRegistryTools(not CheckBox1.Checked);
  CheckBox1.Checked:= ReadDisableRegistryTools = 0;
end;
 
procedure TForm1.FormCreate(Sender: TObject);
begin
  CreatePathKey(HKEY_CURRENT_USER, RegistryTools);
  CheckBox1.Checked:= ReadDisableRegistryTools = 0;
end;
 
end.

PD: Edito para restaurar el archivo adjunto perdido.

Saludos.

Attached Files

•  RegistryTools.rar   157.42KB   0 downloads

[ELKurgan]

Una vez más me descubro ante tu sabiduría. 

Muchas gracias por el aporte, maestro.

[poliburro]

Excelente truco, gracias por compartirlo amigo.

[egostar]

Interesante la solución

Aunque a mi me da cierto recelo mover algo al Registro de Windows 

Saludos

[cram]

Interesante Escafandra. Como ando en otras cosas bajé el RAR para analizarlo mejor después.
Hace tiempo tuve un lío con el tema de solicitar permisos y todo lo que sea registro en algún momento es útil.
Muchas gracias 

Saludos.

[escafandra]

Interesante la solución

Aunque a mi me da cierto recelo mover algo al Registro de Windows 

Saludos

Al fin y al cabo es donde se escriben, en este caso, esos permisos. Si escribes donde debes, no hay el más mínimo problema. A mi no me da el más mínimo reparo y me resuelve muchos problemas de todo tipo. 

Saludos.

[Delphius]

Se agradece el truco amigo. 

Interesante la solución

Aunque a mi me da cierto recelo mover algo al Registro de Windows 

Saludos

Más peligroso es borrar o modificar una entrada del Registro. 

Saludos,