27 respuestas en este tema

[monchito_elroro]

buenas amigos, yo de nuevo aquí para pedirles una mano, como puedo hacer para saber cuando el mouse toque los lados de la pantalla, es decir cuando toque el borde superior o cualquiera de los lados de la pantalla me avise.

 

Desde ya gracias por sus ayudas

[Nikolas]

para un formulario:

php

procedure TForm1.FormMouseEnter(Sender: TObject);
begin
  showmessage('ENTRE AL FORM');
end;

[monchito_elroro]

Gracias amigo Nikolas, esta interesante...

[monchito_elroro]

He estado investigando y parece ser que tengo que usar las coordenadas del mouse ... alguna sugerencia

[cram]

Deberás capturar la posición del ratón para los límites del contexto de dispositivo 0 (o sea la pantalla). Esto pudo haber cambiado, la verdad es que hace mucho no veo este tipo de información.

Además deberás tener en cuenta que no estés en un ambiente con pantallas múltiples, ya que el puntero se pasará a otra pantalla.

 

En Delphi mediante Vcl.Forms.TScreen podrás acceder al mouse a un nivel global.

En Lazarus también existe un componente TScreen, deberías averiguar como funciona.

 

Creo que por ahí anda la solución

 

Saludos

[monchito_elroro]

Gracias "cram" por tu información , de momento he tenido un pequeño avanze con el evento "OnMoveMouse" del FORM1.

Este es el código que uso:

php

procedure TForm1.FormMouseMove(Sender: TObject; Shift: TShiftState; X,
  Y: Integer);
begin
   Label1.Caption := IntToStr(x) + ' ' + IntToStr(y);  // funciona
end;

.

Pero como podría seguir el movimiento del mouse Globalmente y no solo dentro del Form1.  :mellow: :mellow:

[cram]

Hace mucho tuve ese problema y como es extraño, no recuerdo exactamente como es, para pasarte un código claro.

Lo que puedo hacer es darte una guía.

Hay que capturar al ratón (ya que es un recurso compartido por todas las aplicaciones que están en ejecución incluso explorer (Windows).

 

El siguiente enlace explica muy bien el correcto uso de SetCapture y ReleaseCapture para permitirte comenzar una solución, además deberás usar las funciones de conversión de coordenadas ScreenToiClient o alguna otra parecida.

 

http://www.codeproje...-correctly-usua

 

Espero te sirva,

Saludos

[monchito_elroro]

Gracias amigo "Cram" lo revisaré.

[escafandra]

Si tu entorno de trabajo es Windows, revisa la API GetCursorPos

 

 

Saludos.

[monchito_elroro]

he encontrado un pequeño ejemplo con la api mencionada por el amigo Escafandra, es un pequeño salto para un newbie como yo, pero un gran salto para la humanidad

Este es el código:

php

uses
…, windows;
 
-------------
procedure TForm1.Button1Click(Sender: TObject);
var
posiciondelcuy: TPoint;
begin
  GetCursorPos(posiciondelcuy);
  label1.Caption := IntToStr(posiciondelcuy.x);
  label2.Caption := IntToStr(posiciondelcuy.y);
end;

.

 

Queda mejor en el Evento "OnMouseMove" del form1, pero como lo puedo hacer global, no solo para el form sino para toda la pantalla.

Espero sus sugerencias y apoyo   saludos.

[escafandra]

La API GetCursorPos te devuelve las coordenadas absolutas, no del Form.

Revisa la traducción a delphi que hice de WinInfo, allí muestro como usarla.

Saludos.

[monchito_elroro]

Tiene razón amigo escafranda, pero como puedo hacer para capturarlas esas coodenadas y mostrarlas en un Label, la única manera que se me ocurrió era con el evento "OnMouseMove".

[escafandra]

Esa es una buena opción. Depende de tus necesidades. Siempre puedes capturarlas usando la API en cualquier momento, depende de lo que necesites.


Saludos.

[monchito_elroro]

Lo que quisiera realizar es poder mostrar las coordenadas siempre, moviendo en cualquier posición el mouse y mostrar en un Label las coordenadas obtenidas en pleno movimiento, utilizando el evento "OnMouseMove" del form puedo realizarlo pero si retiro el mouse del form entonces se detiene el seguimiento de las coordenadas. :unsure:

[escafandra]

Revisa esto. Hoy es tarde para mi, mañana te muestro como hacer un Hook al ratón.


Saludos.

[monchito_elroro]

ok lo haré

[escafandra]

Te pongo un ejemplo con un Hook al ratón que hace lo que pretendes, pone las coordenadas en un label:

delphi

var
  Form1: TForm1;
  hMouseHook: HHOOK;
 
implementation
 
{$R *.dfm}
 
function MouseEvent(nCode, wParam, lParam: Integer): Integer; stdcall;
var
  Point:  TPoint;
begin
  if nCode>=0 then
  begin
    GetCursorPos(Point);
    Form1.Label1.Caption:= '(' + IntToStr(Point.X) + ', ' + IntToStr(Point.Y) + ')';
  end;
  Result:= CallNextHookEx(hMouseHook, nCode, wParam, lParam);
end;
 
procedure TForm1.FormCreate(Sender: TObject);
begin
  // Ponemos en marcha el Hook
  hMouseHook:= SetWindowsHookEx(WH_MOUSE_LL, @MouseEvent, HInstance, 0);
end;
 
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  // Paramos el Hook
  UnhookWindowsHookEx(hMouseHook);
end;
 
end.

Saludos.

[monchito_elroro]

Muchisimas gracias amigo escafandra, eres un maestro me funciona perfecto.

 

Le comento que al probarlo tuve dos inconvenientes pero pude solucionarlos de la siguiente manera:

 

1. La primer prueba me salió este error:   
unit1.pas(30,15) Error: Identifier not found "HHOOK"

Solución: le agregue el uses "windows"

 

2. Ya con el uses "windows" ahora me salió este error:

unit1.pas(59,33) Error: Identifier not found "WH_MOUSE_LL"

Solución: Investigando en la web, agregué este código para solucionarlo:

php

Uses
 . . . .  Windows;
 
const
//WH_KEYBOARD_LL =13;
WH_MOUSE_LL =14;
 
type
......

Agrego el código completo:

php

unit Unit1;
 
{$mode objfpc}{$H+}
 
interface
 
uses
  windows, Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls;    // agregue el uses "windows"
 
const
//WH_KEYBOARD_LL =13;
WH_MOUSE_LL =14;  // lo agregué para que funcione
 
type
 
  { TForm1 }
 
  TForm1 = class(TForm)
    Label1: TLabel;
    procedure FormClose(Sender: TObject; var CloseAction: TCloseAction);
    procedure FormCreate(Sender: TObject);
  private
    { private declarations }
  public
    { public declarations }
  end;
 
var
  Form1: TForm1;
  hMouseHook: HHOOK;
 
implementation
 
{$R *.lfm}
 
{ TForm1 }
 
function MouseEvent(nCode, wParam, lParam: Integer): Integer; stdcall;
var
  Point:  TPoint;
begin
  if nCode>=0 then
  begin
    GetCursorPos(Point);
    Form1.Label1.Caption:= '(' + IntToStr(Point.X) + ', ' + IntToStr(Point.Y) + ')';
  end;
  Result:= CallNextHookEx(hMouseHook, nCode, wParam, lParam);
end;
 
procedure TForm1.FormClose(Sender: TObject; var CloseAction: TCloseAction);
begin
    // Paramos el Hook
  UnhookWindowsHookEx(hMouseHook);
end;
 
procedure TForm1.FormCreate(Sender: TObject);
begin
   // Ponemos en marcha el Hook
  hMouseHook:= SetWindowsHookEx(WH_MOUSE_LL, @MouseEvent, HInstance, 0);
end;
 
end.

.

Ahora si me funciona.

Amigo Escafandra usted cree que esta bien estos códigos que he agregado, por favor corrijame de ser necesario.

 

 

 

 

 

 

 

 

 

 

 

 

 

[escafandra]

Es así. Olvide que estabas con Lazarus, lógicamente debes añadir uses Windows. El valor de WH_MOUSE_LL es 14.

Saludos.

[monchito_elroro]

Muy bueno días con todos en este día hermoso

Les comento en especial al amigo Escafandra que  he agregado unos códigos al suyo para poder realizar lo que buscaba, poder saber cuando el mouse toca los lados de la pantalla.

 

Les comparto el código:

php

unit Unit1;
 
{$mode objfpc}{$H+}
 
interface
 
uses
  windows, Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls;
 
const
//WH_KEYBOARD_LL =13;
WH_MOUSE_LL =14;
 
type
 
  { TForm1 }
 
  TForm1 = class(TForm)
    GroupBox1: TGroupBox;
    GroupBox2: TGroupBox;
    Label1: TLabel;
    Label2: TLabel;
    Label3: TLabel;
    Label4: TLabel;
    Label5: TLabel;
    Label6: TLabel;
    procedure FormClose(Sender: TObject; var CloseAction: TCloseAction);
    procedure FormCreate(Sender: TObject);
  private
    { private declarations }
  public
    { public declarations }
  end;
 
var
  Form1: TForm1;
  hMouseHook: HHOOK;
 
implementation
 
{$R *.lfm}
 
{ TForm1 }
 
function MouseEvent(nCode, wParam, lParam: Integer): Integer; stdcall;
var
  Point:  TPoint;
begin
  if nCode>=0 then
  begin
    GetCursorPos(Point);
    Form1.Label1.Caption:= '(Horizontal X:  ' + IntToStr(Point.X) + ', Vertical Y:  ' + IntToStr(Point.Y) + ')';
 
       //if Point.Y=0 then ShowMessage('pegado arriba') else form1.Label3.Caption:='normal';  // el ShowMessage cuelga el form
 
       if Point.Y=0 then form1.Label3.Caption:='pegado arriba' else form1.Label3.Caption:='normal';
       if Point.X=0 then form1.Label4.Caption:='pegado izquierda' else form1.Label4.Caption:='normal';
       if Point.X=screen.Width-1 then form1.Label5.Caption:='pegado derecha' else form1.Label5.Caption:='normal';
       if Point.Y=screen.height-1 then form1.Label6.Caption:='pegado abajo' else form1.Label6.Caption:='normal';
 
  end;
  Result:= CallNextHookEx(hMouseHook, nCode, wParam, lParam);
end;
 
procedure TForm1.FormClose(Sender: TObject; var CloseAction: TCloseAction);
begin
    // Paramos el Hook
  UnhookWindowsHookEx(hMouseHook);
end;
 
procedure TForm1.FormCreate(Sender: TObject);
begin
   form1.Label2.Caption:='El Ancho es:  '+inttostr(Screen.Width)+' El alto es:  '+inttostr(Screen.Height)+' Y el Pixel es:  '+inttostr(Screen.PixelsPerInch);  // Obtener las dimensiones de la pantalla
 
   // Ponemos en marcha el Hook
  hMouseHook:= SetWindowsHookEx(WH_MOUSE_LL, @MouseEvent, HInstance, 0);
end;
 
end.

.

Me funciona muy bien, pero me quedan unas dudas:

 

* Porque cuando utilizo un showmessage se queda como colgado el programita.

* Porque cuando el mouse toca el borde derecho o abajo el valor es el total-1 (es decir si el total es 1500, el mouse marca 1499).

* Como haría para saber cuando tocas las esquinas de la pantalla.

 

Desde ya gracias por su ayuda y me gustaría recibir sus comentarios y correcciones.