9 respuestas en este tema

[armadillo]

Hola Amig@s,

Hace mucho tiempo que no ando por aqui, ya que hace mucho tiempo que no programo... pero ya estoy volviendo a las andadas, y por supuesto con dudas.

He empezado hacer algunos pinitos en Lazarus y estoy realmente bastante satisfecho, con el resultado y el proyecto Lazarus.

Bien vamos al grano, seguro es una tonteria pero estoy fuera de training y no se por donde agarrarlo.

 

El ejemplo es el siguiente:

delphi

...
// aqui es donde la declaro
  public
    { public declarations }
    function TipoTelefono(var NroTel: String): String; // <-- Aqui me da el error
...
 
implementation
 
// Esta es la funcion en cuestion
function TipoTelefono(var NroTel: String): String;
begin
    if (NroTel[1]='8') or (NroTel[1]='9') then Result:='FIJO'
    else if (NroTel[1]='6') or (NroTel[1]='7') then Result:='MOVIL'
end;                  
 
// Y aqui es donde la uso
procedure TForm1.Button1Click(Sender: TObject);
var
  LineasArchivo, Campos: TStringList;
  Tip_Tel, Segundos, LineaReg: String;
  i,x: Integer;
begin
  Campos:=TStringList.Create;
  LineasArchivo:=TStringList.Create;
  Label1.Caption:='Iniciamos el proceso de Carga...';
  OpenDialog1.Execute;
  // Cargamos el archivo para procesar
  LineasArchivo.LoadFromFile(OpenDialog1.FileName);
  // Empezamos a procesar el Archivo
  for i:=1 to LineasArchivo.Count-1 do
      Begin
        LineaReg:=LineasArchivo[i]; 
        Campos.DelimitedText:=LineaReg;  // Creamos el arreglo Campos 
        Tip_Tel:=Campos[3];
        Campos.Add(TipoTelefono(Tip_Tel)); // Aqui la uso y me da el errror
        ...
        ...
        // Añado registros a MySQL con el arreglo Campos
      end;
end;

En realidad el error me lo da en la compilacion del mismo en la parte de la declaracion de la funcion y este:

 

principal.pas(30,14) Error: Forward declaration not solved "TipoTelefono(var AnsiString):AnsiString;"

 

Pues si alguien sabe decirme que hacer os lo agradeceria

[Delphius]

Ummm... habría que ver el código completo y exacto. El primer error que aprecio es que hay un public y esto me hace pensar en que hay una declaración de una clase.

Has definido una función y por tu muestra del código, está dentro de la clase, por tanto se trataría de un método para la clase.

De ser correcto, tal implementación debiera ser:

delphi

function NombreDeLaClase.TipoTelefono(var NroTel: string): string;
 
begin
 
// el código aquí
 
end;

El otro error que aprecio es que el tipo de dato que definiste para el parámetro de la función TipoTelefono es del tipo string, pero al momento de usarla, al pasarle el valor al parámetro le estás dando un tipo char. Es decir

 

tipo_tel := Campos[3];

 

Regresa un carácter. O para más simple: un char.

 

Entonces el parámetro para la función debiera ser justamente de ese tipo y no un string. Al ser char, éste solamente cuenta con un carácter por tanto no hace es posible hacer un tipo_tel[].

 

En resumen. La solución es:

delphi

function TipoTelefono(Tipo: char): string;
 
begin
 
if Tipo = '8' ...
 
end;

Saludos,

[Agustin Ortu]

Tal y como te dice Delphius, te tiene que quedar asi:
 

delphi

implementation
 
function TipoTelefono(var NroTel: String): String;
begin
 
end;
 
function TForm1.TipoTelefono(var NroTel: String): String;
begin
 
end;

Tenes que referencia a la clase que implementa al metodo

[Delphius]

Tal y como te dice Delphius, te tiene que quedar asi:
 

delphi

implementation
 
function TipoTelefono(var NroTel: String): String;
begin
 
end;
 
function TForm1.TipoTelefono(var NroTel: String): String;
begin
 
end;

Tenes que referencia a la clase que implementa al metodo

 

Y Cambiar el tipo del parámetro a char

Aunque no se si realmente ese public que vemos corresponde al Form1. El código de muestra está recortado. Asi que puede ser Form1, TClaseTelefono, lo que sea...

 

Saludos,

[armadillo]

Hola Delphius y OrtuAgustin,

Antes de nada gracias por vuestras prontas respuestas,

Bueno la solucion fue lo que habeis dicho, el añadir el nombre del form en la implementación de la función, y listo todo quedo ok.

Yo creía que era un error de tipos de variables, cosa que me extrañaba ya que las dos estaban declaradas como String.

La variable Campo es una arreglo de string, por eso la usaba como Campo[1] o campo[3]...

 

Bien desde ya muchas gracias a los dos

Un Saludo

[Agustin Ortu]

Siempre me mando la misma cagada y respondo en el sub foro de lazarus creyendo que estoy en delphi
 
En mi caso con dephi 2010 este codigo me funciona perfecto:

delphi

type
  TForm1 = class(TForm)
    Edit1: TEdit;
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
    function TipoTelefono(const NroTel: string): string;
  public
    { Public declarations }
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
procedure TForm1.Button1Click(Sender: TObject);
begin
  ShowMessage(TipoTelefono(Edit1.Text));
  ShowMessage(TipoTelefono(Edit1.Text[1]));
end;
 
function TForm1.TipoTelefono(const NroTel: string): string;
begin
  if (NroTel[1] = '8') or (NroTel[1] = '9') then
    Result := 'FIJO'
  else if (NroTel[1] = '6') or (NroTel[1] = '7') then
    Result := 'MOVIL'
end;

Lo del TForm1 fue porque abajo le vi el ButtonClick que pertenecia a ese form, por eso me la juge pero obviamente podria ser cualquier cosa

 

Otro dato interesante es que si en ves de poner la declaracion de la funcion dentro del cuerpo de la clase TForm1 se hace fuera, entonces en ese caso se puede implementar la funcion sin que pertenezca "a nadie"

delphi

type
  TForm1 = class(TForm)
    Edit1: TEdit;
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
      public
    { Public declarations }
  end;
 
function TipoTelefono(const NroTel: string): string;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
procedure TForm1.Button1Click(Sender: TObject);
begin
  ShowMessage(TipoTelefono(Edit1.Text));
end;
 
function TipoTelefono(const NroTel: string): string;
begin
  if (NroTel[1] = '8') or (NroTel[1] = '9') then
    Result := 'FIJO'
  else if (NroTel[1] = '6') or (NroTel[1] = '7') then
    Result := 'MOVIL'
end;

[egostar]

Hola

 

Yo modificaría la función TipoTelefono() de ésta forma:

 

php

function TForm1.TipoTelefono(const NroTel: string): string;
begin
  case NroTel[1] of
    '8','9': Result := 'FIJO';
    '6','7': Result := 'MOVIL';
    else Result := '';
  end;
end;

 

 

Saludos 

 

 

[Delphius]

Yo cambiaría el tipo del parámetro NroTel por Char

 

Saludos,

[egostar]

Yo cambiaría el tipo del parámetro NroTel por Char
 
Saludos,

 
Sería exactamente lo mismo porque en la llamada tendrías que hacer esto: 
 

delphi

ShowMessage( TipoTelefono( Edit1.Text[1] ) );

Saludos

[Delphius]

Parece ser lo mismo, pero la cuestión es: ¿Para que pasar como parámetro todo el string si al final se necesita de un carácter? Tiene sentido pasar todo el string si se va a utilizar para algo más, dentro de la función. Además tampoco cuesta demasiado el poner cadena[1].

 

Saludos,