5 replies to this topic

[agag4]

Buen dia compañeros, tengo un pequeño problema de hace varios años atras con windows 7, resulta que a veces se bloquean mis aplicaciones al ejecutar, al darle varios clicks sobre el icono se va a Procesos de windows, y si abre el Administrador de Tareas en la pestaña PROCESOS, aparece varias veces mi aplicación, se tiene que finalizar a cada una, apenas asi vuelve a entrar, esto pasa a lo largo no es comun, habia pensado en hacer que al cargar el programa tomar el handle de la aplicación y hace un barrido de las aplicaciones ejecutadas y finalizar si se encuentra mas de una vez sin afectar a la nueva por el handle, no se si me explique ??

 

Espero sus sugerencias..

 

gracias.

[Marc]

Te recomiendo que compiles tu aplicación con MadExcept. La parte de gestión de errores es gratuita.

 

http://madshi.net/ma...Description.htm

 

Este gestor de errores puede detectar que tu aplicación se queda bloqueada (no responde durante más de N segundos) y generar un informe para que sepas donde se ha creado el problema, así como cerrar automáticamente la aplicación, o reiniciarla.

 

Saludos.

[enecumene]

Mientras revisas la propuesta de Marc, puedes ir intentando con ésto:
 
 

delphi

function KillTask(ExeFileName: string): Integer; 
const 
  PROCESS_TERMINATE = $0001; 
var 
  ContinueLoop: BOOL; 
  FSnapshotHandle: THandle; 
  FProcessEntry32: TProcessEntry32; 
begin 
  Result := 0; 
  FSnapshotHandle := CreateToolhelp32Snapshot(TH32CS_SNAPPROCESS, 0); 
  FProcessEntry32.dwSize := SizeOf(FProcessEntry32); 
  ContinueLoop := Process32First(FSnapshotHandle, FProcessEntry32); 
  while Integer(ContinueLoop) <> 0 do 
  begin 
    if ((UpperCase(ExtractFileName(FProcessEntry32.szExeFile)) = 
      UpperCase(ExeFileName)) or (UpperCase(FProcessEntry32.szExeFile) = 
      UpperCase(ExeFileName))) then 
      Result := Integer(TerminateProcess( 
                        OpenProcess(PROCESS_TERMINATE, 
                                    BOOL(0), 
                                    FProcessEntry32.th32ProcessID), 
                                    0)); 
     ContinueLoop := Process32Next(FSnapshotHandle, FProcessEntry32); 
  end; 
  CloseHandle(FSnapshotHandle); 
end;

Su uso sería:

delphi

procedure TForm1.Button1Click(Sender: TObject); 
begin 
  KillTask('notepad.exe'); 
end;

[agag4]

Muchas gracias compañeros, voy a probar lo que me sugieren los mantengo informados...

 

Saludos.

[escafandra]

Si lo que quieres es matar todos los procesos con un determinado nombre menos la actual, que es lo que entiendo y asegurar el tiro, debes identificar el PID de la aplicación matadora para no suidicarse, además deberías darte privilegios debug:
 

delphi

//uses  TLHelp32;
 
function EnablePrivilege(name: String; Enable: boolean = true): boolean;
var
  hToken: Cardinal;
  priv: TOKEN_PRIVILEGES;
begin
  priv.PrivilegeCount:= 1;
  priv.Privileges[0].Attributes:= 0;
  if Enable then priv.Privileges[0].Attributes:= SE_PRIVILEGE_ENABLED;
  LookupPrivilegeValue(nil, PCHAR(name), priv.Privileges[0].Luid);
  OpenProcessToken(GetCurrentProcess, TOKEN_ADJUST_PRIVILEGES, hToken);
  AdjustTokenPrivileges (hToken, FALSE, priv, sizeof(priv), nil, PDWORD(nil)^);
  Result:= (GetLastError = ERROR_SUCCESS);
  CloseHandle (hToken);
end;
 
procedure KillProcess(FileName: String);
var
  Process, hSysSnapshot: THandle;
  PE: TPROCESSENTRY32;
begin
  EnablePrivilege('SeDebugPrivilege');
  PE.dwSize:= sizeof(TPROCESSENTRY32);
  hSysSnapshot:= CreateToolhelp32Snapshot(TH32CS_SNAPPROCESS, 0);
  if (hSysSnapshot <> INVALID_HANDLE_VALUE) and Process32First(hSysSnapshot, PE) then
    repeat
      if (lstrcmpi(PE.szExeFile, PAnsiChar(FileName)) = 0) and (GetCurrentProcessID <> PE.th32ProcessID) then
      begin
        Process:= OpenProcess(PROCESS_TERMINATE, false, PE.th32ProcessID);
        if Process <> 0 then
        begin
          TerminateProcess(Process, 0);
          CloseHandle(process);
        end;
      end;
    until not Process32Next(hSysSnapshot, PE);
  CloseHandle(hSysSnapshot);
  EnablePrivilege('SeDebugPrivilege', false);
end;

Ese código lo puedes colocar en el evento OnCreate o mejor aún, antes de crear ningún formulario:

delphi

program Project1;
uses
  Forms,
  Unit1 in 'Unit1.pas' {Form1};
 
{$R *.res}
 
begin
  KillProcess('Project1.exe');  // Matas a todos menos a ti mismo...
 
  Application.Initialize;
  Application.CreateForm(TForm1, Form1);
  Application.Run;
end.

Saludos.

[agag4]

muchas gracias compañero, ya estoy haciendo pruebas, te aviso que paso...

 

saludos.