12 replies to this topic

[escafandra]

He estado jugando un poco con las interfaces y conexiones wifi y el resultado es una pequeña aplicación que muestra las redes wifi disponibles y nos conecta a una si tenemos configurada su autentificación.
 
La base del ejercicio es la API  Native Wifi Functions. En delphi 7 habrá que definir unas cuantas estructuras tomadas de la documentación de M$ y adaptadas para simplificar las cosas, no se si en las últimas versiones de delphi están incluidas estas definiciones.
 
El programita hace una lista de las redes disponibles escaneando los adaptadores wifi presentes en el PC, luego, conociendo el nombre de la Wifi a conectarnos, nos conecta. He incluido una desconexión rápida de todos los adaptadores.
 
El corazón del código es este:

delphi

type
  TWifiData = record
    InterfaceInfo: String;
    Profile: String;
    SSID: String;
    Signal: integer;
    Auth: String;
    Conected: BOOL;
  end;
 
 
function WifiScan(var List: array of TWifiData): integer;
const
  AuthStr: array [1..9]of String = ('Open','Shared Key','WPA','WPA-PSK','WPA NONE','RSNA','RSNA-PSK','IHV Start','IHV End');
var
  hClient: THandle;
  dwVersion: DWORD;
  pInterfaceInfoList: PWLAN_INTERFACE_INFO_LIST;
  pInterfaceGuid: PGUID;
  pNetworkList: PWLAN_AVAILABLE_NETWORK_LIST;
  i, j: integer;
begin
  Result:= 0;
  if ERROR_SUCCESS = WlanOpenHandle(1, nil, @dwVersion, @hClient) then
  begin
    if ERROR_SUCCESS = WlanEnumInterfaces(hClient, nil, @pInterfaceInfoList) then
    begin
      for i := 0 to pInterfaceInfoList^.dwNumberOfItems - 1 do
      begin
        pInterfaceGuid:= @pInterfaceInfoList^.InterfaceInfo[pInterfaceInfoList^.dwIndex].InterfaceGuid;
        if ERROR_SUCCESS = WlanGetAvailableNetworkList(hClient, pInterfaceGuid, 1, nil, pNetworkList) then
        begin
          for j := 0 to pNetworkList^.dwNumberOfItems - 1 do
          begin
            Result:= pNetworkList^.dwNumberOfItems;
            with List[j] do
            begin
              InterfaceInfo:= pInterfaceInfoList^.InterfaceInfo[0].strInterfaceDescription;
              Profile:= WideCharToString(pNetworkList^.Network[j].strProfileName);
              SSID:= PChar(@pNetworkList^.Network[j].dot11Ssid.ucSSID);
              Signal:= pNetworkList^.Network[j].wlanSignalQuality;
              Auth:= AuthStr[pNetworkList^.Network[j].dot11DefaultAuthAlgorithm];
              Conected:= (pNetworkList^.Network[j].dwFlags and WLAN_AVAILABLE_NETWORK_CONNECTED) <> 0;
            end;
          end;
          WlanFreeMemory(pNetworkList);
        end;
      end;
      WlanFreeMemory(pInterfaceInfoList);
    end;
    WlanCloseHandle(hClient, nil);
  end;
end;
 
function WifiConect(SSID: WideString): BOOL;
var
  hClient: THandle;
  dwVersion: DWORD;
  pInterfaceInfoList: PWLAN_INTERFACE_INFO_LIST;
  pInterfaceGuid: PGUID;
  i: integer;
  pWLCP: PWLAN_CONNECTION_PARAMETERS;
begin
  Result:= false;
  if ERROR_SUCCESS = WlanOpenHandle(1, nil, @dwVersion, @hClient) then
  begin
    if ERROR_SUCCESS = WlanEnumInterfaces(hClient, nil, @pInterfaceInfoList) then
    begin
      for i:= 0 to pInterfaceInfoList^.dwNumberOfItems - 1 do
      begin
        pInterfaceGuid:= @pInterfaceInfoList^.InterfaceInfo[pInterfaceInfoList^.dwIndex].InterfaceGuid;
        pWLCP:= WlanAllocateMemory(sizeof(TWLAN_CONNECTION_PARAMETERS));
        pWLCP.strProfile:= PWCHAR(SSID);
        pWLCP.wlanConnectionMode:= 0;
        pWLCP.pDot11Ssid:= nil; //pDot11_DDSI;
        pWLCP.pDesiredBssidList:= nil;
        pWLCP.dot11BssType:= 1;
        pWLCP.dwFlags:= 0;//$F;
        Result:= (ERROR_SUCCESS = WlanConnect(hClient, pInterfaceGuid, pWLCP, nil));
        WlanFreeMemory(pWLCP);
      end;
      WlanFreeMemory(pInterfaceInfoList);
    end;
    WlanCloseHandle(hClient, nil);
  end;
end;
 
function WifiDisConect: BOOL;
var
  hClient: THandle;
  dwVersion: DWORD;
  pInterfaceInfoList: PWLAN_INTERFACE_INFO_LIST;
  pInterfaceGuid: PGUID;
  i: integer;
begin
  Result:= false;
  if ERROR_SUCCESS = WlanOpenHandle(1, nil, @dwVersion, @hClient) then
  begin
    if ERROR_SUCCESS = WlanEnumInterfaces(hClient, nil, @pInterfaceInfoList) then
    begin
      for i:= 0 to pInterfaceInfoList^.dwNumberOfItems - 1 do
      begin
        pInterfaceGuid:= @pInterfaceInfoList^.InterfaceInfo[pInterfaceInfoList^.dwIndex].InterfaceGuid;
        WlanDisconnect(hClient, pInterfaceGuid, nil);
      end;
      WlanFreeMemory(pInterfaceInfoList);
    end;
    WlanCloseHandle(hClient, nil);
  end;
end;

Subo el código.


Saludos.


PD/ Existe una actualización aquí.

Attached Files

•  WiffiConnect.rar   163.19KB   54 downloads

[cram]

Me sorprende ...

La verdad que hace mucho tiempo se me ocurría explorar ciertas áreas de la programación. Ahora estoy "enfrascado" en trabajo y no investigo nada.

Muchas gracias amigo Escafandra.

 

Saludos

[Wilson]

Gracias maestro, como siempre excelente. 

[enecumene]

Excelente!! 

[luk2009]

Gracias por ser una fuente inagotable de aportes

Enviado desde mi D5803 mediante Tapatalk

[poliburro]

Como plus valdría la pena que se validará la seguridad de la red.

[escafandra]

Como plus valdría la pena que se validará la seguridad de la red.

 

Si, y algunas otras cosas como registrar notificaciones. Cuando disponga de tiempo le doy un empujoncito.

 

Saludos.

[escafandra]

Prometí ampliar este tema, en esta ocasión añado varias funcionalidades nuevas:

1- Notificaciones de lo que sucede con la WIFI con apoyo de función callback: API WlanRegisterNotification

2- Información del cifrado de clave y de red.

3- Posibilidad de conectarse a una red Wifi no añadida en el PC identificándonos con su SSID y Clave.

4- Posibilidad de conectarse a una red abierta.

5. Extracción de la clave de una SSID específica.

6- Extracción de todas las claves de la lista de redes wifi memorizada en el PC.

7- Funciones extra,

8- Notificaciones en el SysTray.

9- Aumento definiciones de la API Native Wifi Functions en una unit por separado.

 

Como el código es largo, lo incluyo en un nuevo adjunto.

 

 

Saludos.

Attached Files

•  WiffiConnect2.rar   171.63KB   88 downloads

[Wilson]

Descargado, muchas gracias Escafandra, muy buen trabajo.

[enecumene]

[monchito_elroro]

Buenas con todos, en especial y felicitando al amigo Escafandra por compartir un buen aporte a la comunidad, agradeciendole también por la ayuda recibida en el post: 

http://delphiaccess....jadas-en-el-pc/

 

Ahora he tratado de pasar este proyecto para lazarus, les comento que me ha ido bien , aunque unos codes me indicaba error al compilar estos los pude solucionar siguiendo las mismos consejos que me dío el maestro Escafranda en el post mencionado, paso a compartirles el proyecto para lazarus.

 

http://www.mediafire...Escafranda).zip

(disculpen por usar mediafire es que por este medio no me deja)

 

Por favor les pido que me corrijan si algo estoy haciendo mal.

 

Quisiera agradecer a Escafranda quien es el autor del código por siempre estar dispuesto a brindarnos grandes aportes.

también aprovecho la oportunidad para pedirle una consulta, el software funciona genial pero porque mi red wifi lo detecta dos veces como lo adjunto en la imagen dentro del proyecto que he subido a mediafie.

 

Esperando sus consejos me despido.

 

 

[enecumene]

No sé si aprovechar el hilo o abrir otro, pero.., amigo escafandra, habrá alguna API para el inicio y detención de un HostedNetwork?, no encuentro información al respecto.

 

Saludos.

[escafandra]

Wireless Hosted Network Sample

No he jugado con eso pero no creo que sea muy complejo.

Saludos.