7 replies to this topic

[escafandra]

Windows tiene previsto un sistema con unos iconos que indican el orden en las columnas de un ListView, ascendente o descendente. No conozco si las últimas versiones de delphi lo incluyen, hasta la versión 7 no es así, de modo que me puse a trabajar en este truco, a raiz de una pregunta similar en un foro dedicado a Builder en el que suelo participar.
 
Esta sería la versión para delphi:

delphi

procedure SetSortIcon(List: TListView; ColumnIndex: integer; Ascending: integer);
const
  HDF_SORTDOWN = $0200;
  HDF_SORTUP   = $0400;
var
  hHeader: THANDLE;
  HD: HD_ITEM;
begin
  hHeader := SendMessage(List.Handle, LVM_GETHEADER, 0, 0);
  HD.mask:= HDI_FORMAT;
  SendMessage(hHeader, HDM_GETITEM, ColumnIndex, Integer(@HD));
  if Ascending = 0 then
    HD.fmt:= (HD.fmt and not HDF_SORTUP) or HDF_SORTDOWN
  else
    HD.fmt:= (HD.fmt and not HDF_SORTDOWN) or HDF_SORTUP;
   SendMessage(hHeader, HDM_SETITEM, ColumnIndex, Integer(@HD));
end;

 
 
La forma de uso:

delphi

procedure TForm1.ListView1ColumnClick(Sender: TObject; Column: TListColumn);
var
  i: integer;
begin
  Column.Tag:= Column.Tag xor 1; // 0 descendente y 1 ascendente
  SetSortIcon(ListView1, Column.Index, Column.Tag);
 
  // Aquí se implementaría la llamada a la función de ordenación de la columna
  TListView(Sender).CustomSort(@SortByColumn, Column.Index);
end;

 
Se debe incluir le archivo de recursos para WinXP para que funcione. 
 

Saludos.

[escafandra]

Y esta es la versión para Builder C/C++
 

cpp

#define  HDF_SORTDOWN  0x0200
#define  HDF_SORTUP    0x0400
 
void SetSortIcon(TListView *ListView, int ColumnIndex, BOOL Ascending)
{
  HANDLE hHeader;
  HD_ITEM HD;
 
  hHeader = (HANDLE)SendMessage(ListView->Handle, LVM_GETHEADER, 0, 0);
  HD.mask = HDI_FORMAT;
  SendMessage(hHeader, HDM_GETITEM, ColumnIndex, DWORD(&HD));
 
  if(Ascending == 1)
    HD.fmt = (HD.fmt & ~HDF_SORTUP) |  HDF_SORTDOWN;
  else
    HD.fmt = (HD.fmt & ~HDF_SORTDOWN) | HDF_SORTUP;
 
  SendMessage(hHeader, HDM_SETITEM, ColumnIndex, DWORD(&HD));
}

La forma de uso:

cpp

void __fastcall TForm1::ListView1ColumnClick(TObject *Sender, TListColumn *Column)
{
  Column->Tag ^= 1; // Guardamos eun el tag 1 ó 0 para indicar el orden
  SetSortIcon(ListView1, Column->Index, Column->Tag);
 
  // Ordenamos según convenga... esto no está implementado
  TListView(Sender).CustomSort((PFNLVCOMPARE)SortByColumn, Column->Index);
}

Si usáis un BCB antiguo, no olvidéis incluir un archivo de recursos XP.rc


Saludos.

[Agustin Ortu]

Excelente como siempre, este en particular me viene muy bien!!

 

Estas a full con los trucos ultimamente     

[escafandra]

El ListView en delphi (y Builder) borra las flechitas de este truco al redimensionar el botón de la cabecera de la columna, si queremos que no ocurra hay que complicarse un poquito más la vida.
 
Os propongo el código siguiente que realiza un Hook a la función de tratamiento de mensajes del ListView para capturar la notificación y restaurar la flechita. El código es una clase, deberá crearse un objeto para cada ListView que se desee controlar.

delphi

unit SortIcon;
 
//--------------------------------------------------------------------------------------------------
// TSortIcon (Versión Hook estilo C++)
// escafandra 2015
// Clase para manejo de las flechitas de orden en las cabeceras de las columnas
// de un ListView 
 
interface
 
uses Windows, Messages, CommCtrl;
 
const
SI_Descendign = 0;
SI_Ascendign  = 1;
SI_Erase      = 2;
 
type
  TSortIcon = class
  private
    hListView: THANDLE;
    HDFocus: HD_ITEM;
    FocusIndex: integer;
    OldListViewProc: Pointer;
    function ListViewProc(Handle: HWND; Msg: DWORD; WParam: DWORD; LParam: DWORD): DWORD; stdcall;
  public
    destructor Destroy; override;
    procedure  SetSortIcon(Value: DWORD);
    procedure  SetHandle(Handle: THANDLE);
  end;
 
implementation
 
 
function DefListViewProc(Handle: HWND; Msg: DWORD; WParam: DWORD; LParam: DWORD): DWORD; stdcall;
var
  pSortIcon: TSortIcon;
begin
  pSortIcon:= TSortIcon(GetWindowLong(Handle, GWL_USERDATA));
  if pSortIcon <> nil then
    Result:= pSortIcon.ListViewProc(Handle, Msg, WParam, LParam)
  else
    Result:= DefWindowProc(Handle, Msg, WParam, LParam);
end;
 
function TSortIcon.ListViewProc(Handle: HWND; Msg: DWORD; WParam: DWORD; LParam: DWORD): DWORD; stdcall;
begin
  if (Msg = WM_NOTIFY) and (LParam <> 0) then
  begin
    if PNMHDR(LParam).code = NM_RELEASEDCAPTURE then
      SendMessage(PNMHDR(LParam).hwndFrom, HDM_SETITEM, FocusIndex, DWORD(@HDFocus));
  end;
  Result:= CallWindowProc(OldListViewProc, Handle, Msg, WParam, LParam);
end;
 
procedure TSortIcon.SetSortIcon(Value: DWORD);
const
  HDF_SORTDOWN = $0200;
  HDF_SORTUP   = $0400;
var
  hHeader: THANDLE;
  HD: HD_ITEM;
  HTI: HD_HITTESTINFO;
  i: integer;
  ColumCount: integer;
  ColumnIndex: integer;
begin
  if (hListView = 0) or (hListView = INVALID_HANDLE_VALUE) then exit;
 
  Windows.GetCursorPos(HTI.Point);
  Windows.ScreenToClient(hListView, HTI.Point);
  hHeader:= SendMessage(hListView, LVM_GETHEADER, 0, 0);
  ColumCount:= SendMessage(hHeader, HDM_GETITEMCOUNT, 0, 0);
  ColumnIndex:= SendMessage(hHeader, HDM_HITTEST, 0, DWORD(@HTI));
  if HTI.flags <> HHT_ONDIVIDER then FocusIndex:= ColumnIndex;
 
  for i:= 0 to ColumCount - 1 do
  begin
    HD.mask:= HDI_FORMAT;
    SendMessage(hHeader, HDM_GETITEM, i, Integer(@HD));
    if i = FocusIndex then
    begin
      if Value = SI_Ascendign then
        HD.fmt:= (HD.fmt and not HDF_SORTDOWN) or HDF_SORTUP
      else if Value = SI_Descendign then
        HD.fmt:= (HD.fmt and not HDF_SORTUP) or HDF_SORTDOWN;
      HDFocus:= HD;
    end
    else
      // borra la flechita de los demás...
      HD.fmt:= HD.fmt and not(HDF_SORTUP or HDF_SORTDOWN);
    SendMessage(hHeader, HDM_SETITEM, i, Integer(@HD));
  end;
end;
 
procedure TSortIcon.SetHandle(Handle: THANDLE);
begin
  if (hListView <> 0) or (Handle = INVALID_HANDLE_VALUE) or (Handle = 0) then
  if hListView <> 0 then
  begin
    SetWindowLong(hListView, GWL_USERDATA, 0);
    SetWindowLong(hListView, GWL_WNDPROC, LongInt(OldListViewProc));
    SetSortIcon(SI_Erase);
    hListView:= 0;
  end;
 
  if (Handle <> INVALID_HANDLE_VALUE) and (Handle <> 0) then
  begin
    hListView:= Handle;
    SetWindowLong(hListView, GWL_USERDATA, LongInt(self));
    OldListViewProc:= Pointer(SetWindowLong(hListView, GWL_WNDPROC, LongInt(@DefListViewProc)));
  end;
end;
 
destructor TSortIcon.Destroy;
begin
  SetHandle(0);
end;
 
end.

 


El ejemplo de uso:

delphi

procedure TForm1.FormCreate(Sender: TObject);
begin
  SI1:= TSortIcon.Create;
  SI1.SetHandle(ListView1.Handle);
end;
 
procedure TForm1.ListView1ColumnClick(Sender: TObject; Column: TListColumn);
const
{$J+}
  LastColumnIndex: integer = -1;
{$J-}
var
  i: integer;
begin
  if LastColumnIndex = Column.Index then
    Column.Tag:= Column.Tag xor 1; // Guardamos eun el tag 1 ó 0 para indicar el orden
  LastColumnIndex:= Column.Index;
  SI1.SetSortIcon(Column.Tag);     // Selecionamos la flechita (0: abajo, 1: arriba, 2: borrar
 
  // Aquí procedemos a ordenar
end;

Las características:
1. Puede manejar tantos ListView como queramos.
2. Es API pura, con lo que su uso se puede extender a ListView que no sean VCL
3. Admite FullDrag:= true para trasladar las columnas de sitio.
4. No se borra la flechita al redimensionar una columna.
5. No se puede asignar un ListView a dos TSortIcon.
6. Se puede usar como base para crear otra clase que maneje todos los ListView de un formulario
 
Espero que sea de utilidad.


Saludos.

[escafandra]

El mismo código en C++
 

cpp

//------------------------------------------------------------------------------
// TSortIcon
// escafandra 2015
// Clase para manejo de las flechitas de orden en las cabeceras de las columnas 
// de un ListView 
 
 
#ifndef SortIconCPP
#define SortIconCPP
 
#include <Windows.h>
 
#define  HDF_SORTDOWN  0x0200
#define  HDF_SORTUP    0x0400
 
#define SI_Descendign  0
#define SI_Ascendign   1
#define SI_Erase       2
 
typedef int (__stdcall *PLRESULT)();
 
class TSortIcon
{
  private:
  HANDLE hListView;
  HDITEM HDFocus;
  int FocusIndex;
  PLRESULT OldListViewProc;
 
  static LRESULT __stdcall DefListViewProc(HWND hWnd, UINT Msg, WPARAM WParam, LPARAM LParam)
  {
    TSortIcon* pSortIcon = (TSortIcon*)GetWindowLongPtr(hWnd, GWL_USERDATA);
    if(pSortIcon)
      return pSortIcon->ListViewProc(hWnd, Msg, WParam, LParam);
    else return DefWindowProc(hWnd, Msg, WParam, LParam);
  }
 
  LRESULT __stdcall ListViewProc(HWND hWnd, UINT Msg, WPARAM WParam, LPARAM LParam)
  {
    if(Msg == WM_NOTIFY && LParam){
      if(((NMHDR*)(LParam))->code ==  NM_RELEASEDCAPTURE)
        SendMessage(((NMHDR*)(LParam))->hwndFrom, HDM_SETITEM, FocusIndex, DWORD(&HDFocus));
    }
    return CallWindowProc(OldListViewProc, hWnd, Msg, WParam, LParam);
  }
 
  public:
  void SetSortIcon(DWORD Value)
  {
    int ColumCount;
    int ColumnIndex;
    HANDLE hHeader;
    HD_ITEM HD;
    HDHITTESTINFO HTI;
 
    GetCursorPos(&(HTI.pt));
    ::ScreenToClient(hListView, &(HTI.pt));
 
    hHeader = (HANDLE)SendMessage(hListView, LVM_GETHEADER, 0, 0);
    ColumCount  = SendMessage(hHeader, HDM_GETITEMCOUNT, 0, 0);
    ColumnIndex = SendMessage(hHeader, HDM_HITTEST, 0, DWORD(&HTI));
    if(HTI.flags != HHT_ONDIVIDER) FocusIndex = ColumnIndex;
 
    for(int i = 0; i < ColumCount; i++){
      HD.mask = HDI_FORMAT;
      SendMessage(hHeader, HDM_GETITEM, i, DWORD(&HD));
      if(i == FocusIndex){
        if(Value == SI_Ascendign)
          HD.fmt = (HD.fmt & ~HDF_SORTDOWN) | HDF_SORTUP;
        else if(Value == SI_Descendign)
          HD.fmt = (HD.fmt & ~HDF_SORTUP) | HDF_SORTDOWN;
        HDFocus = HD;
      }
      else
        HD.fmt &= ~(HDF_SORTUP | HDF_SORTDOWN);
      SendMessage(hHeader, HDM_SETITEM, i, DWORD(&HD));
    } 
  }
 
  void SetHandle(HANDLE HListView)
  {
    if(hListView || HListView == INVALID_HANDLE_VALUE || !HListView)
    if(hListView){
      SetWindowLong(hListView, GWL_USERDATA, 0);
      SetWindowLong(hListView, GWL_WNDPROC, (LONG)OldListViewProc);
      SetSortIcon(3);
      hListView = 0;
    }
    if(HListView != INVALID_HANDLE_VALUE && HListView){
      hListView = HListView;
      SetWindowLongPtr(hListView, GWL_USERDATA, (LONG)this);
      OldListViewProc = (PLRESULT)SetWindowLongPtr(hListView, GWL_WNDPROC, (LONG)TSortIcon::DefListViewProc);
    }
  }
 
  ~TSortIcon() {SetHandle(0);}
};
#endif

Saludos.

[escafandra]

Os dejo otra versión de la Clase TSortIcon que me gusta más que la que publiqué hace unos días. Realiza el hook subclassing a la función de tratamiento de mensajes del ListView_Header, en lugar de a la del ListView, disponiendo de un mayor control y simplicidad.
 

delphi

unit SortIcon;
 
//--------------------------------------------------------------------------------------------------
// TSortIcon (Versión Hook estilo C++)
// escafandra 2015
// Clase para manejo de las flechitas de orden en las cabeceras de las columnas
// de un ListView
 
interface
 
uses Windows, Messages, CommCtrl;
 
const
  HDF_SORTDOWN = $0200;
  HDF_SORTUP   = $0400;
 
 
  SI_Descendign = 0;
  SI_Ascendign  = 1;
  SI_Erase      = 2;
 
type
  TSortIcon = class
  private
    hHeader: THANDLE;
    Focusfmt: integer;
    FocusIndex: integer;
    OldHeaderProc: Pointer;
    function HeaderProc(Handle: HWND; Msg: DWORD; WParam: Longint; LParam: Longint): Longint; stdcall;
  public
    destructor Destroy; override;
    procedure  SetSortIcon(Value: DWORD);
    procedure  SetHandle(hListView: THANDLE);
  end;
 
implementation
 
 
function DefHeaderProc(Handle: HWND; Msg: DWORD; WParam: Longint; LParam: Longint): Longint; stdcall;
var
  pSortIcon: TSortIcon;
begin
  pSortIcon:= TSortIcon(GetWindowLong(Handle, GWL_USERDATA));
  if pSortIcon <> nil then
    Result:= pSortIcon.HeaderProc(Handle, Msg, WParam, LParam)
  else
    Result:= DefWindowProc(Handle, Msg, WParam, LParam);
end;
 
function TSortIcon.HeaderProc(Handle: HWND; Msg: DWORD; WParam: Longint; LParam: Longint): Longint; stdcall;
begin
  if ((Msg = HDM_SETITEMW) or (Msg = HDM_SETITEMA)) and (WParam = FocusIndex) and (LParam <> 0) then
    PHDITEM(LParam).fmt:= PHDITEM(LParam).fmt or Focusfmt;
  Result:= CallWindowProc(OldHeaderProc, Handle, Msg, WParam, LParam);
end;
 
procedure TSortIcon.SetSortIcon(Value: DWORD);
var
  HD: HD_ITEM;
  HTI: HD_HITTESTINFO;
  i: integer;
  ColumCount: integer;
  ColumnIndex: integer;
begin
  if (hHeader = 0) or (hHeader = INVALID_HANDLE_VALUE) then exit;
 
  // Busco el ItemHeader con foco
  Windows.GetCursorPos(HTI.Point);
  Windows.ScreenToClient(hHeader, HTI.Point);
  ColumnIndex:= SendMessage(hHeader, HDM_HITTEST, 0, DWORD(@HTI));
  if HTI.flags <> HHT_ONDIVIDER then FocusIndex:= ColumnIndex;
 
  ColumCount:= SendMessage(hHeader, HDM_GETITEMCOUNT, 0, 0);
  for i:= 0 to ColumCount - 1 do
  begin
    HD.mask:= HDI_FORMAT;
    SendMessage(hHeader, HDM_GETITEM, i, Integer(@HD));
    HD.fmt:= HD.fmt and not(HDF_SORTUP or HDF_SORTDOWN);
    if i = FocusIndex then
    begin
      if Value = SI_Ascendign then
        Focusfmt:= HDF_SORTUP
      else if Value = SI_Descendign then
        Focusfmt:= HDF_SORTDOWN;
      HD.fmt:= HD.fmt or Focusfmt;
    end;
    CallWindowProc(OldHeaderProc, hHeader, HDM_SETITEM, i, LongInt(@HD));
    //SendMessage(hHeader, HDM_SETITEM, i, LongInt(@HD));
  end;
end;
 
procedure TSortIcon.SetHandle(hListView: THANDLE);
begin
  if hListView <> INVALID_HANDLE_VALUE then
  begin
    if (hHeader <> 0) or (hListView = 0) then
    begin
      SetWindowLong(hHeader, GWL_USERDATA, 0);
      SetWindowLong(hHeader, GWL_WNDPROC, LongInt(OldHeaderProc));
      SetSortIcon(SI_Erase);
      hHeader:= 0;
    end;
    if hListView <> 0 then
    begin
      hHeader:= SendMessage(hListView, LVM_GETHEADER, 0, 0);
      SetWindowLong(hHeader, GWL_USERDATA, LongInt(self));
      OldHeaderProc:= Pointer(SetWindowLong(hHeader, GWL_WNDPROC, LongInt(@DefHeaderProc)));
    end;
  end;
end;
 
destructor TSortIcon.Destroy;
begin
  SetHandle(0);
end;
 
end.

 
 
Las características:
1. Puede manejar tantos ListView como queramos.
2. Es API pura, con lo que su uso se puede extender a ListView que no sean VCL
3. Admite FullDrag:= true para trasladar las columnas de sitio.
4. No se borra la flechita al redimensionar una columna con el ratón o por código.
5. No se puede asignar un ListView a dos TSortIcon.
6. Se puede usar como base para crear otra clase que maneje todos los ListView de un formulario.

 
Saludos.

Attached Files

•  Flechitas ListView delphi.rar   193.18KB   2 downloads

[escafandra]

Esta es la versión para C++
 

cpp

//------------------------------------------------------------------------------
// TSortIcon
// escafandra 2015
// Clase para manejo de las flechitas de orden en las cabeceras de las columnas 
// de un ListView 
 
 
#ifndef SortIconCPP
#define SortIconCPP
 
#include <Windows.h>
 
#define  HDF_SORTDOWN  0x0200
#define  HDF_SORTUP    0x0400
 
#define SI_Descendign  0
#define SI_Ascendign   1
#define SI_Erase       2
 
typedef int (__stdcall *PLRESULT)();
 
class TSortIcon
{
  private:
  HANDLE hHeader;
  int Focusfmt;
  int FocusIndex;
  PLRESULT OldHeaderProc;
 
  static LRESULT __stdcall DefHeaderProc(HWND hWnd, UINT Msg, WPARAM WParam, LPARAM LParam)
  {
    TSortIcon* pSortIcon = (TSortIcon*)GetWindowLongPtr(hWnd, GWL_USERDATA);
    if(pSortIcon)
      return pSortIcon->HeaderProc(hWnd, Msg, WParam, LParam);
    else return DefWindowProc(hWnd, Msg, WParam, LParam);
  }
 
  LRESULT __stdcall HeaderProc(HWND hWnd, UINT Msg, WPARAM WParam, LPARAM LParam)
  {
    if((Msg == HDM_SETITEMW || Msg == HDM_SETITEMA) && WParam == WPARAM(FocusIndex) && LParam)
      LPHDITEM(LParam)->fmt |= Focusfmt;
    return CallWindowProc(OldHeaderProc, hWnd, Msg, WParam, LParam);
  }
 
  public:
  void SetSortIcon(DWORD Value)
  {
    int ColumCount;
    int ColumnIndex;
    HDITEM HD;
    HDHITTESTINFO HTI;
 
    if (!hHeader || hHeader == INVALID_HANDLE_VALUE) return;
 
    // Busco el ItemHeader con foco
    GetCursorPos(&(HTI.pt));
    ::ScreenToClient(hHeader, &(HTI.pt));
    ColumnIndex = SendMessage(hHeader, HDM_HITTEST, 0, DWORD(&HTI));
    if(HTI.flags != HHT_ONDIVIDER) FocusIndex = ColumnIndex;
 
    ColumCount  = SendMessage(hHeader, HDM_GETITEMCOUNT, 0, 0);
    for(int i = 0; i < ColumCount; i++){
      HD.mask = HDI_FORMAT;
      SendMessage(hHeader, HDM_GETITEM, i, DWORD(&HD));
      HD.fmt &= ~(HDF_SORTUP | HDF_SORTDOWN);
      if(i == FocusIndex){
        if(Value == SI_Ascendign)
          Focusfmt = HDF_SORTUP;
        else if(Value == SI_Descendign)
          Focusfmt = HDF_SORTDOWN;
        HD.fmt |= Focusfmt;;
      }
      CallWindowProc(OldHeaderProc, hHeader, HDM_SETITEM, i, LPARAM(&HD));
      //SendMessage(hHeader, HDM_SETITEM, i, LPARAM(&HD));
    } 
  }
 
  void SetHandle(HANDLE hListView)
  {
    if(hListView != INVALID_HANDLE_VALUE){
      if(hHeader || !hListView){
        SetWindowLong(hHeader, GWL_USERDATA, 0);
        SetWindowLong(hHeader, GWL_WNDPROC, (LONG)OldHeaderProc);
        SetSortIcon(SI_Erase);
        hHeader = 0;
      }
      if(hListView){
        hHeader = (HANDLE)SendMessage(hListView, LVM_GETHEADER, 0, 0);
        SetWindowLongPtr(hHeader, GWL_USERDATA, (LONG)this);
        OldHeaderProc = (PLRESULT)SetWindowLongPtr(hHeader, GWL_WNDPROC, (LONG)TSortIcon::DefHeaderProc);
      }
    }
  }
 
  ~TSortIcon() {SetHandle(0);}
};
#endif

Saludos.

Attached Files

•  Flechitas ListView BCB.rar   236.32KB   2 downloads

[poliburro]

Gracias por el aporte amigo.