6 respuestas en este tema

[cram]

La propiedad constraint de algunos componentes de la VCL permite restringir (como lo indica su nombre) las dimensiones del objeto contenedor.

Es decir que, en caso de intentar reducir demasiado el tamaño de un contenedor (ventana, por ej.), se imponga un límite para que los objetos no queden fuera de este.

Por más que busco en FM, no la encuentro, ¿alguien conoce algo parecido?

 

Saludos

 

[genriquez]

Hola Cram, creo que no lo tiene, pero es bastante sencillo implementarlo de la siguiente manera.

 

Simplemente adicionas en los uses una librería donde definas esto, o lo adicionas en el form, esto  sobreescribe la clase TLayout,

delphi

TLayout = Class(FMX.Layouts.TLayout)
  private
    FConstraint: TPoint;
    procedure SetConstraint(const Value: TPoint);
 
  Protected
     procedure HandleSizeChanged; Override;
  Public
     Property Constraint : TPoint read FConstraint write SetConstraint;
 
  End;
 
 
......
 
{ TLayout }
 
procedure TLayout.HandleSizeChanged;
begin
  If (FConstraint.X > 0) and (Self.Width < FConstraint.X) then
     Self.Width := FConstraint.X;
 
  If (FConstraint.Y > 0) and (Self.Height < FConstraint.Y) then
     Self.Height := FConstraint.Y;
 
  inherited;
end;
 
procedure TLayout.SetConstraint(const Value: TPoint);
begin
  FConstraint := Value;
end;

Luego en el OnCreate del formulario puedes adicionar la inicialización de los valores del constraint.

delphi

procedure TForm15.FormCreate(Sender: TObject);
begin
   Layout1.Constraint := Point(200,0);
end;

el código fuente del ejemplo está a continuación.

delphi

unit Unit15;
 
interface
 
uses
  System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,
  FMX.Types, FMX.Controls, FMX.Forms, FMX.Graphics, FMX.Dialogs, FMX.StdCtrls, FMX.Layouts;
 
type
 
  TLayout = Class(FMX.Layouts.TLayout)
  private
    FConstraint: TPoint;
    procedure SetConstraint(const Value: TPoint);
 
  Protected
     procedure HandleSizeChanged; Override;
  Public
     Property Constraint : TPoint read FConstraint write SetConstraint;
 
  End;
 
 
  TForm15 = class(TForm)
    Layout1: TLayout;
    Layout2: TLayout;
    Splitter1: TSplitter;
    procedure Layout1Resize(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;
 
var
  Form15: TForm15;
 
implementation
 
{$R *.fmx}
 
procedure TForm15.FormCreate(Sender: TObject);
begin
   Layout1.Constraint := Point(200,0);
end;
 
procedure TForm15.Layout1Resize(Sender: TObject);
begin
 
end;
 
{ TLayout }
 
procedure TLayout.HandleSizeChanged;
begin
  If (FConstraint.X > 0) and (Self.Width < FConstraint.X) then
     Self.Width := FConstraint.X;
 
  If (FConstraint.Y > 0) and (Self.Height < FConstraint.Y) then
     Self.Height := FConstraint.Y;
 
  inherited;
end;
 
procedure TLayout.SetConstraint(const Value: TPoint);
begin
  FConstraint := Value;
end;
 
end.

puedes hacer esto con cualquier componente.

 

Otra forma puede ser creando nuevos componentes y sobreescribiendo la función.  pero esto ya depende de como te guste más.

[cram]

Muchas gracias por la respuesta GEnriquez.

Por supuesto que siempre hay una posibilidad, la que muestras es muy interesante. El asunto es que también tuve que hacer a mano una ampliación controlada, ya que el componente que se supone es especialmente diseñado para esto no lo hace como quiero, pues le falta una propiedad que indique que se quiere mantener el aspecto.

Es que FM tiene tantas novedades respecto de VCL, que aun no puedo comprender como se les pasó una cosa tan útil.

Actualmente estoy trabajando en un comportamiento de la ventana que permita ampliar sus controles pero no permita reducir la ventana a tal punto que no quepan o se vuelvan ilegibles. Para esto inicio de un tamaño que llamo natural y permito la ampliación.

La verdad que FM tiene contrariedades. Por ejemplo una vez que fijas el tamaño de una fuente, ya no se puede ampliar. Es que es una contrariedadm pues las dimensiones de la ventana con la ampliación no son modificadas, pero la fuente una vez definido su tamaño no se puede ampliar a menos que le indiques en la propiedad de la fuente. ...

 

Voy a probarlo.

Pero en este caso quería evitar la creación o modificación de componentes.

 

Saludos.

[cram]

Una respuesta más. Cuando dije interesante es porque noté que estabas creando un componente nuevo. En fin, no lo había visto en detalle, ahora que lo veo en detalle, te comento que es quizá la única forma, pues el componente original solo tiene la posibilidad de capturar el evento OnResize y no uno OnResizing, que sería más apropiado. El asunto es que no puede implementarse algo sin la modificación de la clase, ya que OnResize ocurre después del "resize" y ya no sirve, o al menos no es muy bueno el resultado que podría dar llegar a una dimensión dibujarla y volverla al límite y dibujarla de nuevo (supongo que se entiende).

 

Supongo que deberé crear más de un componente y tenerlos a mano como cuando la VCL no era tan potente en aspectos visuales.

 

Saludos y muchas gracias.

[egostar]

Una respuesta más. Cuando dije interesante es porque noté que estabas creando un componente nuevo. En fin, no lo había visto en detalle, ahora que lo veo en detalle, te comento que es quizá la única forma, pues el componente original solo tiene la posibilidad de capturar el evento OnResize y no uno OnResizing, que sería más apropiado. El asunto es que no puede implementarse algo sin la modificación de la clase, ya que OnResize ocurre después del "resize" y ya no sirve, o al menos no es muy bueno el resultado que podría dar llegar a una dimensión dibujarla y volverla al límite y dibujarla de nuevo (supongo que se entiende).

 

Supongo que deberé crear más de un componente y tenerlos a mano como cuando la VCL no era tan potente en aspectos visuales.

 

Saludos y muchas gracias.

 

Lo unico que yo creo es que hay que tener cuidado con el diseño de componentes para FMX, hay que tener en mente que no son exclusivos para desktop y los móviles tienen manejos diferentes de los componentes, por eso es que el "transporte" no ha sido rápido ni transparente de la VCL a FMX.

 

Saludos

[cram]

Así es Egostar, gracias por la aclaración (lo tuve en cuenta, aunque no lo haya mencionado). Supongo que no todos los sistemas operativos cuentan con el mismo nivel de abundancia en cuanto a eventos.

En realidad constraint es una comodidad para el usuario, más que para el programador, puesto que este debería tener cuidado en al menos algo de lo que hace. Soy algo paranoico al momento de evitar "estupideces" por parte del operador.

 

Saludos

[genriquez]

Hola,  la ventaja que veo en este modelo es que no se crea un nuevo componente, simplemente se extiende, eso queda dentro de una unit,  así que basta con utilizar el componente original y si el detecta que la hay modificaciones, simplemente las utiliza,  la única desventaja es que no son visibles en tiempo de diseño, solo en ejecución.

 

así he creado una gran variedad de librerías, que no requiero instalar, solamente las agrego en los uses y listo,  ese esquema es similar al de los helpers,  no hay que modificar el código de Delphi, ni instalar componentes, solo adicionar en los uses.  así de fácil.

 

Saludos.