Detectado javascript desactivado

Tienes el javascript desactivado en este momento. Muchas funciones podrían no funcionar. Por favor reactiva el javascript para obtener una funcionalidad completa.

Botón del Pánico o como desaferentar el PC

Comenzado por escafandra , sep 01 2016 11:03

Por favor identifícate para responder

10 respuestas en este tema

#1 escafandra

Advanced Member

Administrador
4.111 mensajes

LocationMadrid - España

Escrito 01 septiembre 2016 - 11:03

¿Nunca se os ha ocurrido apagarle a alguien el monitor por código de forma que no pueda encenderlo?, a mi sí y no voy a decir porqué *-)

Apagar el monitor es fácil con SC_MONITORPOWER pero en cuanto se toca el teclado o el ratón, se enciende. Para darle consistencia al apagado he escrito un thread que repite el apagado cada 100 ms y listo. Pero al hacer eso el usuario cambiaría cosas inconscientemente en las aplicaciones en primer plano al tratar de activar el monitor aporreando el teclado o interactuando desesperadamente con el ratón. Para solucionar este inconveniente bloqueo el teclado y el ratón.

¡Ni monitor, ni teclado ni ratón! Que no cunda el pánico, que las combinaciones de teclas en un hook al teclado nos abren la puerta:

ALT - F10: Cierra el programa devolviéndonos el control.

ALT - F11: Nos devuelve el control sin cerrar el programa.

ALT - F12: Apaga el monitor y bloquea el teclado + ratón.

La aplicación no tiene interface gráfico y queda como sigue:

delphi

program MonitorPower;
 
uses
  Windows, Messages;
 
var
  idThTurnOffMonitor: DWORD = 0;
  WHookKeyboard: HHOOK = 0;
  WHookMouse: HHOOK = 0;
 
function ThTurnOffMonitor(): DWORD; stdcall
var
  msg: TMsg;
  i: DWORD;
begin
  // Monitor off
  repeat PeekMessage(msg,0,0,0, PM_REMOVE);
    Sleep(100);
    SendNotifyMessage(GetForegroundWindow(), WM_SYSCOMMAND, SC_MONITORPOWER, 2);
    DispatchMessage(msg);
  until (msg.Message = WM_QUIT);
 
  // Monitor on
  SendNotifyMessage(GetForegroundWindow(), WM_SYSCOMMAND, SC_MONITORPOWER, -1);
  for i:= 0 to 4 do
  begin
    mouse_event(MOUSEEVENTF_MOVE, 0, 10, 0, 0);
    Sleep(40);
    mouse_event(MOUSEEVENTF_MOVE, 0, DWORD(-10), 0, 0);
  end;
  Result:= 0;
end;
 
procedure CmdEnableMonitor(Enable: BOOL);
begin
  if not Enable and (idThTurnOffMonitor = 0) then
    // Turn off monitor
    CloseHandle(CreateThread(nil, 0, @ThTurnOffMonitor, nil, 0, idThTurnOffMonitor));
  if Enable then
  begin
    // Turn on monitor
    PostThreadMessage(idThTurnOffMonitor, WM_QUIT, 0, 0);
    idThTurnOffMonitor:= 0;
  end;
end;
 
function KeyboardHook(Code, wParam, lParam: Integer): Integer; stdcall;
begin
  if (Code = HC_ACTION) and LongBool(PDWORD(lParam + 8)^ and $20{LLKHF_ALTDOWN}) then
  begin
    if PDWORD(lParam)^ = VK_F11 then    // ALT + F11: Monitor Off
      CmdEnableMonitor(true);
    if PDWORD(lParam)^ = VK_F12 then    // ALT + F12: Monitor On
      CmdEnableMonitor(false);
    if PDWORD(lParam)^ = VK_F10 then    // ALT + F10: Quit
      PostThreadMessage(GetCurrentThreadId, WM_QUIT, 0, 0);
  end;
  Result:= -1;
  if idThTurnOffMonitor = 0 then
    Result:= CallNextHookEx(WHookKeyboard, Code, wParam, lParam);
end;
 
function MouseHook(Code, wParam, lParam: Integer): Integer; stdcall;
begin
  Result:= -1;
  if (Code <> HC_ACTION) or (idThTurnOffMonitor = 0) then
  Result:= CallNextHookEx(WHookMouse, Code, wParam, lParam);
end;
 
var
  msg: TMsg;
begin
  idThTurnOffMonitor:= 0;
  WHookKeyboard:= SetWindowsHookEx(13{WH_KEYBOARD_LL}, @KeyboardHook, HInstance, 0);
  WHookMouse:= SetWindowsHookEx(14{WH_MOUSE_LL}, @KeyboardHook, HInstance, 0);
 
  // Bucle de mensajes:
  repeat GetMessage(msg, 0, 0, 0);
    DispatchMessage(msg);
  until (msg.Message = WM_QUIT);
 
  CmdEnableMonitor(true);
  UnhookWindowsHookEx(WHookKeyboard);
  UnhookWindowsHookEx(WHookMouse);
end.

El código puede tener su utilidad como botón del pánico, una broma no demasiado pesada o... la imaginación es libre.

Saludos.

2

Volver arriba

#2 egostar

missing my father, I love my mother.

Administrador
14.460 mensajes

LocationMéxico

Escrito 01 septiembre 2016 - 11:32

El código puede tener su utilidad como botón del pánico, una broma no demasiado pesada o... la imaginación es libre.

Saludos.

:dlaug: :dmad:

Saludos *-) *-) *-)

0

Volver arriba

#3 escafandra

Advanced Member

Administrador
4.111 mensajes

LocationMadrid - España

Escrito 02 septiembre 2016 - 06:49

El mismo código en C/C++

cpp

//---------------------------------------------------------------------------
 
#include <windows.h>
#pragma hdrstop
 
//---------------------------------------------------------------------------
 
#pragma argsused
 
 
DWORD idThTurnOffMonitor = 0;
HHOOK WHookKeyboard = 0;
HHOOK WHookMouse = 0;
 
DWORD WINAPI ThTurnOffMonitor(LPVOID lpParameter)
{
  MSG msg;
  DWORD i;
 
  // Monitor off
  do {
    PeekMessage(&msg,0,0,0, PM_REMOVE);
    Sleep(100);
    SendNotifyMessage(GetForegroundWindow(), WM_SYSCOMMAND, SC_MONITORPOWER, (LPARAM) 2);
    DispatchMessage(&msg);
  } while(msg.message != WM_QUIT);
 
  // Monitor on
  SendNotifyMessage(GetForegroundWindow(), WM_SYSCOMMAND, SC_MONITORPOWER, -1);
  for(i= 0; i<4; i++){
    mouse_event(MOUSEEVENTF_MOVE, 0, 10, 0, 0);
    Sleep(40);
    mouse_event(MOUSEEVENTF_MOVE, 0, DWORD(-10), 0, 0);
  }
  return 0;
}
 
void CmdEnableMonitor(BOOL Enable)
{
  if(!Enable && !idThTurnOffMonitor)
    // Turn off monitor
    CloseHandle(CreateThread(NULL, 0, ThTurnOffMonitor, NULL, 0, &idThTurnOffMonitor));
  if(Enable){
    // Turn on monitor
    PostThreadMessage(idThTurnOffMonitor, WM_QUIT, 0, 0);
    idThTurnOffMonitor = 0;
  }
}
 
LRESULT CALLBACK KeyboardHook(int nCode, WPARAM wParam, LPARAM lParam)
{
  if(nCode == HC_ACTION && (*PDWORD(lParam + 8) & LLKHF_ALTDOWN)){
    if(*PDWORD(lParam) == VK_F11)    // ALT + F11: Monitor Off
      CmdEnableMonitor(true);
    if(*PDWORD(lParam) == VK_F12)    // ALT + F12: Monitor On
      CmdEnableMonitor(false);
    if(*PDWORD(lParam) == VK_F10)    // ALT + F10: Quit
      PostThreadMessage(GetCurrentThreadId(), WM_QUIT, 0, 0);
  }
 
  if(idThTurnOffMonitor)
    return -1;
 
  return CallNextHookEx(WHookKeyboard, nCode, wParam, lParam);
}
 
LRESULT WINAPI MouseEvent(int nCode, WPARAM wParam, LPARAM lParam)
{
  if(nCode == HC_ACTION && idThTurnOffMonitor)
    return -1;
  return CallNextHookEx(WHookMouse, nCode, wParam, lParam);
}
 
WINAPI WinMain(HINSTANCE hInstance, HINSTANCE hPrevInstance, LPSTR lpCmdLine, int nCmdShow)
{
  MSG msg;
 
  idThTurnOffMonitor = 0;
  WHookKeyboard = SetWindowsHookEx(WH_KEYBOARD_LL, (HOOKPROC)KeyboardHook, hInstance, 0);
  WHookMouse = SetWindowsHookEx(WH_MOUSE_LL, (HOOKPROC)KeyboardHook, hInstance, 0);
 
  // Bucle de mensajes:
  do{
    GetMessage(&msg, 0, 0, 0);
    DispatchMessage(&msg);
  }while(msg.message != WM_QUIT);
 
  CmdEnableMonitor(true);
  UnhookWindowsHookEx(WHookKeyboard);
  UnhookWindowsHookEx(WHookMouse);
 
  return 0;
}
//---------------------------------------------------------------------------

Saludos.

2

Volver arriba

#4 Delphius

Advanced Member

Administrador
6.295 mensajes

LocationArgentina

Escrito 02 septiembre 2016 - 07:49

Interesante amigo...

Mi duda es ¿Esto es para hacerlo en local, sobre la propia máquina, no es cierto?

¿Se puede hacerlo remotamente?

Se que hay formas de hacer que a ciertas horas se apaguen y prendas equipos de forma totalmente remota aunque no las he explorado.

Saludos,

0

Volver arriba

#5 escafandra

Advanced Member

Administrador
4.111 mensajes

LocationMadrid - España

Escrito 02 septiembre 2016 - 10:49

Interesante amigo...

Mi duda es ¿Esto es para hacerlo en local, sobre la propia máquina, no es cierto?

¿Se puede hacerlo remotamente?

Se que hay formas de hacer que a ciertas horas se apaguen y prendas equipos de forma totalmente remota aunque no las he explorado.

Saludos,

Efectivamente es para hacerlo en local, pero nada impide hacerlo en red, de hecho estoy haciendo unas pruebas y publicaré la desaferentación en red, con lo que el PC quedaría inutilizado para el usuario pero trabajando, quedando liberado por el "administrador" desde la red,

Saludos.

0

Volver arriba

#6 genriquez

Advanced Member

Miembro Platino
539 mensajes

LocationCali, Colombia

Escrito 02 septiembre 2016 - 10:52

DataSnap tiene una funcionalidad interesante de CallBacks, lo único que hay que garantizar es la conexión del cliente hacia el servidor, y luego se pueden enviar mensajes hacia ese cliente, sería una buena forma de enviar el mensaje de apagado,

0

Volver arriba

#7 egostar

missing my father, I love my mother.

Administrador
14.460 mensajes

LocationMéxico

Escrito 02 septiembre 2016 - 11:19

Interesante amigo...

Mi duda es ¿Esto es para hacerlo en local, sobre la propia máquina, no es cierto?

¿Se puede hacerlo remotamente?

Se que hay formas de hacer que a ciertas horas se apaguen y prendas equipos de forma totalmente remota aunque no las he explorado.

Saludos,

Pues si, porque lo que quieres es que no se metan en tu maquina en algún descuido,

Oops, eso lo pensé o lo dije!!!!

Saludos

0

Volver arriba

#8 escafandra

Advanced Member

Administrador
4.111 mensajes

LocationMadrid - España

Escrito 02 septiembre 2016 - 01:52

DataSnap tiene una funcionalidad interesante de CallBacks, lo único que hay que garantizar es la conexión del cliente hacia el servidor, y luego se pueden enviar mensajes hacia ese cliente, sería una buena forma de enviar el mensaje de apagado,

Para eso Windows tiene el comando de consola shutdown que funciona también en red.

Saludos.

0

Volver arriba

#9 sir.dev.a.lot

Advanced Member

Miembros
545 mensajes

Location127.0.0.1

Escrito 02 septiembre 2016 - 02:17

¿Nunca se os ha ocurrido apagarle a alguien el monitor por código de forma que no pueda encenderlo?, a mi sí y no voy a decir porqué *-)

Apagar el monitor es fácil con SC_MONITORPOWER pero en cuanto se toca el teclado o el ratón, se enciende. Para darle consistencia al apagado he escrito un thread que repite el apagado cada 100 ms y listo. Pero al hacer eso el usuario cambiaría cosas inconscientemente en las aplicaciones en primer plano al tratar de activar el monitor aporreando el teclado o interactuando desesperadamente con el ratón. Para solucionar este inconveniente bloqueo el teclado y el ratón.

¡Ni monitor, ni teclado ni ratón! Que no cunda el pánico, que las combinaciones de teclas en un hook al teclado nos abren la puerta:

ALT - F10: Cierra el programa devolviéndonos el control.

ALT - F11: Nos devuelve el control sin cerrar el programa.

ALT - F12: Apaga el monitor y bloquea el teclado + ratón.

La aplicación no tiene interface gráfico y queda como sigue:

delphi

program MonitorPower;
 
uses
  Windows, Messages;
 
var
  idThTurnOffMonitor: DWORD = 0;
  WHookKeyboard: HHOOK = 0;
  WHookMouse: HHOOK = 0;
 
function ThTurnOffMonitor(): DWORD; stdcall
var
  msg: TMsg;
  i: DWORD;
begin
  // Monitor off
  repeat PeekMessage(msg,0,0,0, PM_REMOVE);
    Sleep(100);
    SendNotifyMessage(GetForegroundWindow(), WM_SYSCOMMAND, SC_MONITORPOWER, 2);
    DispatchMessage(msg);
  until (msg.Message = WM_QUIT);
 
  // Monitor on
  SendNotifyMessage(GetForegroundWindow(), WM_SYSCOMMAND, SC_MONITORPOWER, -1);
  for i:= 0 to 4 do
  begin
    mouse_event(MOUSEEVENTF_MOVE, 0, 10, 0, 0);
    Sleep(40);
    mouse_event(MOUSEEVENTF_MOVE, 0, DWORD(-10), 0, 0);
  end;
  Result:= 0;
end;
 
procedure CmdEnableMonitor(Enable: BOOL);
begin
  if not Enable and (idThTurnOffMonitor = 0) then
    // Turn off monitor
    CloseHandle(CreateThread(nil, 0, @ThTurnOffMonitor, nil, 0, idThTurnOffMonitor));
  if Enable then
  begin
    // Turn on monitor
    PostThreadMessage(idThTurnOffMonitor, WM_QUIT, 0, 0);
    idThTurnOffMonitor:= 0;
  end;
end;
 
function KeyboardHook(Code, wParam, lParam: Integer): Integer; stdcall;
begin
  if (Code = HC_ACTION) and LongBool(PDWORD(lParam + 8)^ and $20{LLKHF_ALTDOWN}) then
  begin
    if PDWORD(lParam)^ = VK_F11 then    // ALT + F11: Monitor Off
      CmdEnableMonitor(true);
    if PDWORD(lParam)^ = VK_F12 then    // ALT + F11: Monitor On
      CmdEnableMonitor(false);
    if PDWORD(lParam)^ = VK_F10 then    // ALT + F10: Quit
      PostThreadMessage(GetCurrentThreadId, WM_QUIT, 0, 0);
  end;
  Result:= -1;
  if idThTurnOffMonitor = 0 then
    Result:= CallNextHookEx(WHookKeyboard, Code, wParam, lParam);
end;
 
function MouseHook(Code, wParam, lParam: Integer): Integer; stdcall;
begin
  Result:= -1;
  if (Code <> HC_ACTION) or (idThTurnOffMonitor = 0) then
  Result:= CallNextHookEx(WHookMouse, Code, wParam, lParam);
end;
 
var
  msg: TMsg;
begin
  idThTurnOffMonitor:= 0;
  WHookKeyboard:= SetWindowsHookEx(13{WH_KEYBOARD_LL}, @KeyboardHook, HInstance, 0);
  WHookMouse:= SetWindowsHookEx(14{WH_MOUSE_LL}, @KeyboardHook, HInstance, 0);
 
  // Bucle de mensajes:
  repeat GetMessage(msg, 0, 0, 0);
    DispatchMessage(msg);
  until (msg.Message = WM_QUIT);
 
  CmdEnableMonitor(true);
  UnhookWindowsHookEx(WHookKeyboard);
  UnhookWindowsHookEx(WHookMouse);
end.

El código puede tener su utilidad como botón del pánico, una broma no demasiado pesada o... la imaginación es libre.

Saludos.

Estaba leyendo y vi esto en el comentario

if PDWORD(lParam)^ = VK_F12 then // ALT + F11: Monitor On

tambien esta en C++

Saludos!

1

Volver arriba

#10 escafandra

Advanced Member

Administrador
4.111 mensajes

LocationMadrid - España

Escrito 02 septiembre 2016 - 02:45

Estaba leyendo y vi esto en el comentario

if PDWORD(lParam)^ = VK_F12 then // ALT + F11: Monitor On

tambien esta en C++

Saludos!

Muy cierto, es el efecto de mi vagancia a la hora de escribir y usar el corta-pega

Menos mal que el código está correcto pues no recuperaríamos el control sin matar el programa

Ya he editado esos comentarios (y)

Saludos

0

Volver arriba

#11 genriquez

Advanced Member

Miembro Platino
539 mensajes

LocationCali, Colombia

Escrito 08 septiembre 2016 - 08:02

Para eso Windows tiene el comando de consola shutdown que funciona también en red.

Saludos.

El CallBacks funciona sobre internet, aún sobre routers. es bien interesante.

0

Volver arriba

Volver a Ejercicios Prácticos

Botón del Pánico o como desaferentar el PC

#1 escafandra

#2 egostar

#3 escafandra

#4 Delphius

#5 escafandra

#6 genriquez

#7 egostar

#8 escafandra

#9 sir.dev.a.lot

#10 escafandra

#11 genriquez

Iniciar sesión