4 respuestas en este tema

[enecumene]

Estoy teniendo un pequeño problemita borrando los items seleccionados de un TListView y es que se me borra todos!, éste es el código:

delphi

procedure TFDatosVME.QuitaFoto(Lista: TStringList; Fotos: TListView);
var i: Integer;
begin
  Fotos.Items.BeginUpdate;
  for I := Fotos.Items.Count - 1 downto 0 do begin
    if Fotos.Items[i].Selected then begin
      Lista.Add(TNodoFoto(Fotos.Items[i].Data).Ubicacion);
 
      cdsFotos.First;
      while not cdsFotos.Eof do begin
        if cdsFotos.FieldByName('veh_fotos').AsString = TNodoFoto(Fotos.Items[i].Data).Nombre then begin
          cdsFotos.Delete;
          Exit;
        end;
 
        cdsFotos.Next;
      end;
 
      Fotos.Selected.Delete;
    end;
  end;
  Fotos.Items.EndUpdate;
end;

Hasta ahora agrega a la lista (TStringList) correctamente todos los items seleccionado, pero al borrar me borra todos, he intentado usar las siguientes propiedades:

delphi

Fotos.Items[i].Delete;
Fotos.SelectedItems;
Fotos.Items.Delete();

Todas con el mimo resultado.

 

¿Alguna idea?

[Agustin Ortu]

No, el problema no es que te borra todos. Estas saliendo de tu procedimiento sin ejecutar Fotos.Items.EndUpdate;

 

Refactorizando: 

delphi

procedure TFDatosVME.QuitaFoto(Lista: TStringList; Fotos: TListView);
var
  i: Integer;
begin
  Fotos.Items.BeginUpdate;
  try
    for i := Fotos.Items.Count - 1 downto 0 do
    begin
      if Fotos.Items[i].Selected then
      begin
        Lista.Add(TNodoFoto(Fotos.Items[i].Data).Ubicacion);
 
        cdsFotos.First;
        while not cdsFotos.Eof do
        begin
          if cdsFotos.FieldByName('veh_fotos').AsString = TNodoFoto(Fotos.Items[i].Data).Nombre then
          begin
            Fotos.Items[i].Delete;
            cdsFotos.Delete;
            Exit;
          end;
 
          cdsFotos.Next;
        end;
      end;
    end;
  finally
    Fotos.Items.EndUpdate;
  end;
end;

[Agustin Ortu]

Aunque yo escribiria el mismo codigo asi:
 

delphi

procedure TFDatosVME.QuitaFoto(Lista: TStringList; Fotos: TListView);
var
  i: Integer;
begin
  Fotos.Items.BeginUpdate;
  try
    for i := Fotos.Items.Count - 1 downto 0 do
    begin
      if not Fotos.Items[i].Selected then
        Continue;
 
      Lista.Add(TNodoFoto(Fotos.Items[i].Data).Ubicacion);
 
      if cdsFotos.Locate('veh_fotos', TNodoFoto(Fotos.Items[i].Data).Nombre, [loCaseInsensitive]) then
      begin
        Fotos.Items[i].Delete;
        cdsFotos.Delete;
        Exit;
      end;
    end;
  finally
    Fotos.Items.EndUpdate;
  end;
end;

[enecumene]

Ah Caray, me ha funcionado!, gracias amigo, tengo la manía de usar try..finally en otras situaciones específicas y me olvido que sirve para cualquier momento.

 

Saludos.

[Agustin Ortu]

El try-finally es una de las cosas que mas me gusta y mas he aprendido a explotar de Delphi

 

Recomiendo este video en donde se explica como simplificar loops para conseguir el mismo efecto y sin tanto anidamiento