Detectado javascript desactivado

Tienes el javascript desactivado en este momento. Muchas funciones podrían no funcionar. Por favor reactiva el javascript para obtener una funcionalidad completa.

Número de serie de una unidad de disco USB

Comenzado por escafandra , oct 23 2016 12:19

Por favor identifícate para responder

8 respuestas en este tema

#1 escafandra

Advanced Member

Administrador
4.111 mensajes

LocationMadrid - España

Escrito 23 octubre 2016 - 12:19

Obtener el número de serie de una unidad USB es un tema buscado en las redes y muy mal documentado. En principio podríamos suponer que la tarea puede hacerse fácilmente con DeviceIoControl IOCTL_STORAGE_GET_MEDIA_SERIAL_NUMBER, pero la realidad es que falla para las unidades de disco USB. cHackAll escribió hace unos años un código que se basaba el leer el registro para encontrar esa información, pero en los actuales S.O. no funciona correctamente. Con motivo de una pregunta en CD, me acordé del antiguo código de cHackAll y me propuse revisar el tema. El código que propongo se basa en la lectura del registro y en verificar si la unidad está "pinchada" en nuestro PC.

El código está probado en WinXP y Win10.

En realidad es una información muy poco útil salvo para aquellos que quieran proteger sus creaciones con una mochila basada en un pendrive.

Este es el código:

delphi

var
 Device: ShortString;
 ValueName: array [0..15] of Char = '\DosDevices\\:';
 
 
const
 IOCTL_VOLUME_GET_VOLUME_DISK_EXTENTS  = $00560000;
 
// Encuentra el número de disco físico que corresponde a una letra de unidad
function GetPhysicalNumOfDrive(Volume: Char): integer;
var
  hFile: THandle;
  Vde: array [0..56] of BYTE;   // VOLUME_DISK_EXTENTS
  BytesReturned: Cardinal;
begin
  Result:= -1;
  hFile:= CreateFile(PAnsiChar('\\.\' + Volume + ':'),0,0,nil, OPEN_EXISTING, 0, 0);
  if hFile <> INVALID_HANDLE_VALUE then
  begin
    if DeviceIoControl(hFile, IOCTL_VOLUME_GET_VOLUME_DISK_EXTENTS, nil, 0, @Vde, SizeOf(Vde), BytesReturned, nil) then
      Result:= PBYTE(DWORD(@Vde)+8)^;
    CloseHandle(hFile);
  end;
end;
 
// Encuentra el número de serie de una letra de unidad para Win10
function GetUSBSerial10(Drive: Char; var SerialNumber: ShortString): LongBool;
var
  hKey: Windows.HKEY;
  Device: ShortString;
  ValueName: array [0..15] of Char;
  Index: Integer;
  Value: Char;
  Size: DWORD;
  i: integer;
  ValueType: DWORD;
begin
  ValueType:= 3;
  Size:= SizeOf(Device);
  Result := False;
  lstrcpy(ValueName, '\DosDevices\\:');
  ValueName[12] := Drive;
  RegOpenKey(HKEY_LOCAL_MACHINE, 'SYSTEM\MountedDevices', hKey);
  i:= RegQueryValueEx(hKey, @ValueName, nil, @ValueType{REG_BINARY}, @Device, @Size);
  RegCloseKey(hKey);
  if i = 0 then
  begin
    i:= SizeOf(Device);
    repeat  dec(i); until Device[i] = '&';  Device[i]:= #0;
    repeat  dec(i); until Device[i] = '#';
    Index := 1;
    repeat
      Value := Device[i + Index * 2];
      SerialNumber[Index]:= Value;
      inc(Index);
    until Value = #0;
    SerialNumber[0]:= CHAR(lstrlen(@SerialNumber[1]));
    Result:= SerialNumber[1] <> #0;
  end;
end;
 
// Modificado del código de cHackAll
function Search(hParent: HKEY; var SubKey: ShortString): LongBool;
var
 hChild: HKEY;
 Index: Cardinal;
 Data: ShortString;
 Size: DWORD;
 ValueType: DWORD;
begin
 ValueType:= 1; //REG_SZ
 Size:= SizeOf(Device);
 Index := 0;
 RegOpenKey(hParent, @SubKey[1], hChild);
 RegQueryValueEx(hChild, 'ParentIdPrefix', nil, @ValueType, @Data[0], @Size);
 Result := not LongBool(lstrcmp(@Data, @Device));
 while not Result and (RegEnumKey(hChild, Index, @SubKey[1], SizeOf(SubKey) - 1) = ERROR_SUCCESS) do
  begin
   Result := Search(hChild, SubKey);
   Inc(Index);
  end;
 RegCloseKey(hChild);
end;
 
// Modificado del código de cHackAll
function usbGetSerial(Drive: Char; var SerialNumber: ShortString): LongBool;
var
 lpSerialNumber: PChar;
 hKey: Windows.HKEY;
 Index: Integer;
 Value: Char;
 Size: DWORD;
 i: integer;
 ValueType: DWORD;
begin
 ValueType:= 3;
 Size:= SizeOf(Device);
 Result := False;
 ValueName[12] := Drive;
 i:= RegOpenKey(HKEY_LOCAL_MACHINE, 'SYSTEM\MountedDevices', hKey);
 RegQueryValueEx(hKey, @ValueName, nil, @ValueType{REG_BINARY}, @Device, @Size);
 RegCloseKey(hKey);
 
 Index := 0;
 repeat if Device[(Index + 3) * 2 + 54] <> '#' then
  Value := Device[Index * 2 + 54] else Value := #0;
  Device[Index] := Value;
  Inc(Index);
 until Value = #0;
 SerialNumber[0] := #0;
 lstrcpy(@SerialNumber[1], 'SYSTEM\CurrentControlSet\Enum\USBSTOR');
 if (Device[0] <> #0) and Search(HKEY_LOCAL_MACHINE, SerialNumber) then
  begin
   lpSerialNumber := @SerialNumber[1];
   repeat Inc(SerialNumber[0]);
    Inc(lpSerialNumber);
    if lpSerialNumber[0] = '&' then
     lpSerialNumber[0] := #0;
   until lpSerialNumber[0] = #0;
   Result := True;
  end;
end;
 
function GetSOVersion: integer;
var
  VerInfo: TOSVersioninfo;
begin
  VerInfo.dwOSVersionInfoSize:= SizeOf(TOSVersionInfo);
  GetVersionEx(VerInfo);
  Result:= VerInfo.dwMajorVersion; // 5 es XP, mayor vista...
end;
 
function GetUSBSerial(Drive: Char; var SerialNumber: ShortString): LongBool;
begin
  if(GetSOVersion > 5) then
    Result:= GetUSBSerial10(Drive, SerialNumber)
  else
    Result:= usbGetSerial(Drive, SerialNumber);
end;

Y un ejemplo de uso:

delphi

procedure TForm1.Edit1KeyPress(Sender: TObject; var Key: Char);
var
  SerialNumber: ShortString;
begin
  Edit1.Text:='';
  Label1.Caption:= '';
  if GetPhysicalNumOfDrive(Key) <> -1 then
  begin
    GetUSBSerial(Key, SerialNumber);
    Label1.Caption:= SerialNumber;
  end
  else MessageBox(Handle, 'Unmounted drive', 'Error', MB_ICONEXCLAMATION);
end;

Subo un proyecto completo con el ejemplo.

Saludos.

Archivos adjuntos

GetUSBSerial.rar 161,08KB 50 descargas

5

Volver arriba

#2 FerCastro

Advanced Member

Miembro Platino
637 mensajes

LocationCiudad de México

Escrito 24 octubre 2016 - 10:45

Mi estimado Escafandra, aplausos!! y me paro de pié.

Eres un master, muchas gracias por este codigo.

0

Volver arriba

#3 egostar

missing my father, I love my mother.

Administrador
14.460 mensajes

LocationMéxico

Escrito 24 octubre 2016 - 11:46

Como siempre un código de mucha utilidad, muchas gracias amigo. (y)

Saludos

0

Volver arriba

#4 escafandra

Advanced Member

Administrador
4.111 mensajes

LocationMadrid - España

Escrito 25 octubre 2016 - 05:18

Por si fuera de interés, os muestro otra forma de obtener el número de serie que también trabaja con HD pero que no me convence porque no encuentra los números de serie USB en WinXP en las memorias que he probado y en Win10, al menos en una de ellas, cambia el último dígito del mismo al compararlo con el dato encontrado en el registro de Windows.

delphi

const
  IOCTL_STORAGE_QUERY_PROPERTY = $2D1400;
 
type
PSTORAGE_DEVICE_DESCRIPTOR = ^STORAGE_DEVICE_DESCRIPTOR;
STORAGE_DEVICE_DESCRIPTOR = packed record
  Version: ULONG;
  Size: ULONG;
  DeviceType: UCHAR;
  DeviceTypeModifier: UCHAR;
  RemovableMedia: Boolean;
  CommandQueueing: Boolean;
  VendorIdOffset: ULONG;
  ProductIdOffset: ULONG;
  ProductRevisionOffset: ULONG;
  SerialNumberOffset: ULONG;
  BusType: ULONG;
  RawPropertiesLength: ULONG;
  RawDeviceProperties: array[0..0] of UCHAR;
end;
 
PSTORAGE_PROPERTY_QUERY = ^STORAGE_PROPERTY_QUERY;
STORAGE_PROPERTY_QUERY = record
  PropertyId: DWORD;     // StorageDeviceProperty = 0
  QueryType: DWORD;      // PropertyStandardQuery = 0
  AdditionalParameters: array[0..0] of UCHAR;
end;
 
function GetSerialNumber(Volume: Char; var SerialNumber: string): BOOL;
var
  hFile: THANDLE;
  SPQ: STORAGE_PROPERTY_QUERY;
  SDD: STORAGE_DEVICE_DESCRIPTOR;
  PSDD: PSTORAGE_DEVICE_DESCRIPTOR;
  Size: DWORD;
begin
  Result:= FALSE;
  SerialNumber:= '';
  hFile:= CreateFile(PAnsiChar('\\.\' + Volume + ':'),0,0,nil, OPEN_EXISTING, 0, 0);
  if hFile <> INVALID_HANDLE_VALUE then
  begin
    ZeroMemory(@SPQ, sizeof(SPQ));
    if DeviceIoControl(hFile, IOCTL_STORAGE_QUERY_PROPERTY, @SPQ, sizeof(SPQ), @SDD, sizeof(SDD), Size, nil) then
    begin
      PSDD:= VirtualAlloc(nil, SDD.Size, MEM_COMMIT, PAGE_READWRITE);
      ZeroMemory(PSDD, SDD.Size);
      if DeviceIoControl(hFile, IOCTL_STORAGE_QUERY_PROPERTY, @SPQ, sizeof(SPQ), PSDD, SDD.Size, Size, nil) then
      begin
        if PSDD.SerialNumberOffset <> 0 then
          SerialNumber:= String(PCHAR(PSDD) + PSDD.SerialNumberOffset);
      end;
      VirtualFree(PSDD, 0, MEM_RELEASE);    
    end;
    CloseHandle(hFile);
  end;
  Result:= Length(SerialNumber) <> 0;
end;

Saludos.

2

Volver arriba

#5 cram

Advanced Member

Miembro Platino
832 mensajes

LocationMisiones, Argentina

Escrito 26 octubre 2016 - 07:25

Muchas gracias por semejante aporte.

Es de gran utilidad, tanto para estudio como para aplicación.

Saludos Maestro!!

0

Volver arriba

#6 jmonfor

Member

Miembros
20 mensajes

Escrito 06 noviembre 2016 - 03:35

Impresionante. Realmente te das cuenta de cúanto hay por aprender... y en este foro sois todos unos fenómenos!!!

Muchas gracias por el aporte!!!

Saludos :ap:

0

Volver arriba

#7 monchito_elroro

Advanced Member

Miembros
260 mensajes

Escrito 14 noviembre 2016 - 01:24

Muchas gracias amigo Escafranda por compartir un excelente aporte, lo acabo de probar en lazarus y trabaja sin problemas, también quería comentar que le he agreado unos códigos para detectar también los seriales para los disco duros (Fijos y USB mediante la letra de su unidad) acontinuación les comparto el enlace para que lo bajen:

http://www.mediafire...ial Lazarus.zip

Quisiera también hacer una consulta si se puede al Amigo escafranda:
Lo que pasa es que en el caso del código que agregue para los seriales de los discos duros, si en caso estos discos son formateados los seriales cambian por unos nuevos, al menos eso fue lo que leí por ahí.
Mi pregunta es si en caso el USB lo llevo a otra pc, me dará el mismo serial que me dio al principio ? Pues probe formateando el usb y aún así me da el mismo serial, lo cual es perfecto, pero también quisiera saber si al conectarlo a otra computadora me seguirá dando el mismo serial o me dará uno nuevo.

Esperando su respuesta me despido amigos

0

Volver arriba

#8 escafandra

Advanced Member

Administrador
4.111 mensajes

LocationMadrid - España

Escrito 14 noviembre 2016 - 03:39

El problema es que la API GetVolumeInformation no devuelve el número de serie del fabricante sino el del formateo y varía si vuelves a formatear.

GetVolumeInformation function

lpVolumeSerialNumber [out, optional]

A pointer to a variable that receives the volume serial number.
This parameter can be NULL if the serial number is not required.
This function returns the volume serial number that the operating system assigns when a hard disk is formatted. To programmatically obtain the hard disk's serial number that the manufacturer assigns, use the Windows Management Instrumentation (WMI) Win32_PhysicalMedia property SerialNumber.

El código que expuse para USB devuelve en número de serie del fabricante del pendrive y el de este mensaje, sirve para HD y USB aunque falla en bastantes USB, tambien devuelve el número de serie del fabricante. El segundo enlace está más indicado para HD aunque es posible que en algunos falle.

Saludos.

0

Volver arriba

#9 monchito_elroro

Advanced Member

Miembros
260 mensajes

Escrito 14 noviembre 2016 - 02:32

Muchas gracias amigo escafranda por su respuesta

siguiendo sus sugerencias he agregado el código que también compartió para los discos duros, en el camino me salió un par de errores, pero pude solucionarlos siguiendo sus consejos de proyectos anteriores, ahora le mando como estoy usando su código amigo: (por favor corregirme si es necesario)

delphi

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;
 
type
 
  { TForm1 }
 
  TForm1 = class(TForm)
    Edit2: TEdit;
    Label1: TLabel;
    Edit1: TEdit;
    Label2: TLabel;
    Label3: TLabel;
    procedure Button1Click(Sender: TObject);
    procedure Edit1KeyPress(Sender: TObject; var Key: Char);
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;
 
function  StrStrI(s1: PCHAR; s2: PCHAR): PCHAR; stdcall; external 'Shlwapi.dll' name 'StrStrIA';
 
var
  Form1: TForm1;
 
implementation
{$R *.lfm}
 
var
 Device: ShortString;
 ValueName: array [0..15] of Char = '\DosDevices\\:';
 
 
const
 IOCTL_VOLUME_GET_VOLUME_DISK_EXTENTS  = $00560000;
 IOCTL_STORAGE_QUERY_PROPERTY = $2D1400;
 
 type
PSTORAGE_DEVICE_DESCRIPTOR = ^STORAGE_DEVICE_DESCRIPTOR;
STORAGE_DEVICE_DESCRIPTOR = packed record
  Version: ULONG;
  Size: ULONG;
  DeviceType: UCHAR;
  DeviceTypeModifier: UCHAR;
  RemovableMedia: Boolean;
  CommandQueueing: Boolean;
  VendorIdOffset: ULONG;
  ProductIdOffset: ULONG;
  ProductRevisionOffset: ULONG;
  SerialNumberOffset: ULONG;
  BusType: ULONG;
  RawPropertiesLength: ULONG;
  RawDeviceProperties: array[0..0] of UCHAR;
end;
 
PSTORAGE_PROPERTY_QUERY = ^STORAGE_PROPERTY_QUERY;
STORAGE_PROPERTY_QUERY = record
  PropertyId: DWORD;     // StorageDeviceProperty = 0
  QueryType: DWORD;      // PropertyStandardQuery = 0
  AdditionalParameters: array[0..0] of UCHAR;
end;
 
// encuentra el serial del disco duro físico
function GetSerialNumber(Volume: Char; var SerialNumber: string): BOOL;
var
  hFile: THANDLE;
  SPQ: STORAGE_PROPERTY_QUERY;
  SDD: STORAGE_DEVICE_DESCRIPTOR;
  PSDD: PSTORAGE_DEVICE_DESCRIPTOR;
  Size: DWORD;
begin
  Result:= FALSE;
  SerialNumber:= '';
  hFile:= CreateFile(PAnsiChar('\\.\' + Volume + ':'),0,0,nil, OPEN_EXISTING, 0, 0);
  if hFile <> INVALID_HANDLE_VALUE then
  begin
    ZeroMemory(@SPQ, sizeof(SPQ));
    if DeviceIoControl(hFile, IOCTL_STORAGE_QUERY_PROPERTY, @SPQ, sizeof(SPQ), @SDD, sizeof(SDD), Size, nil) then
    begin
      PSDD:= VirtualAlloc(nil, SDD.Size, MEM_COMMIT, PAGE_READWRITE);
      ZeroMemory(PSDD, SDD.Size);
      if DeviceIoControl(hFile, IOCTL_STORAGE_QUERY_PROPERTY, @SPQ, sizeof(SPQ), PSDD, SDD.Size, Size, nil) then
      begin
 
        if PSDD^.SerialNumberOffset <> 0 then
          SerialNumber:= String(PCHAR(PSDD) + PSDD^.SerialNumberOffset);
      end;
      VirtualFree(PSDD, 0, MEM_RELEASE);
    end;
    CloseHandle(hFile);
  end;
  Result:= Length(SerialNumber) <> 0;
end;
 
// Encuentra el número de disco físico que corresponde a una letra de unidad
function GetPhysicalNumOfDrive(Volume: Char): integer;
var
  hFile: THandle;
  Vde: array [0..56] of BYTE;   // VOLUME_DISK_EXTENTS
  BytesReturned: Cardinal;
begin
  Result:= -1;
  hFile:= CreateFile(PAnsiChar('\\.\' + Volume + ':'),0,0,nil, OPEN_EXISTING, 0, 0);
  if hFile <> INVALID_HANDLE_VALUE then
  begin
    if DeviceIoControl(hFile, IOCTL_VOLUME_GET_VOLUME_DISK_EXTENTS, nil, 0, @Vde, SizeOf(Vde), BytesReturned, nil) then
      Result:= PBYTE(DWORD(@Vde)+8)^;
    CloseHandle(hFile);
  end;
end;
 
// Encuentra el número de serie de una letra de unidad para Win10
function GetUSBSerial10(Drive: Char; var SerialNumber: ShortString): LongBool;
var
  hKey: Windows.HKEY;
  Device: ShortString;
  ValueName: array [0..15] of Char;
  Index: Integer;
  Value: Char;
  Size: DWORD;
  i: integer;
  ValueType: DWORD;
begin
  ValueType:= 3;
  Size:= SizeOf(Device);
  Result := False;
  lstrcpy(ValueName, '\DosDevices\\:');
  ValueName[12] := Drive;
  RegOpenKey(HKEY_LOCAL_MACHINE, 'SYSTEM\MountedDevices', hKey);
  i:= RegQueryValueEx(hKey, @ValueName, nil, @ValueType{REG_BINARY}, @Device, @Size);
  RegCloseKey(hKey);
  if i = 0 then
  begin
    i:= SizeOf(Device);
    repeat  dec(i); until Device[i] = '&';  Device[i]:= #0;
    repeat  dec(i); until Device[i] = '#';
    Index := 1;
    repeat
      Value := Device[i + Index * 2];
      SerialNumber[Index]:= Value;
      inc(Index);
    until Value = #0;
    SerialNumber[0]:= CHAR(lstrlen(@SerialNumber[1]));
    Result:= SerialNumber[1] <> #0;
    //Result:= Length(SerialNumber) <> 0;
  end;
end;
 
// Modificado del código de cHackAll
function Search(hParent: HKEY; var SubKey: ShortString): LongBool;
var
 hChild: HKEY;
 Index: Cardinal;
 Data: ShortString;
 Size: DWORD;
 ValueType: DWORD;
begin
 ValueType:= 1; //REG_SZ
 Size:= SizeOf(Device);
 Index := 0;
 RegOpenKey(hParent, @SubKey[1], hChild);
 RegQueryValueEx(hChild, 'ParentIdPrefix', nil, @ValueType, @Data[0], @Size);
 Result := not LongBool(lstrcmp(@Data, @Device));
 while not Result and (RegEnumKey(hChild, Index, @SubKey[1], SizeOf(SubKey) - 1) = ERROR_SUCCESS) do
  begin
   Result := Search(hChild, SubKey);
   Inc(Index);
  end;
 RegCloseKey(hChild);
end;
 
// Modificado del código de cHackAll
function usbGetSerial(Drive: Char; var SerialNumber: ShortString): LongBool;
var
 lpSerialNumber: PChar;
 hKey: Windows.HKEY;
 Index: Integer;
 Value: Char;
 Size: DWORD;
 i: integer;
 ValueType: DWORD;
begin
 ValueType:= 3;
 Size:= SizeOf(Device);
 Result := False;
 ValueName[12] := Drive;
 i:= RegOpenKey(HKEY_LOCAL_MACHINE, 'SYSTEM\MountedDevices', hKey);
 RegQueryValueEx(hKey, @ValueName, nil, @ValueType{REG_BINARY}, @Device, @Size);
 RegCloseKey(hKey);
 
 Index := 0;
 repeat if Device[(Index + 3) * 2 + 54] <> '#' then
  Value := Device[Index * 2 + 54] else Value := #0;
  Device[Index] := Value;
  Inc(Index);
 until Value = #0;
 SerialNumber[0] := #0;
 lstrcpy(@SerialNumber[1], 'SYSTEM\CurrentControlSet\Enum\USBSTOR');
 if (Device[0] <> #0) and Search(HKEY_LOCAL_MACHINE, SerialNumber) then
  begin
   lpSerialNumber := @SerialNumber[1];
   repeat Inc(SerialNumber[0]);
    Inc(lpSerialNumber);
    if lpSerialNumber[0] = '&' then
     lpSerialNumber[0] := #0;
   until lpSerialNumber[0] = #0;
   Result := True;
  end;
end;
 
function GetSOVersion: integer;
var
  VerInfo: TOSVersioninfo;
begin
  VerInfo.dwOSVersionInfoSize:= SizeOf(TOSVersionInfo);
  GetVersionEx(VerInfo);
  Result:= VerInfo.dwMajorVersion; // 5 es XP, mayor vista...
end;
 
function GetUSBSerial(Drive: Char; var SerialNumber: ShortString): LongBool;
begin
  if(GetSOVersion > 5) then
    Result:= GetUSBSerial10(Drive, SerialNumber)
  else
    Result:= usbGetSerial(Drive, SerialNumber);
end;
 
function GetHardDiskSerial(const DriveLetter: Char): string;
var
  NotUsed:     DWORD;
  VolumeFlags: DWORD;
  VolumeInfo:  array[0..MAX_PATH] of Char;
  VolumeSerialNumber: DWORD;
begin
  GetVolumeInformation(PChar(DriveLetter + ':\'),
    nil, SizeOf(VolumeInfo), @VolumeSerialNumber, NotUsed,
    VolumeFlags, nil, 0);
  {Result := Format('Label = %s   VolSer = %8.8X',
    [VolumeInfo, VolumeSerialNumber])}
  Result := IntToStr(VolumeSerialNumber);
end;
 
function GetVolumeID(DriveChar: Char): String;
//Para obtener el # de serie de un disco
var
  MaxFileNameLength, VolFlags, SerNum: DWord;
  DrivePath : String;
begin
  DrivePath :=  DriveChar + ':\';
  if GetVolumeInformation(PChar(DrivePath), nil, 0,
     @SerNum, MaxFileNameLength, VolFlags, nil, 0)
  then
  begin
      Result := IntToStr(SerNum);
  end
  else
      Result := '';
End;
 
// EN ESTA PARTE LLAMAMOS A LA FUNCION
procedure TForm1.Edit1KeyPress(Sender: TObject; var Key: Char);
var
  SerialNumber: ShortString;
  SerialNumber2: string;
begin
  Edit1.Text:='';
  Label1.Caption:= '';
  if GetPhysicalNumOfDrive(Key) <> -1 then  // si hay una letra escrita hacer
  begin
    case GetDriveType(PChar(Key + ':\')) of
     DRIVE_REMOVABLE:
       begin
       GetUSBSerial(Key, SerialNumber);
       Label1.Caption:= SerialNumber;
       Edit2.Text:=SerialNumber;
       end;
     DRIVE_FIXED:
       begin
       //Label1.Caption:=GetHardDiskSerial(Key);  // obtener serial volumen 1
       //Label1.Caption:=GetVolumeID(Key);  // obtener serial volumen 2
       GetSerialNumber(Key, SerialNumber2);
       Label1.Caption:=SerialNumber2;
       Edit2.Text:=SerialNumber2;
       end;
    end;
  end
  else MessageBox(Handle, 'Unmounted drive', 'Error', MB_ICONEXCLAMATION);
end;
 
procedure TForm1.Button1Click(Sender: TObject);
begin
 
end;
 
procedure TForm1.FormCreate(Sender: TObject);
begin
 
end;
 
end.

Le comento que de momento me esta funcionando excelente

ahora ya me detecta los números de series del fabricante del disco duro, muchas gracias amigo, también quisiera compartirles mis seriales que en mi caso me detecta:

disco duro fijo laptop seagate (500gb):             SBY5DGCY
disco duro usb samgung (500gb):                     00000000011E0E20
memoria usb hp (16gb):                                    0416KK00000066840814

Cuando tenga tiempo los probaré en otras pcs, ahorita no tengo otra a la mano.

También voy a compartirles el proyecto que estoy usando, miles de gracias de nuevo al amigo Escafranda sus aportes son muy buenos

http://www.mediafire...USB - HDD 2.zip

.