2 respuestas en este tema

[escafandra]

Es posible que en nuestro archivo de recursos tengamos imágenes en formatos gráficos que no sean Bitmap (png, jpg...) y deseemos cargarlos como una imagen desde ese archivo.

 

Imaginemos que tenemos un archivo rc como este:

php

Imagen1 RCDATA "Imagen1.png"
Imagen2 RCDATA "Imagen2.jpg"

Y lo compilamos como un archivo.res para incluir en nuestro ejecutable.

 

Para extraer las imágenes podemos crear los archivos correspondientes o cargarlas directamente de memoria sin necesidad de un archivo intermedio. La forma de actuar con al API sería así:

delphi

uses
  Winapi.Windows, Winapi.ActiveX;
 
 
// GDI+ Flat API...
function  GdiplusStartup(var GdiToken: ULONG_PTR; Startup, Output: PBYTE): Cardinal; stdcall external 'gdiplus';
procedure GdiplusShutdown(GdiToken: ULONG_PTR); stdcall external 'gdiplus';
function  GdipCreateHBITMAPFromBitmap(GBitmap: THANDLE; var hBitmap: HBITMAP; BKColor: DWORD): DWORD; stdcall external 'gdiplus';
function  GdipCreateBitmapFromStream(stream: ISTREAM; var GBitmap: THANDLE): Cardinal; stdcall external 'gdiplus';
function  GdipDisposeImage(image: THANDLE): Cardinal; stdcall external 'gdiplus';
 
type
TGdiplusStartupInput = record
  GdiplusVersion: UINT32;
  DebugEventCallback: Pointer;
  SuppressBackgroundThread: BOOL;
  SuppressExternalCodecs: BOOL;
end;
 
 
implementation
{$R MiArchivo.res}
 
function CreateHBITMAPFromRCDATAResurce(FileName: PWCHAR):HBITMAP;
const
  RT_RCDATAW: PWCHAR = MakeIntResourceW(10);
var
  Res: HRSRC;
  Size: DWORD;
  hMem: HGLOBAL;
  pImage: Pointer;
  GBitmap: THANDLE;
  Stream: IStream;
  gdiplusToken: ULONG_PTR;
  GdiPlusStartupInput: TGdiplusStartupInput;
begin
  // Inicializamos GDI+.
  GdiPlusStartupInput.GdiplusVersion:= 1; GdiPlusStartupInput.DebugEventCallback:= nil;
  GdiPlusStartupInput.SuppressBackgroundThread:= FALSE; GdiPlusStartupInput.SuppressExternalCodecs:= FALSE;
  GdiplusStartup(gdiplusToken, @GdiPlusStartupInput, nil);
 
  Result:= 0;
  Res:= FindResourceW(0, FileName, RT_RCDATAW);//MAKEINTRESOURCEW(10));
  if Res <> 0 then
  begin
    Size:= SizeofResource(0, Res);
    hMem:= GlobalAlloc(GMEM_MOVEABLE, Size);
    pImage:= GlobalLock(hMem);
    CopyMemory(pImage, LockResource(LoadResource(0, Res)), Size);
    GlobalUnlock(hMem);
    CreateStreamOnHGlobal(hMem, true, Stream);
    GdipCreateBitmapFromStream(Stream, GBitmap);
    GdipCreateHBITMAPFromBitmap(GBitmap, Result, 0);
    GdipDisposeImage(GBitmap);
    GlobalFree(hMem);
  end;
  // Shutdown GDI+
  GdiplusShutdown(gdiplusToken);
end;

Y un ejemplo de uso:

delphi

begin
  Image1.Picture.Bitmap.Handle:= CreateHBITMAPFromRCDATAResurce('Imagen1');
end;

El ejemplo está desarrollado con Berlin pero funciona en delphi7

 

¿Por qué usar la API pura y GDI+ Flat? Para economizar recursos y tamaño del ejecutable cuando eso sea lo que prime.

 

 

 

Saludos.

[escafandra]

El mismo truco en C/C++:
 

cpp

#include <windows.h>
 
#pragma link "Gdiplus.lib"
#pragma resource "MiArchivo.res"
 
extern "C" {
DWORD WINAPI GdiplusStartup(ULONG_PTR *hToken, void *input, void *Output);
void  WINAPI GdiplusShutdown(ULONG_PTR token);
DWORD WINAPI GdipCreateBitmapFromHBITMAP(HBITMAP hBmp, HPALETTE hPal, HANDLE* GBitmap);
DWORD WINAPI GdipCreateHBITMAPFromBitmap(HANDLE Bmp, HBITMAP* hBmp, DWORD BKColor);
DWORD WINAPI GdipCreateFromHDC(HDC hDC, HANDLE* hGraphics);
DWORD WINAPI GdipDisposeImage(HANDLE hImage);
DWORD WINAPI GdipTranslateWorldTransform(HANDLE hGraphics, float sx, float sy, DWORD Order);
DWORD WINAPI GdipRotateWorldTransform(HANDLE hGraphics, float Angle, DWORD Order);
DWORD WINAPI GdipDrawImage(HANDLE hGraphics, HANDLE hImage, float sx, float sy);
DWORD WINAPI GdipDeleteGraphics(HANDLE hGraphics);
DWORD WINAPI GdipCreateBitmapFromFile(WCHAR* filename, HANDLE* bitmap);
DWORD WINAPI GdipCreateHBITMAPFromBitmap(HANDLE bitmap, HBITMAP* hBitmap, DWORD BKColor);
//DWORD WINAPI GdipCreateBitmapFromResource(HINSTANCE hInstance, WCHAR* lpBitmapName, HANDLE* GBitmap);
DWORD WINAPI GdipCreateBitmapFromStream(IStream* stream, HANDLE* GBitmap);
 
 
DWORD WINAPI GdipImageRotateFlip(HANDLE hImage, DWORD rfType);
}
 
TForm1 *Form1;
 
typedef struct {
  UINT32 GdiplusVersion;
  PVOID  DebugEventCallback;  //DebugEventProc
  BOOL   SuppressBackgroundThread;
  BOOL   SuppressExternalCodecs;
} GdiplusStartupInput;
 
HBITMAP CreateHBITMAPFromRCDATAResurce(PWCHAR FileName)
{
  PWCHAR RT_RCDATAW = MAKEINTRESOURCEW(10);
  HBITMAP hBitmap = 0;
  HANDLE GBitmap = 0;
  IStream* Stream;
  ULONG_PTR  gdiplusToken;
  GdiplusStartupInput gdiplusStartupInput = {0};
  gdiplusStartupInput.GdiplusVersion = 1;
  if(GdiplusStartup(&gdiplusToken, &gdiplusStartupInput, NULL)) return 0;
 
  HRSRC Res = FindResourceW(0, FileName, RT_RCDATAW);//MAKEINTRESOURCEW(10));
  if(Res){
    DWORD Size = SizeofResource(0, Res);
    HGLOBAL hMem = ::GlobalAlloc(GMEM_MOVEABLE, Size);
    LPVOID pImage = ::GlobalLock(hMem);
    CopyMemory(pImage, LockResource(LoadResource(0, Res)), Size);
    ::GlobalUnlock(hMem);
    ::CreateStreamOnHGlobal(hMem, true, &Stream);
    GdipCreateBitmapFromStream(Stream, &GBitmap);
    GdipCreateHBITMAPFromBitmap(GBitmap, &hBitmap, 0);
    GdipDisposeImage(GBitmap);
    //GlobalFree(hMem);
    Stream->Release();
  }
 
  //shutdown GDI+
  GdiplusShutdown(gdiplusToken);
 
  return hBitmap;
}

 Y la forma de uso:

cpp

Image1->Picture->Bitmap->Handle = CreateHBITMAPFromRCDATAResurce(L"Imagen1");

Saludos.

[ELKurgan]

Muy buen código. como siempre

 

Gracias por el aporte