Detectado javascript desactivado

Tienes el javascript desactivado en este momento. Muchas funciones podrían no funcionar. Por favor reactiva el javascript para obtener una funcionalidad completa.

Exportar un DataSet a Excel

Comenzado por enecumene , ene 06 2017 10:02

Por favor identifícate para responder

13 respuestas en este tema

#1 enecumene

Webmaster

Administrador
7.419 mensajes

LocationRepública Dominicana

Escrito 06 enero 2017 - 10:02

Aquí dejo cómo podemos exportar el resultado de un DataSet a un Archivo Excel, para quien le pueda ser útil, en mi caso utilicé el TFDQuery, pero es aplicable para cualquier otro, el código incluye una barra de progreso:

delphi

procedure TFInvGeneral.exportToExcel(AData: TFDQuery; AProgreso: TProgressBar);
    procedure ProgressBarInit;
    begin
      AProgreso.Max := AData.RecordCount;
      AProgreso.Position := 0;
      AProgreso.Visible := True;
    end;
 
var ExcelApp, Libro: Variant;
    fila, i:integer;
  	Columnas: TStringList;
begin
 
  Columnas := TStringList.Create;
  Columnas.Add('Código');
  Columnas.Add('Referencia');
  Columnas.Add('Insumo/Pieza');
  Columnas.Add('Marca');
  Columnas.Add('Existencia');
  Columnas.Add('Condición');
  Columnas.Add('Area');
  Columnas.Add('Costo');
 
  //svGuardar es un SaveDialog para poder especificar la ruta del archivo
  svGuardar.Title := 'Exportando Reporte a Excel';
  svGuardar.DefaultExt := '*.xlsx';
 
  svGuardar.Filter := 'Archivos Excel (*.xls,*.xlsx)|*.xls;*.xlsx';
  svGuardar.FilterIndex := 1;
 
  try
    svGuardar.Execute;
    if (svGuardar.FileName <> '') then
      begin
      // Comprobar si existe el component TProgressBar
      if (AProgreso <> nil) then
        ProgressBarInit;
 
      //Deshabilitamos los controles
      AData.DisableControls;
 
      //Creamos el archivo Excel
      ExcelApp := CreateOleObject('Excel.Application');
 
      //Evitamos mostrar las alertas propias de Excel
      ExcelApp.DisplayAlerts := false;
 
      // Añadimos una Hoja
      ExcelApp.WorkBooks.Add();
 
      // Colocamos el Nombre de la Hoja
      ExcelApp.WorkBooks[1].ActiveSheet.Name := 'Inventario';
 
      // Activamos la hoja la cual trabajaremos
      Libro := ExcelApp.WorkBooks[1].ActiveSheet;
 
      // Orientación de página
      //1 - Vertical y 2 - Horizontal
      Libro.PageSetup.Orientation := 1;
 
      //Agregamos la primera fila con la cabecera
      for i:= 0 to Columnas.count - 1 do
      begin
        Libro.Cells[1,i+1] := Columnas.Strings[i];
        Libro.Cells[1,i+1].Font.Bold := True;
        Libro.Cells[1,i+1].font.Size := 12;
        Libro.Cells[1,i+1].font.Color := clWhite;
        Libro.Cells[1,i+1].Interior.Color := clGray ;
        Libro.Cells[1,i+1].HorizontalAlignment := -4108; //-4108 corresponde al centralizado del texto
      end;
 
    // Ahora cargaremos los datos
 
    //Empezamos desde la segunda fila
    //Recordar que la primera es la cabecera
    fila := 2;
 
    //Lo dejamos en Segundo Plano
    ExcelApp.Visible := False;
 
    AData.First;
    while not AData.eof do begin
      //Código
      Libro.Cells[fila,1].NumberFormat := '0';
      Libro.Cells[fila,1] := AData.FieldByName('INS_ID').AsInteger;
 
      //Referencia
      Libro.Cells[fila,2].NumberFormat := RPad('0', '0', Length(AData.FieldByName('INS_REF').AsString));
      Libro.Cells[fila,2] := AData.FieldByName('INS_REF').AsString;
 
      //Insumo/Pieza
      Libro.Cells[fila,3].NumberFormat := RPad('0', '0', Length(AData.FieldByName('INS_NOMBRE').AsString));
      Libro.Cells[fila,3] := AData.FieldByName('INS_NOMBRE').AsString;
 
      //Marca
      Libro.Cells[fila,4].NumberFormat := RPad('0', '0', Length(AData.FieldByName('INS_MARCA').AsString));
      Libro.Cells[fila,4] := AData.FieldByName('INS_MARCA').AsString;
 
      //Existencia
      Libro.Cells[fila,5].NumberFormat := '0.00';
      Libro.Cells[fila,5] := AData.FieldByName('INS_EXISTENCIA').asFloat;
 
      //Condicion
      Libro.Cells[fila,6].NumberFormat := RPad('0', '0', Length(getCondicion(AData.FieldByName('INS_CONDICION').AsInteger)));
      Libro.Cells[fila,6] := getCondicion(AData.FieldByName('INS_CONDICION').AsInteger);
 
      //Area
      Libro.Cells[fila,7].NumberFormat := RPad('0', '0', Length(getArea(AData.FieldByName('INS_AREA').AsInteger)));
      Libro.Cells[fila,7] := getArea(AData.FieldByName('INS_AREA').AsInteger);
 
      //Costo
      Libro.Cells[fila,8].NumberFormat := '0.00';
      Libro.Cells[fila,8] := AData.FieldByName('INS_COSTE').AsFloat;
 
      //Autofijamos las columnas
      Libro.Cells.Columns.Autofit;
 
      //Siguiente Fila
      Inc(Fila);
 
      AProgreso.Position := AProgreso.Position + 1;
 
      AData.Next;
    end;
 
      AData.EnableControls;
 
      Libro.SaveAs(svGuardar.FileName);
 
      if AProgreso.Position = AData.RecordCount then begin
        MessageDLG('¡Se exportó correctamente!',mtInformation,[mbOk],0);
        ExcelApp.Visible := True;
      end;
    end; //if svGuardar.FileName <> ''
  except
    ExcelApp.Quit;
    AData.EnableControls;
    Showmessage('No se pudo crear el Archivo Excel.');
    raise;
  end;
 
    Columnas.Free;
end;

Saludos.

3

Volver arriba

#2 sir.dev.a.lot

Advanced Member

Miembros
545 mensajes

Location127.0.0.1

Escrito 06 enero 2017 - 06:00

delphi

function LPad(S: string; Ch: Char; Len: Integer): string;
var   RestLen: Integer;
begin   Result  := S;
  RestLen := Len - Length(s);
  if RestLen < 1 then Exit;
  Result := S + StringOfChar(Ch, RestLen);
end;
 
function RPad(S: string; Ch: Char; Len: Integer): string;
var   RestLen: Integer;
begin   Result  := S;
  RestLen := Len - Length(s);
  if RestLen < 1 then Exit;
  Result := StringOfChar(Ch, RestLen) + S;
end;

Para cual version de Delphi ?

delphi

function LPad(Value: string; Key: Char = ' '; ALenght: Integer = 0): string;
var
  iLen: Integer;
begin
  iLen := Length(Value);
 
  if (iLen > ALenght) then
    Result := Copy(Value, 1, ALenght)
  else
    Result := StringOfChar(Key, ALenght-iLen) + Value;
end;
 
function LPad(Value: Integer; Key: Char = '0'; ALenght: Integer = 0): string;
begin
  Result := LPad(IntToStr(Value), Key, ALenght);
end;
 
function RPad(Value: string; Key: Char = ' '; ALenght: Integer = 0): string;
var
  iLen: integer;
begin
  iLen  := Length(Value);
 
  if (iLen > ALenght) then
    Result := Copy(Value, 1, ALenght)
  else
     Result := Value + StringOfChar(Key, ALenght-iLen);
end;
 
function RPad(Value: integer; Key: Char = '0'; ALenght: Integer = 0): string;
begin
  Result := RPad(IntToStr(Value), Key, ALenght);
end;

Saludos!

0

Volver arriba

#3 Agustin Ortu

Advanced Member

Moderadores
831 mensajes

LocationArgentina

Escrito 07 enero 2017 - 01:08

...

Creo que te equivocaste de hilo

Editado por Agustin Ortu, 07 enero 2017 - 01:08 .

0

Volver arriba

#4 sir.dev.a.lot

Advanced Member

Miembros
545 mensajes

Location127.0.0.1

Escrito 07 enero 2017 - 04:48

Creo que te equivocaste de hilo

//Condicion

Libro.Cells[fila,6].NumberFormat := RPad('0', '0', Length(getCondicion(AData.FieldByName('INS_CONDICION').AsInteger)));

Libro.Cells[fila,6] := getCondicion(AData.FieldByName('INS_CONDICION').AsInteger);

Hola @

Agustin Ortu

La funcion RPad, esta en el Codigo de

enecumene

lo que no se si es una funcion que ya esta incluida en Berlin 10.1 o Tokyo, y escribi en mi POST Para cual version de Delphi ?

Saludos!

0

Volver arriba

#5 Marc

Advanced Member

Moderadores
1.484 mensajes

LocationMallorca

Escrito 07 enero 2017 - 05:57

Este código solo funciona cuando Excel está instalado en el equipo, ¿ verdad ? (crea un objeto OLE Excel.Application).

Personalmente prefiero exportar a CSV, que es tremendamente fácil de hacer y no depende de tener aplicaciones instaladas. Además, Excel lee perfectamente esos archivos CSV.

0

Volver arriba

#6 enecumene

Webmaster

Administrador
7.419 mensajes

LocationRepública Dominicana

Escrito 07 enero 2017 - 09:51

Este código solo funciona cuando Excel está instalado en el equipo, ¿ verdad ? (crea un objeto OLE Excel.Application).

Personalmente prefiero exportar a CSV, que es tremendamente fácil de hacer y no depende de tener aplicaciones instaladas. Además, Excel lee perfectamente esos archivos CSV.

Estás en lo cierto amigo Marc, así estaba en un principio, pero para el cliente le era tedioso utilizar el wizard de Excel al abrir arcivos CSV. 8o|

Saludos.

0

Volver arriba

#7 enecumene

Webmaster

Administrador
7.419 mensajes

LocationRepública Dominicana

Escrito 07 enero 2017 - 09:52

Sir.Dev.A.Lot, RPAD y LPAD son funciones creadas fuera de delphi, hasta XE7 delphi no cuenta con funciones similares, no sabría decirte en las versiones más recientes.

Saludos.

0

Volver arriba

#8 sir.dev.a.lot

Advanced Member

Miembros
545 mensajes

Location127.0.0.1

Escrito 09 enero 2017 - 07:50

Lo he probado en Delphi 7 y Seattle y no lo tiene por defecto.

Pero si vi algo asi que es lo equivalente.

delphi

program Project1;
{$APPTYPE CONSOLE}
 
var
  strA, strB     : String;
 
begin
  strA := '12345';
 
  strB := strA.PadLeft(7);
 
  Console.WriteLine('Default padding  to 7 characters = ''' + strB + '''');
 
  strB := strA.PadLeft(7, '-');
 
  Console.WriteLine('Padding with ''-'' to 7 characters = ''' + strB + '''');
 
  Console.ReadLine;
end.

Inclui el RPAD y LPAD porque no lo vi en tu codigo @Enecumene.

Saludos!

1

Volver arriba

#9 enecumene

Webmaster

Administrador
7.419 mensajes

LocationRepública Dominicana

Escrito 10 enero 2017 - 07:25

La verdad es que esa función se me coló

0

Volver arriba

#10 enecumene

Webmaster

Administrador
7.419 mensajes

LocationRepública Dominicana

Escrito 10 enero 2017 - 07:26

La verdad es que esa función se me coló

0

Volver arriba

#11 Carlosgimenez

Newbie

Miembros
3 mensajes

Escrito 18 julio 2022 - 08:42

Hay alguna manera de acelerar el proceso?? ya que cuando son muchos registros tarda su tiempo..

0

Volver arriba

#12 egostar

missing my father, I love my mother.

Administrador
14.460 mensajes

LocationMéxico

Escrito 18 julio 2022 - 04:05

Hay alguna manera de acelerar el proceso?? ya que cuando son muchos registros tarda su tiempo..

Hola Carlosgimenez

Lamentablemente el tiempo depende de los accesos a Excel, y el recorrido del Dataset por lo que el tiempo que tarda es exponencial.

Saludos

0

Volver arriba

#13 Carlosgimenez

Newbie

Miembros
3 mensajes

Escrito 18 julio 2022 - 04:47

Hola Carlosgimenez

Lamentablemente el tiempo depende de los accesos a Excel, y el recorrido del Dataset por lo que el tiempo que tarda es exponencial.

Saludos

Ok. Perdon la pregunta. Soy nuevo en programación y sobre todo con Delphi.

0

Volver arriba

#14 egostar

missing my father, I love my mother.

Administrador
14.460 mensajes

LocationMéxico

Escrito 18 julio 2022 - 06:17

Ok. Perdon la pregunta. Soy nuevo en programación y sobre todo con Delphi.

Sin problema Carlosgimenez, bienvenido a DelphiAccess.-

Espero que seamos de ayuda, no dudes en preguntar, siempre habrá alguien que te pueda ayudar con gusto.

Saludos.

0

Volver arriba

Volver a Tutoriales

Exportar un DataSet a Excel

#1 enecumene

#2 sir.dev.a.lot

#3 Agustin Ortu

#4 sir.dev.a.lot

#5 Marc

#6 enecumene

#7 enecumene

#8 sir.dev.a.lot

#9 enecumene

#10 enecumene

#11 Carlosgimenez

#12 egostar

#13 Carlosgimenez

#14 egostar

Iniciar sesión