Detectado javascript desactivado

Tienes el javascript desactivado en este momento. Muchas funciones podrían no funcionar. Por favor reactiva el javascript para obtener una funcionalidad completa.

[MULTILENGUAJE] Como colocar CheckBoxes en la cabecera e Items de un ListView

Comenzado por escafandra , ene 20 2017 10:12

CheckBoxes ListView cabecera Items Selecionar todos los Items

Por favor identifícate para responder

4 respuestas en este tema

#1 escafandra

Advanced Member

Administrador
4.111 mensajes

LocationMadrid - España

Escrito 20 enero 2017 - 10:12

Preguntaron como colocar un CheckBox y seleccionar con el todos los Items de un ListView en C++ y quería dejar en DA Una solución basada en una clase que realiza un subclassing del formulario para controlar las notificaciones que envían la cabecera y el ListView. La clase agrega un ChecBox en la cabecera de la primera columna y en cada Item. También genera dos eventos, uno cuando se marca el CheckBox de la caberera y otro cuando se marca el de un Item, de esta forma tendremos control desde el formulario de lo que está pasando. Cuando se marca la cabecera, automáticamente se marcan todos los Items y cuando están marcados todos los Items individualmente, se marca la cabecera.

Esta funcionalidad aparece desde Vista en adelante.

El código de la clase es este:

delphi

unit LVCheckBox;
 
//--------------------------------------------------------------------------------------------------
// TLVCheckBox (Versión Hook estilo C++)
// escafandra 2017
// Clase para manejo de CheckBox en la cabecera e Items de un ListView
 
interface
 
uses Windows, Messages, CommCtrl;
 
const
  HDN_ITEMSTATEICONCLICK: integer = $FFFFFEC4;
  HDF_CHECKBOX           = $0040;
  HDF_CHECKED            = $0080;
  HDF_FIXEDWIDTH         = $0100;
  HDS_CHECKBOXES         = $0400;
 
type
  PNMHEADER   = ^TagNMHEADER;
//  PNMLISTVIEW = ^TagNMLISTVIEW;
 
  TOnHeaderChecked = procedure(Checked: boolean) of object;
  TOnItemChecked = procedure(Index: integer; Checked: boolean) of object;
 
type
  TLVCheckBox = class
  private
    hListView: HWND;
    OldWndProc: Pointer;
    function WndProc(Handle: HWND; Msg: DWORD; WParam: Longint; LParam: Longint): Longint; stdcall;
  public
    OnHeaderChecked: TOnHeaderChecked;
    OnItemChecked: TOnItemChecked;
    constructor Create; overload;
    constructor Create(hListView: HWND); overload;
    destructor Destroy; override;
    procedure  SetHeaderCheck;
    procedure  SetHandle(hLV: HWND);
  end;
 
implementation
 
 
function DefWndProc(Handle: HWND; Msg: DWORD; WParam: Longint; LParam: Longint): Longint; stdcall;
var
  pLVCheckBox: TLVCheckBox;
begin
  pLVCheckBox:= TLVCheckBox(GetWindowLong(Handle, GWL_USERDATA));
  if pLVCheckBox <> nil then
    Result:= pLVCheckBox.WndProc(Handle, Msg, WParam, LParam)
  else
    Result:= DefWindowProc(Handle, Msg, WParam, LParam);
end;
 
constructor TLVCheckBox.Create;
begin
  OnHeaderChecked:= nil;
  OnItemChecked:= nil;
  SetHandle(0);
end;
 
constructor TLVCheckBox.Create(hListView: HWND);
begin
  OnHeaderChecked:= nil;
  OnItemChecked:= nil;
  SetHandle(hListView);
end;
 
function TLVCheckBox.WndProc(Handle: HWND; Msg: DWORD; WParam: Longint; LParam: Longint): Longint; stdcall;
var
  pNMH: PNMHEADER;
  pNMLV: PNMLISTVIEW;
  HeaderChecked: bool;
  i: integer;
begin
  if Msg = WM_NOTIFY then
  begin
    // Notificación del cambio del CheckBox de la cabecera
    pNMH:= PNMHEADER(LParam);
    if pNMH.hdr.code = HDN_ITEMSTATEICONCLICK then
    begin
      if (0 <> (pNMH.PItem.mask and HDI_FORMAT)) and (0 <> (pNMH.PItem.fmt and HDF_CHECKBOX)) then
      begin
        HeaderChecked:= (0 = (pNMH.pitem.fmt and HDF_CHECKED));
        if @OnHeaderChecked <> nil then
          OnHeaderChecked(HeaderChecked);
        for i:= 0 to ListView_GetItemCount(hListView)-1 do
          ListView_SetCheckState(hListView, i, HeaderChecked);
      end;
    end;
 
    // Notificación del cambio del CheckBox de un Item
    if pNMH.hdr.code = LVN_ITEMCHANGED then
    begin
      pNMLV:= PNMLISTVIEW(LParam);
      if (pNMLV.uChanged and LVIF_STATE) <> 0 then
      begin
        if @OnItemChecked <> nil then
          OnItemChecked(pNMLV.iItem, ListView_GetCheckState(hListView, pNMLV.iItem) <> 0);
        SetHeaderCheck;
      end;
    end;
  end;
  Result:= CallWindowProc(OldWndProc, Handle, Msg, WParam, LParam);
end;
 
procedure TLVCheckBox.SetHeaderCheck;
var
  HeaderChecked: boolean;
  i: integer;
  hHeader: HWND;
  HDI: HD_ITEM;
begin
  HeaderChecked:= true;
  for i:= 0 to ListView_GetItemCount(hListView)-1 do
  begin
    if ListView_GetCheckState(hListView, i) = 0 then
    begin
      HeaderChecked:= false;
      break;
    end;
  end;
 
  hHeader:= ListView_GetHeader(hListView);
  HDI.mask:= HDI_FORMAT;
  Header_GetItem(hHeader, 0, HDI);
  if HeaderChecked then
      HDI.fmt:= HDI.fmt or HDF_CHECKED
  else
    HDI.fmt:= HDI.fmt and not HDF_CHECKED;
  Header_SetItem(hHeader, 0, HDI);
end;
 
procedure TLVCheckBox.SetHandle(hLV: HWND);
var
  hHeader: HWND;
  HD: HD_ITEM;
begin
  if (hLV <> INVALID_HANDLE_VALUE) and (hLV <> hListView) then
  begin
    if hLV = 0 then
    begin
      SetWindowLong(GetParent(hListView), GWL_USERDATA, 0);
      SetWindowLong(GetParent(hListView), GWL_WNDPROC, LongInt(OldWndProc));
    end;
    if hLV <> 0 then
    begin
      ListView_SetExtendedListViewStyle(hLV, LVS_EX_CHECKBOXES or LVS_EX_FULLROWSELECT);
      //hHeader = (HANDLE)SendMessage(hListView, LVM_GETHEADER, 0, 0);
      hHeader:= ListView_GetHeader(hLV);
      SetWindowLong(hHeader, GWL_STYLE, GetWindowLong(hHeader, GWL_STYLE) or HDS_CHECKBOXES);
      ZeroMemory(@HD, sizeof(HD_ITEM));
      HD.mask:= HDI_FORMAT;
      Header_GetItem(hHeader, 0, HD);
      HD.fmt:= HD.fmt or HDF_CHECKBOX or HDF_FIXEDWIDTH;
      Header_SetItem(hHeader, 0, HD);
 
      SetWindowLong(GetParent(hLV), GWL_USERDATA, LongInt(self));
      OldWndProc:= Pointer(SetWindowLong(GetParent(hLV), GWL_WNDPROC, LongInt(@DefWndProc)));
    end;
    hListView:= hLV;
  end;
end;
 
destructor TLVCheckBox.Destroy;
begin
  OnHeaderChecked:= nil;
  OnItemChecked:= nil;
  SetHandle(0);
end;
 
end.

Un ejemplo de uso:

delphi

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ComCtrls, CommCtrl, XPMan, LVCheckBox, StdCtrls;
 
type
  TForm1 = class(TForm)
    ListView1: TListView;
    XPManifest1: TXPManifest;
    Button1: TButton;
    Button2: TButton;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
  private
    LVC: TLVCheckBox;
    procedure OnHeaderChecked(Checked: boolean);
    procedure OnItemChecked(Index: integer; Checked: boolean);
 
  public
    { Public declarations }
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
procedure TForm1.FormCreate(Sender: TObject);
begin
  LVC:= TLVCheckBox.Create(ListView1.Handle);
  LVC.OnHeaderChecked:= OnHeaderChecked;
  LVC.OnItemChecked:= OnItemChecked;
end;
 
procedure TForm1.Button1Click(Sender: TObject);
begin
  LVC.SetHandle(ListView1.Handle);
  LVC.OnHeaderChecked:= OnHeaderChecked;
  LVC.OnItemChecked:= OnItemChecked;
end;
 
procedure TForm1.Button2Click(Sender: TObject);
begin
  LVC.SetHandle(0);
end;
 
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  LVC.Free;
end;
 
 
procedure TForm1.OnHeaderChecked(Checked: boolean);
begin
  Windows.Beep(500, 100);
end;
 
procedure TForm1.OnItemChecked(Index: integer; Checked: boolean);
begin
  Windows.Beep(1000, 100);
end;
 
 
end.

Probado en Delphi 7 y Berlin.

Subo el código.

Saludos.

Archivos adjuntos

LVCheckBox D7.rar 192,89KB 4 descargas
LVCheckBox Berlin.rar 720,5KB 3 descargas

0

Volver arriba

#2 Agustin Ortu

Advanced Member

Moderadores
831 mensajes

LocationArgentina

Escrito 20 enero 2017 - 10:50

No tienen los ListView una propiedad Checkboxes que hace justamente esto? O es algo que agregaron más adelante?

0

Volver arriba

#3 escafandra

Advanced Member

Administrador
4.111 mensajes

LocationMadrid - España

Escrito 20 enero 2017 - 11:10

No tienen los ListView una propiedad Checkboxes que hace justamente esto? O es algo que agregaron más adelante?

La funcionalidad de el checkbox en la cabecera apareció con Vista, en los Items ya estaba en winXP. Ninguna versión de compiladores visuales previos aportan propiedades en ListView para hecerlo por motivos obvios y los posteriores tardan en adaptarse.

Mucha gente usa compiladores antiguos como el mítico Delphi7, Builder 5/6 o antiguas versiones de Visual Studio, en ellos hay que usar trucos cómo el publicado y que gestiona el propio Windows solo en lo referente a la visualización de los checkboxes y notificaciones, no en cuanto a su funcionalidad.

En el truco he programado que al marcar la cabecera se marquen los Items pero podríamos hacer otra cosa, windows ahí no se mete.

El caso es parecido al de las flechitas del ListView, Windows permite ponerlas pero no por defecto.

El truco podría colocar a capón controles checkbox para funcionar en WinXP, puesto que esa versión no lo contempla, pero no lo he hecho.

El truco sirve también como estudio de como conocer y manejar las notificaciones del ListView de Windows a bajo nivel que es lo que usan los componentes de la VCL.

Saludos.

1

Volver arriba

#4 escafandra

Advanced Member

Administrador
4.111 mensajes

LocationMadrid - España

Escrito 20 enero 2017 - 05:39

Publico también la versión C++ probada en BCB5, BCB6 y Berlin

cpp

//--------------------------------------------------------------------------------------------------
// TLVCheckBox (Versión Hook estilo C++)
// escafandra 2017
// Clase para manejo de CheckBox en la cabecera e Items de un ListView
 
 
#ifndef LVCheckBoxCPP
#define LVCheckBoxCPP
 
#include <Windows.h>
#include <Commctrl.h>
 
#define HDF_CHECKBOX   0x0040
#define HDF_CHECKED    0x0080
#define HDF_FIXEDWIDTH 0x0100
 
#define HDS_CHECKBOXES 0x0400
 
#ifndef HDN_ITEMSTATEICONCLICK
  #define HDN_ITEMSTATEICONCLICK 0xFFFFFEC4
#endif
 
#ifndef STRICT
  typedef int  (__stdcall *PLRESULT)();
#else
  typedef WNDPROC PLRESULT;
#endif
 
//typedef void (__fastcall *POnHeaderChecked)(bool Checked);
//typedef void (__fastcall *POnItemChecked)(int Item, bool Checked);
typedef void __fastcall(__closure* POnItemChecked)(int Item, bool Checked);
typedef void __fastcall(__closure* POnHeaderChecked)(bool Checked);
 
 
class TLVCheckBox
{
  private:
  HWND hListView;
  int Focusfmt;
  int FocusIndex;
  PLRESULT OldWndProc;
  static LRESULT __stdcall DefWndProc(HWND hWnd, UINT Msg, WPARAM WParam, LPARAM LParam)
  {
    TLVCheckBox* pLVCheckBox = (TLVCheckBox*)GetWindowLongPtr(hWnd, GWL_USERDATA);
    if(pLVCheckBox)
      return pLVCheckBox->WndProc(hWnd, Msg, WParam, LParam);
    else
      return DefWindowProc(hWnd, Msg, WParam, LParam);
  }
 
  LRESULT __stdcall WndProc(HWND hWnd, UINT Msg, WPARAM WParam, LPARAM LParam)
  {
    if(Msg == WM_NOTIFY){
      // Notificación del cambio del CheckBox de la cabecera
      NMHEADER* pNMH = (NMHEADER*)LParam;
      //if(pNMH->hdr.hwndFrom == hListView)
        if(pNMH->hdr.code == HDN_ITEMSTATEICONCLICK){
          if(pNMH->pitem->mask & HDI_FORMAT && pNMH->pitem->fmt & HDF_CHECKBOX){
            bool HeaderChecked = !(pNMH->pitem->fmt & HDF_CHECKED);
            if(OnHeaderChecked)
              OnHeaderChecked(HeaderChecked);
            for(int i = 0; i < ListView_GetItemCount(hListView); i++)
              ListView_SetCheckState(hListView, i, HeaderChecked);
          }
        }
      // Notificación del cambio del CheckBox de un Item
      if(pNMH->hdr.code == LVN_ITEMCHANGED){
        NMLISTVIEW* pNMLV = (NMLISTVIEW*)LParam;
        if (pNMLV->uChanged & LVIF_STATE){
          if(OnItemChecked)
            OnItemChecked(pNMLV->iItem, ListView_GetCheckState(hListView, pNMLV->iItem));
          SetHeaderCheck();
        }
      }
    }
    return CallWindowProc(OldWndProc, hWnd, Msg, WParam, LParam);
  }
 
  public:
  POnHeaderChecked OnHeaderChecked;
  POnItemChecked OnItemChecked;
  void __fastcall SetHeaderCheck()
  {
    BOOL HeaderChecked = TRUE;
    for(int i = 0; i < ListView_GetItemCount(hListView); i++) {
      if(!ListView_GetCheckState(hListView, i)){
         HeaderChecked = FALSE;
         break;
      }
    }
 
    HWND hHeader = ListView_GetHeader(hListView);
    HDITEM HDI = {0};
    HDI.mask = HDI_FORMAT;
    Header_GetItem(hHeader, 0, &HDI);
    if(HeaderChecked)
      HDI.fmt |= HDF_CHECKED;
    else
      HDI.fmt &= ~HDF_CHECKED;
    Header_SetItem(hHeader, 0, &HDI);
  }
 
  void SetHandle(HWND hLV)
  {
    if(hLV != INVALID_HANDLE_VALUE && hLV != hListView){
      if(!hLV){
        SetWindowLong(GetParent(hListView), GWL_USERDATA, 0);
        SetWindowLong(GetParent(hListView), GWL_WNDPROC, (LONG)OldWndProc);
      }
      if(hLV){
        ListView_SetExtendedListViewStyle(hLV, LVS_EX_CHECKBOXES | LVS_EX_FULLROWSELECT);
        //hHeader = (HANDLE)SendMessage(hLV, LVM_GETHEADER, 0, 0);
        HWND hHeader = ListView_GetHeader(hLV);
        SetWindowLong(hHeader, GWL_STYLE, GetWindowLong(hHeader, GWL_STYLE) | HDS_CHECKBOXES);
        HDITEM HD = {0};
        HD.mask = HDI_FORMAT;
        Header_GetItem(hHeader, 0, &HD);
        HD.fmt |= HDF_CHECKBOX | HDF_FIXEDWIDTH;
        Header_SetItem(hHeader, 0, &HD);
 
        SetWindowLongPtr(GetParent(hLV), GWL_USERDATA, (LONG)this);
        OldWndProc = (PLRESULT)SetWindowLongPtr(GetParent(hLV), GWL_WNDPROC, (LONG)TLVCheckBox::DefWndProc);
      }
      hListView = hLV;
    }
  }
 
  TLVCheckBox(HWND hListView = 0)
  {
    OnHeaderChecked = 0;
    OnItemChecked = 0;
    SetHandle(hListView);
  }
 
  ~TLVCheckBox() {SetHandle(0);}
};
#endif

Y un ejemplo de uso muy similar a Delphi

cpp

//---------------------------------------------------------------------------
#include <vcl.h>
#pragma hdrstop
 
#include "Unit1.h"
 
//---------------------------------------------------------------------------
#pragma package(smart_init)
#pragma resource "*.dfm"
TForm1 *Form1;
 
//---------------------------------------------------------------------------
__fastcall TForm1::TForm1(TComponent* Owner)
  : TForm(Owner)
{
  LVC.SetHandle(ListView1->Handle);
  LVC.OnItemChecked = &OnItemChecked;
  LVC.OnHeaderChecked = &OnHeaderChecked;
}
//---------------------------------------------------------------------------
 
void __fastcall TForm1::OnHeaderChecked(bool Checked)
{
   Beep(500, 100);
   // Aquí seguimos actuando según el cambio del ChecBox de la cabecera
}
//---------------------------------------------------------------------------
 
void __fastcall TForm1::OnItemChecked(int Item, bool Checked)
{
   Beep(1000, 100);
   // Aquí seguimos actuando según el Item y si cambia su estado a Checked = true
}
//---------------------------------------------------------------------------
 
void __fastcall TForm1::Button1Click(TObject *Sender)
{
  LVC.SetHandle(ListView1->Handle);
  LVC.OnItemChecked = &OnItemChecked;
  LVC.OnHeaderChecked = &OnHeaderChecked;
}
//---------------------------------------------------------------------------
 
void __fastcall TForm1::Button2Click(TObject *Sender)
{
  LVC.SetHandle(0);
}
//---------------------------------------------------------------------------