5 respuestas en este tema

[pcicom]

Saludos CHAVOS..  jejeje

 

Tengo una aplicacion funcionando desde hace mucho tiempo, pero quiero depurarla de tal modo que corrija un pequeño defecto que tiene, es editor de formatos de documentos el cual utilizo para imprimir documentos mediante un archivo .FTO que es modifcable.

 

Explico.

 

Cuando mando la impresion de mi documento a Impresora todo funciona perfectamente y las coordenadas de los datos se imprimen en la posicion correcta en CENTIMTEROS.MILIMETROS donde yo indique

utilizando la funcion descrita aqui abajo para tomar un nFx, nFy, como factores de calculo/aproximacion a las coordenadas donde yo imprimo.  Hasta aqui todo bien sin broncas.

 

En problema esta en cuando quiero hacer un preview imprimiendo en el canvas de una imagen, ahi es donde hay un pequeño error de calculo al imprimir, no se si sea por los pixeles por pulgada y/o algo no estoy generando bien, para lo cual agredecere en caso de que alguien tenga algo similar, y/o el metodo de impresion en canvas a imagen como preview de impresion.

 

 

El previev lo utilizo para:

* Tener vistas previas de los FORMATOS cuando los estoy creando.

* Generar un PDF por medio de los componentes PowerPDF, insertando la imagen. (Sin dependencia de impresoras virtuales y DLL ni nada de nada puro DELPHI).

 

Se que se puede hacer por medio de SynPDF, pero por ahora quisiera solo la aproximacion mas exacta en una IMAGEN.

PROBLEMA.ACTUAL 

 

* Quiero que la impresion en una imagen sea exactamente como cuando envio a la impresora.

 

* La Imagen del mismo tamaño/proporcional al del canvas de la impresora.

* El Texo impreso del mismo tamaño proporcional al la impresion del el canvas de la Impresora.

  (Aqui es donde existe basicamente el problema ya que segun el tamaño del FONT la imrpesion es mas corta en el preview). 

 

 

SI ALGUIEN Tiene una IDEA agredecere, algun tip que me ayude con este pequeño problema.

 

 

ANEXO MINICODIGO que utilizo para datos bases de las impresiones.

 

 

delphi

Var
  preview : TImage.
 
 
procedure InitPrinter;
var
    XD,YD:Integer;
    x,y:string;
begin
   if lPrinter then
   begin
       // pixels/inch horizontales
       XD:=GetDeviceCaps(Printer.Handle,LogPixelSX);
       // pixels/inch verticales
       YD:=GetDeviceCaps(Printer.Handle,LogPixelSY);
       nFx := XD/25.4;
       nFy := YD/25.4;
       nFx := nFx * 10;
       nFy := nFy * 10;
       nIncY:=0;
       printer.Canvas.brush.Style:=bsClear;
   end
   ELSE
   begin
      //Factores de Calculo Pixel/MM
      nFx := GetDeviceCaps(printer.Handle,LogPixelSX)/25.4;
      nFy := GetDeviceCaps(printer.Handle,LogPixelSY)/25.4;
 
      //    
      ////////////////////////////////////
      // CON ESTOS VALORES LA IMPRESION ES MUY SIMILAR A IMPRESORA
      ////////////////////////////////////
      //
 
      nFx := 37.795275591;
      nFy := 37.795275591;
 
 
      x := floattostr(int(nFy*100));
      y := floattostr(int(nFX*100));
      nIncY:=0;
      preview.Height := strtoint(y);
      preview.Width :=  strtoint(x);
      preview.Canvas.brush.Style:=bsClear;
      preview.Picture := nil;
 
 
   end;
 
end;
 
procedure TipoLetra(cFont:String; nSize:Integer);
begin
 
   if lPrinter then
   begin
      printer.Canvas.font.Name := aLLTRIM(cFont);
      if nSize>0 then
         printer.canvas.Font.Size := nSize;
   end
   ELSE
   begin
      preview.Canvas.font.Name := AllTrim(cFont);
      if nSize>0 then
         preview.canvas.Font.Size := nSize;
   end;
 
end;
 
procedure Escribe(xPos:Extended;cValor,cMask:String);
Var x,y:integer;
begin
   xPos := int(xPos * nFx);
   x := strtoint(floattostr(xPos));
   if lPrinter then
   begin
      y:=printer.canvas.PenPos.y;
      cValor := Maskara(cValor,cMask);
      printer.Canvas.Brush.Style := bsClear;
      printer.Canvas.TextOut(x,y,cValor);
   end
   ELSE
   begin
      y:=preview.canvas.PenPos.y;
      cValor := Maskara(cValor,cMask);
      preview.Canvas.Brush.Style := bsClear;
      preview.Canvas.TextOut(x,y,cValor);
   end;
end;
 
 
procedure EscribeXY(x1,y1:Extended;cValor,cMask:String);
Var
   x,y:integer;
begin
 
   x1 := int(x1 * nFx);
   y1 := int(y1 * nFy);
   x := strtoint(floattostr(x1));
   y := strtoint(floattostr(y1)) + nIncY;
   cValor := Maskara(cValor,cMask);
 
   if lPrinter then
   begin
      printer.Canvas.Brush.Style := bsClear;
      printer.Canvas.TextOut(x,y,cValor);
   end
   else
   begin
      preview.Canvas.Brush.Style := bsClear;
      preview.Canvas.TextOut(x,y,cValor);
   end;
   Brinca(1);
end;

 

Editado por pcicom, 13 abril 2017 - 09:23 .

[escafandra]

En ocasiones he realizado algo similar a lo que haces, escribiendo en un HDC. Si el HDC es el dela impresora, imprime. Si el HDC es el de una ventana, previsualiza.
 
A vote pronto creo que tu problema está en los tipos en coma flotante. Usas una forma extrana pasando el resultado a un String y luego a float, imagino que es porque viste que perdías precisión, o algo así. Es mejor usar el tipo double para no perder precisión, pero lo que yo suelo hacer el usar la API MulDiv algo así:

delphi

clientR.right = MulDiv(PageSize.cx, screenRes.cx, printRes.cx);

Así evito el uso de tipos de coma flotante cuando el final va a ser un entero.

Saludos.

[pcicom]

En ocasiones he realizado algo similar a lo que haces, escribiendo en un HDC. Si el HDC es el dela impresora, imprime. Si el HDC es el de una ventana, previsualiza.
 
A vote pronto creo que tu problema está en los tipos en coma flotante. Usas una forma extrana pasando el resultado a un String y luego a float, imagino que es porque viste que perdías precisión, o algo así. Es mejor usar el tipo double para no perder precisión, pero lo que yo suelo hacer el usar la API MulDiv algo así:

delphi

clientR.right = MulDiv(PageSize.cx, screenRes.cx, printRes.cx);

Así evito el uso de tipos de coma flotante cuando el final va a ser un entero.

Saludos.

 

 

 

Gracias, por contestar mi estimado escafandra,  la verdad ya ni me acuerdo por que lo uso asi, ya que como comento es algo que desarrolle hace varios años, como comento en mi consulta..  mi bronca principal es cuando imprimo en una imagen a la que le llamo preview, y no se porque aplica principalmente a los FONTS que posiblemente no los escalo correctamente,  pero dentro de la logica siendo canvas el de la imagen y canvas el de la printer,  pues deberia de haber una correspondencia o algo parecido..

 

Es decir en el printer  existe el printer.pagewidth y printer.pageheight   y para utilizar una imagen cual deberia de ser sus correspondientes valores de width y height de tal manera que los FONTS correspondan en su tamaño natural..  osea que si en el printer.canvas.font.size = 10   en el image.canvas.font.size=10 sean iguales/correspondientes a tamaño..   esta es la base de mi problema...

 

Agredezco cualquier comentario, y mas siendo de los NOVATOS de DELPHI a los cuales me gusta leer tus aportes..     



 

[escafandra]

Para escalar Windows nos propone las APIs SetMapMode, SetViewportExtEx y SetWindowExtEx. Para escalar un dispositivo, como la impresora, a la pantalla, la escala debe estar en proporción a las resoluciones de ambos. Las APIs SetViewportExtEx y SetWindowExtEx adaptan el canvas de un dispositivo al otro. Te pongo un ejemplo donde coloco en un formulario un TImage que servirá para previsualizar lo que se imprime en la impresora. El TImage debe tener un tamaño proporcional al papel usado, para ello se ajusta al crear el formulario. La impresión y la previsualización se hacen con la misma función que pinta directamente en el Canvas del dispositivo. La escala consigue adaptar el preview.

delphi

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Printers, ExtCtrls;
 
type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Image1: TImage;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
procedure Draw(Canvas: TCanvas; var Rect: TRect);
var
  TE: TSize;
  i: integer;
begin
  Canvas.Font.Name:= 'arial';
  Canvas.Font.Size:= 195;
  Canvas.Brush.Style:= bsClear;
  Canvas.Rectangle(Rect);
  TE:= Canvas.TextExtent('HOLA');
  for i:= 0 to 3 do
    Canvas.TextOut((Rect.Right - TE.cx) div 2, i*TE.cy, 'HOLA');
end;
 
procedure TForm1.Button1Click(Sender: TObject);
var
  PrintRect: TRect;
begin
  PrintRect:= Rect(0, 0, Printer.PageWidth-1, Printer.PageHeight-1);
  Printer.BeginDoc;
  Draw(Printer.Canvas, PrintRect);
  Printer.EndDoc;
end;
 
procedure TForm1.Button2Click(Sender: TObject);
var
  DocRect: TRect;
  screenRes, printRes: TSize;
  screenDC: HDC;
begin
  screenDC:= Windows.GetDC(0);
  screenRes.cx:= GetDeviceCaps(screenDC, LOGPIXELSX);
  screenRes.cy:= GetDeviceCaps(screenDC, LOGPIXELSY);
  Windows.ReleaseDC(0, screenDC);
 
  printRes.cx:= GetDeviceCaps(Printer.Handle, LOGPIXELSX);
  printRes.cy:= GetDeviceCaps(Printer.Handle, LOGPIXELSY);
 
  DocRect.left:= 0;
  DocRect.top:= 0;
  DocRect.right:= MulDiv(Printer.PageWidth, screenRes.cx, printRes.cx);
	DocRect.bottom:= MulDiv(Printer.PageHeight, screenRes.cy, printRes.cy);
 
  SetMapMode(Image1.Canvas.Handle, MM_ISOTROPIC);
 
  SetViewportExtEx(Image1.Canvas.Handle, Image1.Width, Image1.Height, nil);
  // Escala la ventana al tamaño logico de la pagina (asume left = top = 0)
  SetWindowExtEx(Image1.Canvas.Handle, DocRect.right, DocRect.bottom, nil);
 
  Draw(Image1.Canvas, DocRect);
end;
 
procedure TForm1.FormCreate(Sender: TObject);
begin
  Image1.Height:= MulDiv(Printer.PageHeight, Image1.Width, Printer.PageWidth);
end;
 
end.

 

 

Subo el proyecto probado con Delphi7  en Windows10.

 

 

 

Saludos.

Archivos adjuntos

•  Preview.rar   163,58KB   18 descargas

[foxito]

me puedes proporcionar tu correo

[egostar]

me puedes proporcionar tu correo

 

Hola foxito, bienvenido a DelphiAccess

 

¿Tienes alguna pregunta? Este medio es el óptimo para ello ya que ayudará a mas compañeros.

 

Saludos