5 respuestas en este tema

[jorgebq77]

Saludos mis queridos foristas,

 

En internet encontré este código para obtener los papeles de una impresora usando el API de Windows y el objeto TPrinter de Delphi.

 

Aquí esta el código:

delphi

procedure GetPaperNames(sl : TStrings);
type
  TPaperName = array[0..63] of Char;
  TPaperNameArray = array[1..High(Integer) div SizeOf(TPaperName)] of TPaperName;
  PPaperNameArray = ^TPaperNameArray;
var
  Device, Driver, Port : array[0..255] of Char;
  hDevMode : THandle;
  I, NumPaperFormats : Integer;
  pPaperFormats : PPaperNameArray;
begin
  Printer.PrinterIndex := Printer.PrinterIndex;
  Printer.GetPrinter(Device, Driver, Port, hDevmode);
  NumPaperFormats := DeviceCapabilities(Device, Port, DC_PAPERNAMES, nil, nil);
  if NumPaperFormats > 0 then
    begin
      GetMem(pPaperFormats, NumPaperFormats * SizeOf(TPaperName));
      try
        DeviceCapabilities(Device, Port, DC_PAPERNAMES, Pchar(pPaperFormats), nil);
        sl.Clear;
        for I:= 1 to NumPaperFormats do
        sl.add( pPaperformats^[I] );
 
      finally
        FreeMem(pPaperFormats);
      end;
    end;
end;

Tomando este código como referencia he hecho una función para obtener el nombre del papel de la impresora pasando como parámetro el numero de papel. por ejemplo, si le paso a la función el código 1 (correspondiente a DMPAPER_LETTER) la función devolverá el papel "US Letter 8 1/2 x 11 in", si le paso el código 5 (correspondiente a DMPAPER_LEGAL)  la función devolverá el papel "US Legal 8 1/2 x 14 in", si le paso el código 9 (correspondiente a DMPAPER_A4)  la función devolverá el papel "A4 210 x 297 mm" y así sucesivamente.

 

Aquí esta la función que diseñe para obtener el nombre del papel :

delphi

function GetPaperName(IdxPrinter, Papel : Word) : string;
type
  TPaperName = array[0..63] of Char;
  TPaperNameArray = array[1..High(Integer) div SizeOf(TPaperName)] of TPaperName;
  PPaperNameArray = ^TPaperNameArray;
var
  Device, Driver, Port : array[0..255] of Char;
  hDevMode : THandle;
  I, NumPaperFormats : Integer;
  pPaperFormats : PPaperNameArray;
begin
  Printer.PrinterIndex := IdxPrinter;
  Printer.GetPrinter(Device, Driver, Port, hDevmode);
  NumPaperFormats := DeviceCapabilities(Device, Port, DC_PAPERNAMES, nil, nil);
  if NumPaperFormats > 0 then
    begin
      GetMem(pPaperFormats, NumPaperFormats * SizeOf(TPaperName));
      try
        DeviceCapabilities(Device, Port, DC_PAPERNAMES, Pchar(pPaperFormats), nil);
 
        for I:= 1 to NumPaperFormats do
          begin
            if I = Papel then
              begin
                Result := pPaperformats^[I];
                Break;
              end;
          end;
 
      finally
        FreeMem(pPaperFormats);
      end;
    end;
end;

Esta función que diseñe devuelve el nombre del papel pero de forma incorrecta.... pues lamentablemente no soy experto en el uso del API de Windows. Por eso les pido de favor que me ayuden a corregir dicha función ya que la necesito para pasársela a los reporteadores que uso (FastReport y ReportBuilder). Esta utilidad la usare para evitarle a los usuarios el tener que elegir el tamaño del papel cada vez que quieran imprimir. Como pista creo que el error esta en el bucle donde comparo el parámetro "Papel" con el índice del bucle.

 

Esperando que me hayan entendido les agradezco su ayuda y atención.

 

Att: Jorge

 

 

 

 

 

 

 

 

 

 

 

 

 

 

 

[egostar]

Así de bote pronto no será que TPaperName es base 0 y TPaperNameArray es base 1

 

De cualquier forma hay que analizar el código para poder darte una mejor respuesta.

 

Saludos

[jorgebq77]

El amigo escafandra tal vez tenga la respuesta ya que es un experto en el manejo del API de Windows. 

[escafandra]

El problema está en que cuando se solicita la lista de nombre, ésta no está ordenada según los valores de dmPaperSize. Para poder obtener el nombre ordenado hay que listar los nombre por un lado, y los índices por el otro (DC_PAPERS).

La forma de conseguir un array con los indices del tamaño del papel según dmPaperSize es la siguiente: 

delphi

DeviceCapabilitiesA(Device, Port, DC_PAPERS, PAnsiChar(pPapers), nil);

De esta forma y modificando lo justo la función que proponías en tu post, te propongo esta solución:

delphi

function GetPaperName(IdxPrinter, Papel : Word) : string;
type
  TPaperName = array[0..63] of AnsiChar;
  TAWord = array[1..High(WORD)] of WORD;
  TPaperNameArray = array[1..High(Integer) div SizeOf(TPaperName)] of TPaperName;
  PPaperNameArray = ^TPaperNameArray;
  PAWord = ^TAWord;
var
  Device, Driver, Port : array[0..255] of AnsiChar;
  hDevMode : THandle;
  I, NumPaperFormats : Integer;
  pPaperFormats : PPaperNameArray;
  pPapers: PAWord; //PWORD;
begin
  Result := '';
  Printer.PrinterIndex := IdxPrinter;
  Printer.GetPrinter(Device, Driver, Port, hDevmode);
  NumPaperFormats := DeviceCapabilities(Device, Port, DC_PAPERNAMES, nil, nil);
  if NumPaperFormats > 0 then
    begin
      GetMem(pPaperFormats, NumPaperFormats * SizeOf(TPaperName));
      GetMem(pPapers, NumPaperFormats * SizeOf(WORD));
      ZeroMemory(pPapers, NumPaperFormats);
      try
        DeviceCapabilitiesA(Device, Port, DC_PAPERNAMES, PAnsiChar(pPaperFormats), nil);
        DeviceCapabilitiesA(Device, Port, DC_PAPERS, PAnsiChar(pPapers), nil);
 
        for I:= 1 to NumPaperFormats do
        begin
          if pPapers^[I] = Papel then
          begin
             Result := pPaperformats^[I];
             Break;
          end;
        end;
      finally
        FreeMem(pPaperFormats);
        FreeMem(pPapers);
      end;
    end;
end;

Para evitar conflictos con UNICODE, he usado la versión Ansi de la API DeviceCapabilitiesA. De esta forma el código es compatible con versiones antiguas de delphi. Esto impica usar Array de  AnsiChar. Dado que el origen de indice de los array los estableciste en 1, los respeto. Personalmente prefiero que empiezen en cero por coherencia con el diseño de la API. Al tener el array de Papers que contiene los dmPaperSize, Solo hay que comparar cada elemento del array con el Papel solicitado, el índice de ese valor, será el que usaremos para encontrar el nombre del papel en el array correspòndiente de nombres. 
 
 
Saludos.
 
PD/ adjunto un extracto del archivo wingdi.h donde se definen los tamaños de papel.

Archivos adjuntos

•  Papers.txt   9,88KB   2 descargas

[jorgebq77]

Muy valiosa tu aportación querido escafandra, sabia perfectamente que tu darías con este asunto..

 

Solo una aclaración, probé la modificación de la función que propones pero no compila en estas dos líneas:

delphi

Printer.GetPrinter(Device, Driver, Port, hDevmode);

El error que sale en esa línea es :[dcc32 Error] Unit1.pas(342): E2010 Incompatible types: 'PWideChar' and 'array[0..255] of AnsiChar'

 

 

en esta otra línea :

delphi

NumPaperFormats := DeviceCapabilities(Device, Port, DC_PAPERNAMES, nil, nil);

 el error que sale es : [dcc32 Error] Unit1.pas(343): E2010 Incompatible types: 'PWideChar' and 'array[0..255] of AnsiChar'

 

 

Sale el mismo error en ambas líneas por que en el procedimiento GetPrinter espera parámetros de tipo PWideChar y la función DeviceCapabilities también espera parámetros de tipo PWideChar.

 

Trate de convertir los parámetros a PWideChar y me da el error [dcc32 Error] Unit1.pas(342): E2089 Invalid typecast

 

Como puedo solventar estos dos errores ??? Yo uso el Delphi Tokyo 10.2

 

Gracias por tu valiosa ayuda compañero.

[escafandra]

El error es por el UNICODE

 

Si vas a usar Tokyo, entonces usa la versión W

delphi

function GetPaperName(IdxPrinter, Papel : Word) : string;
type
  TPaperName = array[0..63] of Char;
  TAWord = array[1..High(WORD)] of WORD;
  TPaperNameArray = array[1..High(Integer) div SizeOf(TPaperName)] of TPaperName;
  PPaperNameArray = ^TPaperNameArray;
  PAWord = ^TAWord;
var
  Device, Driver, Port : array[0..255] of Char;
  hDevMode : THandle;
  I, NumPaperFormats: Integer;
  pPaperFormats : PPaperNameArray;
  pPapers: PAWord; //PWORD;
begin
  Result := '';
  Printer.PrinterIndex := IdxPrinter;
  Printer.GetPrinter(Device, Driver, Port, hDevmode);
  NumPaperFormats := DeviceCapabilities(Device, Port, DC_PAPERNAMES, nil, nil);
  if NumPaperFormats > 0 then
    begin
      GetMem(pPaperFormats, NumPaperFormats * SizeOf(TPaperName));
      GetMem(pPapers, NumPaperFormats * SizeOf(WORD));
      ZeroMemory(pPapers, NumPaperFormats * SizeOf(WORD));
      try
        DeviceCapabilities(Device, Port, DC_PAPERNAMES, PChar(pPaperFormats), nil);
        DeviceCapabilities(Device, Port, DC_PAPERS, PChar(pPapers), nil);
 
        for I:= 1 to NumPaperFormats do
        begin
          if pPapers^[I] = Papel then
          begin
             Result := pPaperformats^[I];
             Break;
          end;
        end;
      finally
        FreeMem(pPaperFormats);
        FreeMem(pPapers);
      end;
    end;
end;

Saludos.