8 respuestas en este tema

[escafandra]

Para asociar un tipo de extensión con un ejecutable utilizaremos el registro de la siguiente manera:

cpp

#define ShlObjHPP
#include <vcl.h>
#pragma hdrstop
 
#include <shlobj.h>
#include <Registry.hpp>
 
 
//---------------------------------------------------------------------------
void RegisterFileType(AnsiString Ext, AnsiString PathExec)
{
  // Ext tipo de archivo : EXTENSION
  // PathExec: RUTA COMPLETA del ejecutable que queremos asociar
 
  TRegistry *Registry = new TRegistry;
  try{
    Registry->RootKey = HKEY_CLASSES_ROOT;
    // Crear la clave .Ext
    if(Registry->OpenKey("." + Ext, true)){
      // Valor con el nombre del tipo de archivo para esta clave (extfile)
      Registry->WriteString("", Ext + "file");
      Registry->CloseKey();
    }
    // Crear una clave nueva para el nombre del tipo de archivo dado antes (extfile)
    if(Registry->CreateKey(Ext + "file")){
      // Crear una nueva clave para el icono por defecto
      if(Registry->OpenKey(Ext + "file\\DefaultIcon", true)){
        // Crear un valor con el icono (PathExec.exe,0)
        Registry->WriteString("", PathExec + ",0");
        Registry->CloseKey();
      }
      if(Registry->OpenKey(Ext + "file\\shell\\open\\command", true)){
        //Crear el valor para el ejecutable que abre el tipo de archivo (PathExec.exe "%1")
        Registry->WriteString("", PathExec + " \"%1\"");
        Registry->CloseKey();
      }
    }
  }
  __finally{
    delete Registry;
  }
  // Notificar al sistema el cambio efectuado
  SHChangeNotify(SHCNE_ASSOCCHANGED, SHCNF_IDLIST, 0, 0);
}

Si queremos asociar la extensión "txt", por ejemplo, con nuestro programa:

cpp

RegisterFileType("txt", Application->ExeName);

Para reasignar la extensión a otro ejecutable, basta con volver a llamar a la función.


Que le saquéis partido.

Saludos.

[razadi]

Excelente aporte escafranda, gracias y saludos

[enecumene]

Excelente aportación , me hice el valiente en este caso e hice una versión en Delphi :$, estoy que necesita alguna mejoras, espero no te molestes amigo:

delphi

procedure AsociarExt(Ext, AppPath: String);
var
  Registry: TRegistry;
begin
  Registry := TRegistry.Create;
  try
    Registry.RootKey := HKEY_CLASSES_ROOT;
 
    Registry.OpenKey(Ext, true);
    Registry.WriteString('', Ext);
    Registry.CloseKey;
 
    Registry.OpenKey('shell\open\command', true);
    Registry.WriteString('', AppPath + ' "%1"');
  finally
    Registry.Free;
  end;
end;

Saludos.

[escafandra]

Excelente aportación , me hice el valiente en este caso e hice una versión en Delphi :$, estoy que necesita alguna mejoras, espero no te molestes amigo...

No me molesta, además muchos delphiparlantes lo preferirán así. Sólo un detalle, olvidaste asociar el icono de la aplicación. 

De todas formas cuando un tipo de archivo es totalmente nuevo se debe añadir una clave de nombre punto+EXT (para axchivos txt, por ejemplo: .txt) y escribir en ella el valor del nombre del tipo de archivo, o al menos eso tenía entendido  :^)

Saludos.

[enecumene]

Bueno, en un momento de aburrimiento volví y me hice el guapo, hice la versión para delphi que es prácticamente igual al que tienes , Aquí lo dejo:

delphi

procedure RegisterFileType(Ext,PathExec: string);
var Registry: TRegistry;
begin
  Registry := TRegistry.Create;
    try
      Registry.RootKey := HKEY_CLASSES_ROOT;
      //Crear la Clave .Ext
      if (Registry.OpenKey('.'+Ext, True)) then
       begin
         // Valor con el nombre del tipo de archivo para esta clave (extfile)
         Registry.WriteString('', Ext + 'file');
         Registry.CloseKey;
       end;
      // Crear una clave nueva para el nombre del tipo de archivo dado antes (extfile)
      if (Registry.CreateKey(Ext + 'file')) then
        begin
          // Crear una nueva clave para el icono por defecto
          if (Registry.OpenKey(Ext + 'file\\DefaultIcon', true)) then
           begin
             // Crear un valor con el icono (PathExec.exe,0)
             Registry.WriteString('', PathExec + ',0');
             Registry.CloseKey;
           end;
           if (Registry.OpenKey(Ext + 'file\\shell\\open\\command', true)) then
           begin
             //Crear el valor para el ejecutable que abre el tipo de archivo (PathExec.exe "%1")
             Registry.WriteString('', PathExec + '"%1"');
             Registry.CloseKey;
           end;
        end;
    finally
      Registry.Free;
    end;
 SHChangeNotify(SHCNE_ASSOCCHANGED, SHCNF_IDLIST, 0, 0);
end;

A ver si ahora quedó mejor

Saludos.

[escafandra]

Cuando tenga necesidad bajo delphi ya lo tengo traducido   

Saludos.

[enecumene]

Cuando tenga necesidad bajo delphi ya lo tengo traducido   

Saludos.

Ah vaya

[escafandra]

Retoco la traducción que hizo enecumene:

Básicamente se trata de arreglar las cadenas, en C para escribir un carácter '\' se escribe '\\', pues ese carácter tiene un significado especial como código de control. De esta forma, al traducir a delphi debemos quitar uno de los caracteres. Cuando en C queremos colocar comillas dentro de una cadena, el compilador precisa que se coloquen así \", puesto que el carácter " se dedica a decirle al compilador que lo que sigue es una cadena de texto literal. De esta forma al traducir a delphi, debemos quitar el carácter '\'

También falta un espacio en '"%1"' debe ser ' "%1"'

delphi

uses
  ShlObj, Registry;
 
 
procedure RegisterFileType(Ext,PathExec: string);
var Registry: TRegistry;
begin
  Registry := TRegistry.Create;
    try
      Registry.RootKey := HKEY_CLASSES_ROOT;
      //Crear la Clave .Ext
      if (Registry.OpenKey('.'+Ext, True)) then
       begin
         // Valor con el nombre del tipo de archivo para esta clave (extfile)
         Registry.WriteString('', Ext + 'file');
         Registry.CloseKey;
       end;
      // Crear una clave nueva para el nombre del tipo de archivo dado antes (extfile)
      if (Registry.CreateKey(Ext + 'file')) then
        begin
          // Crear una nueva clave para el icono por defecto
          if (Registry.OpenKey(Ext + 'file\DefaultIcon', true)) then
           begin
             // Crear un valor con el icono (PathExec.exe,0)
             Registry.WriteString('', PathExec + ',0');
             Registry.CloseKey;
           end;
           if (Registry.OpenKey(Ext + 'file\shell\open\command', true)) then
           begin
             //Crear el valor para el ejecutable que abre el tipo de archivo (PathExec.exe "%1")
             Registry.WriteString('', PathExec + ' "%1"');
             Registry.CloseKey;
           end;
        end;
    finally
      Registry.Free;
    end;
 SHChangeNotify(SHCNE_ASSOCCHANGED, SHCNF_IDLIST, nil, nil);
end;

Saludos.

[enecumene]

Gracias escafandra tomo nota .