5 respuestas en este tema

[Rolphy Reyes]

Saludos compañeros.

Tengo una duda y como en estos días he estado lejos del negocio se me a hecho difícil encontrar la solución.

La duda es necesito hacer una función para calcular capital e interés (esta parte la tengo manejada) y que el resultado por decir sea devuelto en un TDataSet para luego yo manejarlo a mí antojo osea para guardarlo en la tabla destino.

Sería con sus campos y valores pero que sean temporales hasta que yo cargue sus datos.

delphi

CUOTA CAPITAL INTERES MONTO_CUOTA
1        1000      100        1100
2        1000      100        1100 

Puede que sea facilito pero anda dando cabezazos estos días.

Por cierto tengo D2007.

[Wilson]

He aquí una idea, creando un archivo xml con el esuqma que necesitas, con esto podrás arrastrar en tiempo de disño un TClientDataset o hacerlo dinámicamente para manipular los datos a tu antojo.  Es solo una idea espero te sirva.

delphi

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Db, DbClient;
 
type
  TForm1 = class(TForm)
    Button1: TButton;
    SaveDialog1: TSaveDialog;
    procedure Button1Click(Sender: TObject);
  private
    procedure CrearEsquema;
    procedure ManipularDataset;
    procedure PasarDatos;
    { Private declarations }
  public
    { Public declarations }
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
{ TForm1 }
 
procedure TForm1.Button1Click(Sender: TObject);
begin
  CrearEsquema;
end;
 
procedure TForm1.CrearEsquema; // Creas el esquema y lo guardas en un archivo xml
var
  D: TClientDataset;
begin
  D := TClientDataset.Create(self);
  try
    D.FieldDefs.Clear;
    D.FieldDefs.Add('CUOTA', ftInteger, 0);
    D.FieldDefs.Add('CAPITAL', ftCurrency, 0);
    D.FieldDefs.Add('INTERES', ftFloat, 0);
    D.FieldDefs.Add('MONTO_CUOTA', ftCurrency, 0);
    D.CreateDataSet;
//Aquí podrías empezar a manipular tus datos sin necesidad de crear el archivo xml
    SaveDialog1.DefaultExt := 'xml';
    SaveDialog1.Filter := 'XML files|*.xml|All files|*.* ';
    if SaveDialog1.Execute then
      D.SaveToFile(SaveDialog1.FileName, dfXML);
  finally
    D.Free
  end;
end;
 
procedure TForm1.ManipularDataset;
var
  Archivo: string;
  CD: TClientDataset; // Podrías arrastar un TClientDatse en tiempo de diseño
  // y cargarlo con el archivo de esquema y manipularlo a tu gusto
  I: Integer;
begin
  CD := TClientDataset.Create(self);
  try
    CD.LoadFromFile(Archivo); // Carga el esquema creado en el procedimiento anterior
    CD.Open;
    for I := 1 to CuantosDatosHayan do
    begin
      CD.Append;
      PasarDatos;
      CD.Post;
    end;
    // Aquí podrías guardar tus datos o lo que quieras hacer con ellos
  finally
    CD.CancelUpdates; // Si no quieres contaminar el esquema base
    CD.Close;
    CD.Free
  end;
end;
 
procedure TForm1.PasarDatos;
begin
  // Aqui la parte que ya tienes manejada para obtener tus datos
end;
 
end.

[Wilson]

Otra

delphi

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Db, DbClient;
 
type
  TForm1 = class(TForm)
  private
    procedure CrearEsquema;
    procedure ManipularDataset(DS: TClientDataset);
    procedure PasarDatos;
    { Private declarations }
  public
    { Public declarations }
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
{ TForm1 }
 
procedure TForm1.PasarDatos;
begin
  // Aqui la parte que ya tienes manejada para obtener tus datos
end;
 
procedure TForm1.ManipularDataset(DS: TClientDataset);
var
  I: Integer;
begin
  DS.Open;
  for I := 1 to CuantosDatosHayan do
  begin
    DS.Append;
    PasarDatos;
    DS.Post;
  end;
  // Hacer aqui todo lo que quieras
end;
 
procedure TForm1.CrearEsquema; 
var
  D: TClientDataset;
begin
  D := TClientDataset.Create(self);
  try
    D.FieldDefs.Clear;
    D.FieldDefs.Add('CUOTA', ftInteger, 0);
    D.FieldDefs.Add('CAPITAL', ftCurrency, 0);
    D.FieldDefs.Add('INTERES', ftFloat, 0);
    D.FieldDefs.Add('MONTO_CUOTA', ftCurrency, 0);
    D.CreateDataSet;
    ManipularDataset(D);
  finally
    D.Close;
    D.Free
  end;
end;
 
end.

[axesys]

Haber si esto te sirve

Creando tablas de memoria con ClientDataSet


Saludos

[Rolphy Reyes]

Gracias por sus respuestas.

Le echare un ojo, lo único que veo como "problema" es que si uso ClientDataSet tengo que llevar el MIDAS.DLL con mi ejecutable pero veremos.

[axesys]

Gracias por sus respuestas.

Le echare un ojo, lo único que veo como "problema" es que si uso ClientDataSet tengo que llevar el MIDAS.DLL con mi ejecutable pero veremos.

Para que no tengas que tener esa dll puedes agregar al uses del proyecto MidasLib


Saludos