17 respuestas en este tema

[Caral]

Hola a todos
Estoy tratando de hacer mi primer programa sin form (nunca lo había hecho) y me tope con una de tantas dificultades, a ver si me dais un empujón.
Lo que quiero hacer es sencillo:
Tengo un programa (sin Form) que cierra una aplicación de windows.
Hasta ahí todo bien, el asunto es que quiero que use un timer para controlar el tiempo de cerrar dicho programa.
Normalmente con un form simplemente lo coloco y ya.
Si creara el componente tendría que ponerle un padre (creo) pero como no tengo form pues no puedo.

El código que tengo es sencillo:

delphi

program Project1;
 
uses
  windows,
  Messages;
 
var
Mango:integer;
begin
Mango:=FindWindow(nil,'Calculator');
if mango=0
then
else PostMessage(FindWindow(Nil, Pchar('Calculator')), WM_QUIT, 0, 0);
 
end.

Si tuviese un form, colocaría un timer y lo haria asi:

delphi

procedure TForm1.FormCreate(Sender: TObject);
begin
  Timer1.Enabled:= True;
end;
 
procedure TForm1.Timer1Timer(Sender: TObject);
var
Mango:integer;
begin
Mango:=FindWindow(nil,'Calculator');
if mango=0
then
else PostMessage(FindWindow(Nil, Pchar('Calculator')), WM_QUIT, 0, 0);
 
end;

Ahora la pregunta:
Como creo en el programa sin form el timer y le indico que si cumple con un determinado tiempo se ejecute la acción de cerrar la aplicación?.
Espero que me entiendan y ayuden amigos.
Gracias.
Saludos

[Caral]

Hola
Otra cosa que se me ocurre es que se pueda definir si esta abierta o no la aplicación a cerrar, para que no genere ningún error.
Saludos

[egostar]

Hola amigo

A reserva de que los que saben de estos menesteres se pronuncien, debes de utilizar una aplicación de consola e incluir este código.

delphi

program Project1;
 
{$APPTYPE CONSOLE}
 
uses
  SysUtils, windows, messages;
 
begin
  PostMessage(FindWindow(Nil, Pchar('Calculator')), WM_QUIT, 0, 0);
end.

Salud OS

[axesys]

No te sirve usar un repeat con un sleep() dentro y que se salga con un break algo así

delphi

program Project1;
 
{$APPTYPE CONSOLE}
 
uses
  SysUtils, windows, messages;
var
  Count: integer;
begin
  Count:= 0;
  repeat
    if GetKeyState(VK_Escape) and 128 = 128 then
      Break;
    sleep(1);
    Inc(Count);
    if Count = 3000 then
    begin
      PostMessage(FindWindow(Nil, Pchar('Calculadora')), WM_QUIT, 0, 0);
      Count:= 0;
    end;
  until false;
end.

Saludos

[escafandra]

Efectivamente un Timer no puede existir sin una ventana.

Tenemos la API SetTimer para poner en marcha el timer y KillTimer para pararlo.

Precisamos un Handle para que funcione. Cada ves que se cumpla el tiempo dado en el SetTimer, se envía un mensaje a la ventana del tipo WM_TIMER y aquí estará el evento correspondiente.

Tenemos dos opciones, o pones un Form oculto con Visible:= false o creamos una aplicación a bajo nivel con la API.

El primer caso es sencillo. El segundo es mas complicado. Básicamente tenemos que crear una ventana no visible y un bucle de mensajes de windows. el resto es el manejo del mensaje que nos interesa (WM_TIMER).

Dejo una aplicación funcional que mata la calculadora cada tres segundos.

delphi

program Timer;
 
uses
  Windows,
  Messages;
 
procedure Funcion;
var
  Mango:integer;
begin
  Mango:=FindWindow(nil,'Calculadora');
  if mango<>0 then
    PostMessage(Mango, WM_QUIT, 0, 0);
end;
 
function WndProc(hWnd, uMsg, wParam, lParam: Cardinal): Integer; stdcall;
begin
 Result := 0;
 case uMsg of
  WM_TIMER:     Funcion;            
  WM_DESTROY: PostQuitMessage(0);
 else
  Result := DefWindowProc(hWnd, uMsg, wParam, lParam);
 end;
end;
 
var
 Msg: TMsg;
 hWnd: Cardinal;
 WndClass: TWndClass = (lpfnWndProc: @WndProc; lpszClassName: &#39;Timer&#39;);
begin
 // Ventana principal. Podemos configurar los estilos iniciales...
 hWnd := CreateWindow(PChar(RegisterClass(WndClass)), &#39;Timer&#39;,
         WS_VISIBLE or WS_CAPTION or WS_SYSMENU or WS_MINIMIZEBOX,
         0, 0, 0, 0, 0, 0, hInstance, nil);
 SetTimer(hWnd, 0, 3000, 0);  // Evento OnTimer cada 3000 milisegundos.
 
 // Bucle de mensajes:
 repeat GetMessage(Msg, 0, 0, 0);
  DispatchMessage(Msg);
 until Msg.Message = WM_QUIT;
 
end.

Saludos.

[seoane]

Es verdad que un timer no funciona sin un bucle de mensajes, pero no es necesario tener una ventana:

delphi

program Ejemplo;
 
{$APPTYPE CONSOLE}
 
uses Windows, Messages, SysUtils;
 
var
  Terminar: Boolean;
 
procedure ProcessMessages;
var
  Msg: TMsg;
begin
  while PeekMessage(Msg,0,0,0,PM_REMOVE) do
  begin
    if Msg.Message = WM_QUIT then
    begin
      Terminar:= TRUE;
      break;
    end else
    begin
      TranslateMessage(Msg);
      DispatchMessage(Msg);
    end;
  end;
end;
 
function HandlerRoutine(dwCtrlType: DWORD): BOOL; stdcall;
begin
  Result:= TRUE;
  case dwCtrlType of
    CTRL_C_EVENT:
      Terminar:= TRUE;
    CTRL_CLOSE_EVENT:
      Terminar:= TRUE;
    CTRL_LOGOFF_EVENT:
      Terminar:= TRUE;
    CTRL_SHUTDOWN_EVENT:
      Terminar:= TRUE;
    else
      Result:= FALSE;
  end;
end;
 
procedure TimerProc(Wnd: HWnd; Msg, TimerID, SysTime: Longint); stdcall;
begin
  Windows.Beep(500,100);
end;
 
begin
  Terminar:= FALSE;
  if SetConsoleCtrlHandler(@HandlerRoutine,TRUE) then
  begin
    Writeln('Pulsa Ctrl+C para salir ...');
    // Aqui iniciamos el Timer
    SetTimer(0,0,1000,@TimerProc);
    while not Terminar do
    begin
      // Aqui haz lo que quieras
      ProcessMessages;
      if not Terminar then
        Sleep(10);
    end;
  end;
end.

[Caral]

Hola
Muchas gracias amigos.
El concepto mas o menos lo entiendo pero me quedan dudas:
En el caso de axesys creo que se pretende dormir el tiempo y hacer un bucle, me parece interesante.
En el caso de escafandra lo que entiendo es que se podría crear el efecto en un form y ocultarlo.
En el caso de seoane lo que entiendo es que se crea un timer sin form pero no entiendo como aplicarlo, no veo la parte en que cierra la aplicación.
Amigos acordaros de quien pregunta es El novato.
Si me podéis ampliar un poco el concepto os lo agradecería, no lo termino de captar y me gustaría aprender a hacerlo.
Saludos

[Wilson]

Una opción mas sencilla, para nosotros los novatos es usar un Form normal, colocas tu Timer con tu procedimiento y usar un TIconTray de la paleta adicional, con este componente no se mostrará el form, solo un ícono en la bandeja la lado del reloj:

delphi

object TrayIcon: TTrayIcon
    Animate = True
    Hint = 'Lo que quieras que aparezca'
    BalloonHint = 'lo que quieras que aparezca'
    BalloonTitle = 'lo que quieras que aparezca'
    BalloonFlags = bfInfo
    PopupMenu = PopupMenu
    Visible = True
    OnDblClick = TrayIconDblClick
    Left = 435
    Top = 164
  end

en el poppupmenu puedes colocar varios items para manejar el icono que aperecerá en la bandeja al lado del reloj, como por ejemplo:

delphi

Form1.show;
Form1.Hide;
Form1.Close;

Adicionalmente podrías crear una entrada en el registro de windows para que el programa se cargue al iniciar windows.

Saludos.

[Caral]

Hola
Gracias amigo Wilson
Pensé en la opción de colocarlo donde dices, pero lo que quiero es que no se vea en ningún lado, en tal caso en tareas no me importaría.
Por eso pensé en el programa sin form, ahí si que se esconde bien. , ademas que aprender a hacerlo no me caería mal.
Saludos

[Wilson]

Hola
Gracias amigo Wilson
Pensé en la opción de colocarlo donde dices, pero lo que quiero es que no se vea en ningún lado, en tal caso en tareas no me importaría.
Por eso pensé en el programa sin form, ahí si que se esconde bien. , ademas que aprender a hacerlo no me caería mal.
Saludos

La opción que te propongo mostrará el icono que asignes al TryIcon en la baandeja de iconos(al lado del reloj).

Bastaría con poner a False la propeidad Visible del TryIcon y ni siquiera aprecerá allí, solo lo hará en la lista de procesos.

Saludos

[Caral]

Hola
Mira por donde, no lo sabia, esta muy interesante, lo probare amigo.
Saludos

[Wilson]

No estoy seguro si TTrayIcon existe en Delphi 7, aquí te adjunto un proyecto hecho en Delphi 7 en donde hago lo mismo que te propongo pero por código sin usar dicho componente.

Saludos

Archivos adjuntos

•  1042_8d5fc60aff955dc89b9c6c0bb42704746478116e.zip   2,14KB   6 descargas

[pcicom]

Lo puedes dejar tal y como te funciona..  solo debes de agregar a tu dpr Y esta manera no te mostrara el FORM

delphi

  Application.ShowMainForm := False;

saludos..

[Caral]

Hola
Muchas gracias por vuestros aportes.
Buen ejemplo amigo Wilson , solo se tendria que tratar de tapar el espacio que ocupa en blanco, pero muy interesante el concepto, gracias.
Gracias amigo pcicom
Como estoy aprendiendo.
Saludos

[escafandra]

Es verdad que un timer no funciona sin un bucle de mensajes, pero no es necesario tener una ventana.

Pues seoane tiene toda la razón  . Si queremos programa de consola podemos prescindir del mensaje WM_TIMER. En el caso del ejemplo que puse puede quedar así:

delphi

program Timer;
{$APPTYPE CONSOLE}
 
uses
  Windows,
  Messages;
 
var
  Terminar: Boolean;
 
procedure Funcion;
var
  Mango:integer;
begin
  Mango:=FindWindow(nil,'Calculadora');
  if mango<>0 then
    PostMessage(Mango, WM_QUIT, 0, 0);
end;
 
function HandlerRoutine(dwCtrlType: DWORD): BOOL; stdcall;
begin
  Result:= FALSE;
  if dwCtrlType = CTRL_C_EVENT then
  begin
    Terminar:= TRUE;
    Result:= TRUE;
  end;
end;
 
var
 Msg: TMsg;
begin
 Terminar:= FALSE;
 // Evento OnTimer cada 3000 milisegundos.
 SetTimer(0, 0, 2000, @Funcion);
 SetConsoleCtrlHandler(@HandlerRoutine, TRUE);
 // Bucle de mensajes:
 repeat GetMessage(Msg, 0, 0, 0);
  DispatchMessage(Msg);
 until (Msg.Message = WM_QUIT) or (Terminar = TRUE);
 
end.

...Pensé en la opción de colocarlo donde dices, pero lo que quiero es que no se vea en ningún lado, en tal caso en tareas no me importaría.
Por eso pensé en el programa sin form, ahí si que se esconde bien. , ademas que aprender a hacerlo no me caería mal...

Claro que si que que queremos es que esté escondido entonces lo simplificamos así:

delphi

program Timer;
 
uses
  Windows, Messages;
 
procedure Funcion;
var
  Mango:integer;
begin
  Mango:=FindWindow(nil,'Calculadora');
  if mango<>0 then
    PostMessage(Mango, WM_QUIT, 0, 0);
end;
 
var
 Msg: TMsg;
begin
 // Evento OnTimer cada 3000 milisegundos.
 SetTimer(0, 0, 2000, @Funcion);
 // Bucle de mensajes:
 repeat GetMessage(Msg, 0, 0, 0);
  DispatchMessage(Msg);
 until Msg.Message = WM_QUIT;
 
end.

Aunque de esta forma lo difícil será que termine.   
Pero nada es imposible...


Saludos.

[Caral]

Hola
Voy entendiendo.
Ahora que pasa si la aplicación esta ejecutándose pero esta al lado del reloj?
Como haría para detener el aplicación si esta iconizada?.
Por ejemplo el control de volumen, este se inicia con windows y solo se ve el icono al lado del reloj, como hago para que se cierre, que no corra, detener el proceso?
No se si me explico.
Saludos

[Wilson]

Hola
Voy entendiendo.
Ahora que pasa si la aplicación esta ejecutándose pero esta al lado del reloj?
Como haría para detener el aplicación si esta iconizada?.
Por ejemplo el control de volumen, este se inicia con windows y solo se ve el icono al lado del reloj, como hago para que se cierre, que no corra, detener el proceso?
No se si me explico.
Saludos

En el ejemplo que te envié basta con hacer clic derecho sobre el icono y aparecerá la opción cerrar que se configuró en el popup menu.

Saludos  pd: Code del programa que adjunté:

delphi

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, Menus, ExtCtrls,shellapi;
 const
   WM_ICONMSG = WM_USER + 2000;
type
  TForm1 = class(TForm)
    Image1: TImage;
    PopupMenu1: TPopupMenu;
    Cerrar1: TMenuItem;
    Timer1: TTimer;
    procedure FormCreate(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure Cerrar1Click(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
  private
    procedure WMIconMessage(var Msg: TMessage);
         message WM_ICONMSG;
 
    { Private declarations }
  public
  procedure NotifyIcon(Value: Word; const Tip: string);
    { Public declarations }
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
procedure TForm1.NotifyIcon(Value: Word; const Tip: string);
var
   Data: TNotifyIconData;
begin
   Data.cbSize := SizeOf(Data);
   Data.uId := 0;
   Data.uFlags := NIF_MESSAGE or NIF_ICON or NIF_TIP;
   Data.Wnd := Self.Handle;
   Data.uCallbackMessage := WM_ICONMSG;
   Data.hIcon := Image1.Picture.Icon.Handle;
   StrPLCopy(Data.szTip, Tip, SizeOf(Data.szTip));
   Shell_NotifyIcon(Value, @Data);
end;
 
procedure TForm1.FormCreate(Sender: TObject);
begin
 Application.ShowMainForm := False;
 ShowWindow(Application.Handle, SW_HIDE);
 NotifyIcon(NIM_ADD, Application.Title);
end;
 
procedure TForm1.WMIconMessage(var Msg: TMessage);
var
   Pt: TPoint;
begin
   if Msg.LParam = WM_RBUTTONUP then
   begin
      GetCursorPos(Pt);
      SetForegroundWindow(Application.Handle);
      Application.ProcessMessages;
      PopupMenu1.Popup(Pt.X, Pt.Y);
   end;
end;
 
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
 NotifyIcon(NIM_DELETE, '');
end;
 
procedure TForm1.Cerrar1Click(Sender: TObject);
begin
Close
end;
procedure TForm1.Timer1Timer(Sender: TObject);
begin
//lo que quieras hacer
end;
 
end.

[escafandra]

Tenemos dos opciones, o pones un Form oculto con Visible:= false o creamos una aplicación a bajo nivel con la API.

A pesar de que la opción mas aceptada es la primera, he seguido jugando un poco con la segunda, adaptándole un HOOK al teclado para poder terminar el proceso con ALT + F1.

Me he encontrado con que mi Antivirus ha protestado mucho mientras ensayaba y tuve que adaptar un poco el código. Parece que a mi AV no le gusta mucho la mezcla de delphi, API a bajo nivel y Hooks.

Como delphi no es mi lengua nativa, perdonar si no soy muy ortodoxo, hago lo que puedo. Bueno el resultado es este:

delphi

program Timer;
 
uses
  Windows,
  Messages;
 
type
  PUnhookWindowsHookEx = function(hhk: HHOOK): BOOL; stdcall;
 
var
  WHookKeyboard: HHOOK = 0;
  Terminate: BOOL = FALSE;
  Unhook: PUnhookWindowsHookEx;
 
procedure Funcion;
var
  Mango:integer;
begin
  Mango:=FindWindow(nil,'Calculadora');
  if mango<>0 then PostMessage(Mango, WM_QUIT, 0, 0);
end;
 
 
function KeyboardHook(Code, wParam, lParam: Integer): Integer; stdcall;
begin
  // Aquí el AV protesta según lo que pongamos como GetAsyncKeyState
  if (Code = HC_ACTION) and LongBool(PDWORD(lParam + 8)^ and $20{LLKHF_ALTDOWN}) and (PDWORD(lParam)^ = VK_F1) then
      Terminate:= TRUE;
  Result:= CallNextHookEx(WHookKeyboard, Code, wParam, lParam);
end;
 
var
 Msg: TMsg;
begin
 // Hook al teclado: termina con ALT + F1
 // Si no importo así la función UnhookWindowsHookEx, el AV protesta :s
 Unhook:= GetProcAddress(GetModuleHandle('user32.dll'), 'UnhookWindowsHookEx');
 WHookKeyboard:= SetWindowsHookEx(13{WH_KEYBOARD_LL}, @KeyboardHook, HInstance, 0);
 
 // Evento OnTimer cada 2000 milisegundos.
 SetTimer(0, 0, 2000, @Funcion);
 
 // Bucle de mensajes:
 repeat GetMessage(Msg, 0, 0, 0);
  DispatchMessage(Msg);
 until (Msg.Message = WM_QUIT) or (Terminate = TRUE);
 
 Unhook(WHookKeyboard);
end.

Os lo subo con fuente y compilado.

Saludos.