16 respuestas en este tema

[TiammatMX]

¿Cuántas veces hemos tenido un TDbGrid que el cliente o el diseñador quiere que ocupe la pantalla y no presente huecos en la rejilla?

Pues entonces, aquí está la solución:

En la creación de nuestra forma, tendremos algo así.

delphi

procedure TForm1.FormCreate(Sender: TObject);
begin
//Asignamos a la propiedad TAG del DBGrid el ancho
//mínimo que deseamos utilizar. 40 pixeles.
   Table1.FieldByName('FirstName').Tag := 40;
 
//Ahora, el valor de cada título: Ancho de la
// columna de título.
   Table1.FieldByName('LastName').Tag := 4 + Canvas.TextWidth(Table1.FieldByName('LastName').DisplayName);
end;

En el código anterior, obtendremos de una tabla de una base de datos el ancho de cada columna de nuestro TDbGrid, lo que nos permitirá hacer el cálculo y mostrar una rejila limpia y pareja.

Ahora, llamaremos a nuestra función que nos permitirá visualizar correctamente nuestra rejilla.

delphi

procedure TForm1.FormResize(Sender: TObject);
begin
   FixDBGridColumnsWidth(DBGrid1);
end;

Y ahora, la función que nos permitirá hacer todo el trabajo. Y poner a nuestro cliente como un defensor más de Delphi.

delphi

procedure FixDBGridColumnsWidth(const DBGrid: TDBGrid);
var
   i : integer;
   TotWidth : integer;
   VarWidth : integer;
   ResizableColumnCount : integer;
   AColumn : TColumn;
begin
//Ancho total de todas las columnas antes de procesar
   TotWidth := 0;
//Cómo dividir el espacio sobrante de nuestras columnas
   VarWidth := 0;
//Cuantas columnas se procesarán
   ResizableColumnCount := 0;
   for i := 0 to -1 + DBGrid.Columns.Count do
   begin
      TotWidth := TotWidth + DBGrid.Columns[i].Width;
      if DBGrid.Columns[i].Field.Tag <> 0 then
         Inc(ResizableColumnCount);
   end;
 
//Sumar un pixel para la línea de separación
   if dgColLines in DBGrid.Options then
      TotWidth := TotWidth + DBGrid.Columns.Count;
 
//Agregar el ancho del indicador de columna
   if dgIndicator in DBGrid.Options then
      TotWidth := TotWidth + IndicatorWidth;
 
//width vale "left"
   VarWidth := DBGrid.ClientWidth - TotWidth;
 
//Distribuir equitativamente VarWidth
//a todas las columnas que se procesarán
   if ResizableColumnCount > 0 then
      VarWidth := varWidth div ResizableColumnCount;
 
   for i := 0 to -1 + DBGrid.Columns.Count do
   begin
      AColumn := DBGrid.Columns[i];
      if AColumn.Field.Tag <> 0 then
         begin
            AColumn.Width := AColumn.Width + VarWidth;
            if AColumn.Width < AColumn.Field.Tag then
               AColumn.Width := AColumn.Field.Tag;
         end;
   end;
 
end; (*FixDBGridColumnsWidth*)

Y listo...

Se aceptan comentarios y modificaciones para mejorar éste pequeño código.

[enecumene]

Muchas gracias amigo, muy buen aporte

[egostar]

Muy buen truco, gracias amigo Felipe

Salud OS

[TiammatMX]

Y como una solución alterna (en el inicio de éste hilo, consigno el uso de TADOTable) en el caso de usar TADOQuery, programé éste pequeño procedimiento que me ha servido a las mil maravillas...

delphi

procedure TfrmPrincipal.AjustaRejilla(dbgRejilla: TDBGrid;aqQuery: TADOQuery);
var
  iIndc, iIndcdr, iTmn1, iTmn2, iSmaAnch, iCmplmnt : integer;
  sNmbrCmp : string;
begin
  with aqQuery do
  begin
    iSmaAnch := 0;
    for iIndc := 0 to FieldCount -1 do
    begin
      sNmbrCmp := Fields.Fields[iIndc].FieldName;
      for iIndcdr := 0 to dbgRejilla.Columns.Count -1 do
      begin
        if dbgRejilla.Columns.Items[iIndcdr].FieldName = sNmbrCmp then
        begin
          iTmn1 := Trunc(Length(dbgRejilla.Columns.Items[iIndcdr].Title.Caption)*5);
          iTmn2 := Fields.Fields[iIndc].Size;
 
          dbgRejilla.Columns.Items[iIndcdr].Width := Trunc(Iif(iTmn1 > iTmn2, iTmn1, iTmn2));
          iSmaAnch := iSmaAnch + dbgRejilla.Columns.Items[iIndcdr].Width;
        end;
      end;
    end;
 
// Aquí se calcula el complemento de tamaño en caso que los datos no llenen completamente el ancho de la pantalla.
    if dbgRejilla.Width > iSmaAnch then
    begin
      iCmplmnt := Round(((dbgRejilla.Width-(dbgRejilla.Columns.Count*2))-iSmaAnch)/(dbgRejilla.Columns.Count+0.15));
      for iIndcdr := 0 to dbgRejilla.Columns.Count -1 do
        dbgRejilla.Columns.Items[iIndcdr].Width := dbgRejilla.Columns.Items[iIndcdr].Width+iCmplmnt;
    end;
  end;
end;

[egostar]

Ah vaya, un año después, otra alternativa

Saludos

[Caral]

Hola

Ah vaya, un año después, otra alternativa

Saludos

Eso demuestra que nunca es tarde para aprender una forma nueva.
Saludos

[TiammatMX]

...Ah vaya, un año después, otra alternativa ...

Perro nuevo SÍ aprende nuevos trucos... Y en éste caso, fue por necesidad que tuve que programar otra alternativa, sobre todo más eficaz y veloz. Espero haberlo logrado.

[Rolphy Reyes]

Saludos.

Vengo como nata en el pastel, los JEDI tienen en su GRID tienen la propiedad AutoWidthColumn y son Open Source.

Sorry!

[TiammatMX]

... JEDI tienen en su GRID tienen la propiedad AutoWidthColumn y son Open Source...

Pero acuérdate que yo tengo PROHIBIDÍSIMO en el trabajo usar componentes de terceros..., tengo que ingeniármelas para cumplir los requerimientos y ésa regla absurda... 

[enecumene]

Amigo Felipe.MX tuve problemas al implementar tu alternativa, en la linea 19 tienes esto:

delphi

dbgRejilla.Columns.Items[iIndcdr].Width := Trunc(Iif(iTmn1 > iTmn2, iTmn1, iTmn2));

Es eso correcto? que version utilizas? yo utilizo la version 2007.

Saludos.

[Rolphy Reyes]

... JEDI tienen en su GRID tienen la propiedad AutoWidthColumn y son Open Source...

Pero acuérdate que yo tengo PROHIBIDÍSIMO en el trabajo usar componentes de terceros..., tengo que ingeniármelas para cumplir los requerimientos y ésa regla absurda... 

Saludos.

Sí que es una regla absurda, creo mas bien en controlar los componentes a utilizar.

En el trabajo tenemos una cantidad limitada de los componentes de terceros y si se necesitara alguno nuevo se hace un consenso y demás cosas en cuestión.

[TiammatMX]

Amigo Felipe.MX tuve problemas al implementar tu alternativa, en la linea 19 tienes esto:

delphi

dbgRejilla.Columns.Items[iIndcdr].Width := Trunc(Iif(iTmn1 > iTmn2, iTmn1, iTmn2));

Es eso correcto? que version utilizas? yo utilizo la version 2007.

Saludos.

Delphi 6 y vagos recuerdos de Clipper..., ésa función Iif la hice yo para un propósito específico, y la pongo aquí. Perdón por la confusión, enecumene... 

delphi

function Iif(bCondicion: Boolean; vValor1, vValor2: variant): variant;
begin
  if bCondicion then
    Result := vValor1
  else
    Result := vValor2;
end;

[egostar]

... JEDI tienen en su GRID tienen la propiedad AutoWidthColumn y son Open Source...

Pero acuérdate que yo tengo PROHIBIDÍSIMO en el trabajo usar componentes de terceros..., tengo que ingeniármelas para cumplir los requerimientos y ésa regla absurda... 

Saludos.

Sí que es una regla absurda, creo mas bien en controlar los componentes a utilizar.

En el trabajo tenemos una cantidad limitada de los componentes de terceros y si se necesitara alguno nuevo se hace un consenso y demás cosas en cuestión.

Caramba!!!!, cuando tenga mi empresa voy a tener ¡¡¡¡ REGLAS ABSURDAS  !!!!

Salud OS

[enecumene]

Usted tranquilo amigo Felipe.mx de vez en cuando nos pasa, gracias por pasarme la funcion, mañana te comento mis resultados.

Saludos.

[enecumene]

Bueno, ayer probé tu código y no me funcionó, al final tengo un tremendo hueco, o es que debo asignar el tamaño de cada columna en el Size del campo persistente del DataSet?.

Saludos.

[TiammatMX]

Bueno, ayer probé tu código y no me funcionó, al final tengo un tremendo hueco, o es que debo asignar el tamaño de cada columna en el Size del campo persistente del DataSet?.

Saludos.

Dos preguntas, ¿lo utilizas como una función? Me refiero a que cada vez que es llamada, toma el ancho visual de la rejilla y la calcula en referencia a la sumatoria del tamaño de cada columna para añadir un complemento (segunda parte de la función). Creo que ésta parte es la que te está faltando.

Referente a lo de los tamaños, como interroga directamente a cada columna por su tamaño en la tabla, no es necesario ponerle el tamaño (Size) al DataSet...

[enecumene]

Pues la tengo tal cual como lo colocaste incluyendo la funcion Iif, y nada pues, algo mal estare haciendo.

Saludos.