20 respuestas en este tema

[thelibmx]

Hola amigos aqui haciendo  una tormenta de un vaso de agua, quiero comparar dos cadenas o mas bien, quiero ver si una cadena se encuentra dentro de otra  pero la situación es un tanto especial ya que los valores estan separados por comas he estado investigando un poco y he dado con diversas funciones Pos,AnsiContainsStr, AnsiCompareStr, mis cadenas las obtengo de una base de datos, el caso es que cuando son de un caracter me funciona, pero cuando son dos o mas ya no y es ahí donde me atoro, el tipo de comparación es asi:

quiero saber si la cadena A se encuentra dentro de la cadena B
digamos que la cadena B son una serie de permisos,separados con coma y la cadena A es con el que cuenta,
ejemplo

A:="9"  y  B:="01,02,1,05,3,06,9,8,07,11,23,45,65,35"

el 9 si se encuentra dentro de la cadena B
entonces si tiene acceso


y ahi todo bien, pero cuando es de dos digitos digamos

A:=07  y  B:="01,02,1,05,75,3,06,9,8,5,11,23,45,65,35"

ahi ya no va bien la cosa , pues me detecta que si hay un 0 o 7 y me deja entrar pero no existe en realidad el permiso 07

entonces para que pueda accesar la cadena debe de contener dentro de ella el 07 asi

A:=07
B:="01,02,1,05,75,3,06,9,8,5,11,23,07,45,65,35"


no se si me explique bien el caso es que yo tengo algo asi

delphi

if AnsiContainsStr (B,A) then
begin
  showmessage('Acceso con exito');
end
else begin
MessageBox(Handle,PChar('No cuenta con el permiso correspondiente');
end;

No se si sea la manera mas correcta de hacerlo, pero es mas o menos el proceso,y me deja pasar aun cuando no hay ese tipo de permiso, espero haberme explicado bien si no cualquier duda la respondere, agradezco cualquier ayuda,consejo o sugerencia que me puedan dar...

[enecumene]

La situación aquí es diferente porque se trata de números enteros y esa función está hecho más para texto que números, aquí hay que realizar una especie de algoritmo que elimine el cero por delante o formatear los valores con format y luego comparar la cadena, es todo lo que se me ocurre, pues no conozco una función similar para números, a ver qué dicen los maestros.

Saludos.

[egostar]

Y que tal una chapuza de las que se acostumbran por aquí

delphi

procedure TForm1.Button1Click(Sender: TObject);
var
  A,B: string;
begin
  A:= '06';
  B:= '01,02,1,05,75,3,06,9,8,5,11,23,45,65,35';
  if AnsiContainsStr ( ','+B+',' , ','+A+',' ) then // le agregas las comas a ambas variables y prueba :)
  begin
    showmessage('Acceso con exito');
  end
  else begin
         ShowMessage('No cuenta con el permiso correspondiente');
  end;
end;

Salud OS

[thelibmx]

egostar  Maestro de Maestros muchas gracias, su chapuza como magia, "Pequeñas cosas que hacen grandes cosas"

[egostar]

Ah que bien que le sirvio, me alegra mucho

Salud OS

[egostar]

Hola de nuevo

También podemos hacer algo mas ortodoxo, pero implica que tengas que rediseñar la logica de tus permisos es decir que no haya 01 y 1 que todos tus permisos sean diferentes al convertirlos a entero. Te daré la idea y tu decides si te sirve o lo dejas como quedó.

delphi

type
  TInteger = 1..255;
  TIntSet = set of TInteger;
 
var
  Privilegios: TIntSet;
 
procedure TForm1.AsignaPrivilegios;
begin
  Privilegios := [];
  Table1.Open;
  if Table1.RecordCount > 0 then
  begin
    while not Table1.Eof do
    begin
      // Se agregan los privilegios al set de privilegios
      Include(Privilegios,Table1.FieldByName('privilegios').AsInteger);
      Table1.Next;
    end;
  end;
  Table1.Close; 
end;
 
procedure TForm1.Button1Click(Sender: TObject);
begin
  if StrtoInt(Edit1.Text) in Privilegios then
  begin
    showmessage('Acceso con exito');
  end
  else begin
         ShowMessage('No cuenta con el permiso correspondiente');
  end;
end;

Salud OS

[enecumene]

Una opción más:

delphi

function CompareInt(Value1, Value2: string; delimiter: Char): Integer;
var
  Permisos: TStringList;
  i,c: Integer;
  Value3, dato : string;
begin
  c := 0;
  Value3 := '';
  if Copy(Value1,1,1) = '0' then
        Value1 := StringReplace(Value1, '0', '', [rfReplaceAll]);
 
  Permisos := TStringList.Create;
  Assert(Assigned(Permisos));
  Permisos.Clear;
  Permisos.Delimiter := delimiter;
  Permisos.DelimitedText := Value2;
  for i := 0 to Permisos.Count-1 do begin
     if Copy(Permisos.Strings[i],1,1) = '0' then
        value3 := value3 + StringReplace(Permisos.Strings[i],'0','', [rfReplaceAll]) +','
     else begin
        value3 := value3 + Permisos.Strings[i] +',';
        Inc(c);
     end;
  end;
 
  if AnsiContainsStr(Value3, Value1) then
     Result := 1
  else
     Result := -1;
end;
 
procedure TForm1.btn1Click(Sender: TObject);
var A,B: string;
begin
A := '01';
B := '01,10,20,30';
 
  if CompareInt(A,B,',') = 1 then
     ShowMessage('Acceso permitido')
  else
     ShowMessage('No tienes permisos');
end;

Al igual que Egostar debes redefinir los permisos, que no existan 01 y 1 y similares.

Saludos.

[pcicom]

Si la cantidad de los permisos que defines son de 3 digitos, deberas de homologar y grabar todos los permisos con esa misma estructura..

Ejemplo:

A=100
B="001,002,050,030,003,120,089"

Ya que de esta forma siempre tendrias segun los permisos una opcion definida, y si no la homologas tendrias algunos problemas de coincidencias a permisos no definidos.

Ejemplo

A=7
B="1,2,3,17,30,57,107"    <--  Si la ENCONTRARIA pero no seria el PERMISO INDICADO

[kafastoforman]

Que tal muchachos, solo una pequeña duda que me surgio:

¿Por que no utilizan la funcion POS?

tal vez algo asi se podria hacer

delphi

var 
  a,b: string;
 
begin
  a:= '09';
  b:= '01,02,03,04,05';
 
  if pos(a,b) <> 0 then
    showmessage('Acceso con exito')
  else
    showmessage('no cuenta con los permisos necesarios');
 
end;

saludos

Kafastoforman

[pcicom]

POS NO SÈ PORQUE   

[egostar]

Hola amigo Kafastoforman

El problema del POS como en las demas funciones es que en la lógica que maneja nuestro amigo thelibmx contiene números de un digito, por lo que si haces un post a este ejemplo

delphi

var 
  a,b: string;
begin
  a:= '5';
  b:= '01,05,55,35,50';
   if pos(a,b) <> 0 then
    showmessage('Acceso con exito')
  else
    showmessage('no cuenta con los permisos necesarios');
 
end;

El resultado es incorrecto ya que encuentra que el 5 existe en la cadena, pero en realidad no existe el número '5'.

Salud OS

[kafastoforman]

haaaaaaa

entonces podriamos hacer esto no?

delphi

var 
  a,b,amarre: string;
  digitos: integer;
 
begin
  digitos:= 2;
  amarre:= '00000';
  a:= amarre + '5';
  b:= '01,05,55,35,50';
   if pos(copy(a,length(a)-digitos,digitos),b) <> 0 then
    showmessage('Acceso con exito')
  else
    showmessage('no cuenta con los permisos necesarios');
 
end;

y cambiando digitos, podriamos elegir la cantidad de digitos que se desee

¿que tal?

Saludos kafastoforman

[egostar]

, interesante, el asunto es que como te digo la lógica que se sigue en este problema es que no es lo mismo 05 que 5 así que debe encontrarse exactamente el valor deseado, la chapuza que publiqué hace lo que nuestro amigo desea, sin complicaciones y sin bug's (como a primera vista se podría pensar, jejejeje).

Salud OS

[kafastoforman]

jajajajaja ya entendí, por eso te digo que la chapuza esta ley, jejejeje.

Me costo trabajo entender que la longitud es variable y que asi como puede haber 05 puede haber 205 o 2005 o 2055 etc, jejejeje sorry.

Buenas noches

[escafandra]

Siguiendo con la tónica de considerar los permosos como enteros, siendo lo mismo 1 que 01, podemos implementar algo sencillo usando la VCL:

delphi

function TienePermiso(Permiso, Permitidos: String): boolean;
var
  Lista: TStringList;
  P, i: integer;
begin
  while Pos(',', Permitidos)>0  do
        Permitidos[Pos(',', Permitidos)]:= #13;
  Lista:= TStringList.Create();
  Lista.Text:= Permitidos;
  Result := False;
  for i:= 0 to Lista.Count-1 do
    if StrToInt(Lista[i]) = StrToInt(Permiso) then
    begin
      Result:= True;
      break;
    end;
    Lista.Free;
end;

Ejemplo de uso:

delphi

if TienePermiso('6', '01,02,05,75,3,06,9,8,5,11,23,07,45,65,35') then
     ShowMessage('Eureca');

Saludos.

[enecumene]

Ah caray, parece que me pasé de líneas

[kafastoforman]

jajaja esa es de apagar las luces e irse a dormir jejejeejej muy buen código 

solo, no vi donde se ocupa la variable de tipo entero P


saludos

[escafandra]

jajaja esa es de apagar las luces e irse a dormir jejejeejej muy buen código 

solo, no vi donde se ocupa la variable de tipo entero P


saludos

Efectivamente, esa variable se me coló. Podeis eliminarla.

Saludos.

[thelibmx]

Muchas Gracias a todos por responder, es interesante todos los aportes que me han dado los tomare en cuenta para futuros programas,y como comento egostar la cadena contiene valores de diferente longitud, mas que nada lo que me interesaba era que se pudiera encontrar la cadena de caracteres en conjunto  y no solo uno de sus caracteres,que era lo que me pasaba, su chapuza quedo bien y hasta el momento parece que no hay errores, a veces dicen que no hay que buscarle tres pies al gato jejej Gracias totales....

P.D. No se como funciona este foro, si tengo que darles las gracias a cada uno de los que respondieron pues todas sus respuestas son buenas o solo al que me ayudo a resolver el problema,como sea no me cuesta agradecer a cada uno 

[enecumene]

P.D. No se como funciona este foro, si tengo que darles las gracias a cada uno de los que respondieron pues todas sus respuestas son buenas o solo al que me ayudo a resolver el problema,como sea no me cuesta agradecer a cada uno...

A cada uno de los que consideres