11 respuestas en este tema

[eduarcol]

Estoy tratando de colocar una función en una DLL, he leído y buscado y según parece la forma es la siguiente:

Asi se crea la DLL:

delphi

library dlEncrip;
 
 
uses
  ShareMem,
  SysUtils,
  Classes;
 
{$R *.res}
 
//Desencripta la Clave
function Desencriptar(cCadena: string): String; stdcall;
var
   arClave: array[0..53] of Char;
   S, S1: string;
   nIndice, n, nLCadena: integer;
begin
   //La Carga a la matriz
 
**** codigo de la funcion ****
 
   Result := S;
end;
 
exports Desencriptar;
 
begin
 
 
end.

Así hago la llamada desde el programa:

delphi

function Desencriptar(cCadena: String): String; stdcall; external 'dlEncrip.dll';

Pero me lanza un

---------------------------
Debugger Exception Notification
---------------------------
Project dllprobando.exe raised exception class EAccessViolation with message 'Access violation at address 00392144 in module 'dlEncrip.dll'. Read of address 00120048'. Process stopped. Use Step or Run to continue.
---------------------------
OK  Help 
---------------------------

Justo en esta linea:

delphi

procedure TForm1.Button2Click(Sender: TObject);
begin
   Edit2.Text := Desencriptar(Edit1.Text);
end;

La DLL esta en la misma carpeta que el ejecutable, me estoy saltando algun paso?

[egostar]

No debería de ser así ?

delphi

library dlEncrip;
 
uses
  ShareMem,
  SysUtils,
  Classes;
 
{$R *.res}
 
//Desencripta la Clave
function Desencriptar(cCadena: string): String; export;
var
   arClave: array[0..53] of Char;
   S, S1: string;
   nIndice, n, nLCadena: integer;
begin
   //La Carga a la matriz
 
**** codigo de la funcion ****
 
   Result := S;
end;
 
exports Desencriptar;
 
begin
 
end.

Salud OS

[eduarcol]

Acabo de probar y nada... 

[egostar]

Acabo de probar y nada... 

Ah caramba!!!!, deja hacer una prueba.

Salud OS

[eduarcol]

Acabo de probar y nada... 

Ah caramba!!!!, deja hacer una prueba.

Salud OS

Si la prueba es de licores me avisas jejeje

[egostar]

jejeje, cabron

Pues a menos que sea algo dentro del código de la función de tu DLL no veo porque falla, a mi me funciona bien todo, hasta el cerebro

Te adjunto el código y los binarios de mi prueba del añejo

Salud OS

Archivos adjuntos

•  1603_6715966c4e2933613980c64ed2378d5b6b4ae12a.zip   9,4KB   5 descargas
•  1602_642475e292a48eb558cb620d914f05b884a03569.zip   269,23KB   5 descargas

[eduarcol]

Estoy haciendo una depuracion y ya veo que hay un problema con los valores que recibe:

delphi

cCadena := #0#0#0#0'l÷'#$12#0'ÖùB'#0'xBµ'#0'Õ€B'#0'¨÷'#$12#0'ɁB'#0'xBµ'#0';øB'#0'¨÷'#$12#0'¨÷'#$12#0'xBµ'#0'Þ'#7#$B#0#0#0#0#0' '#0#0#0'pö'#$12#0'Ø™:~'#$A'€'#0#0'üö'#$12#0'¢[:~'#$A'€'#0#0'Þ'#7#$B#0'üÿÿÿ'#0#0#0#0#0#0#0#0'„÷'#$12#0#$D'S:~'#1#0#0#0'˜uïw @ów;Ì'#0#0'6°;~‚°;~è„s'#0#$15#2#0#0#0#0#0#0#0#0#0#0#1#0#0#0'6°;~ðö'#$12#0'4‡9~Þ'#7#$B#0#$15#2#0#0#0#0#0#0#0#0#0#0'6°;~Í«ºÜ'#0#0#0#0',÷'#$12#0'6°;~X÷'#$12#0'Ù‹9~'#0'àýX÷'#$12#0' '#0#0#0'X÷'#$12#0'øëý'#0#0#0#0'8÷'#

[egostar]

Entonces tu problema está en el código de la función de la DLL.

Salud OS

[seoane]

¿Supongo que también estas añadiendo ShareMem a las uses del proyecto y no solo en la dll? 

ShareMem should always be the first unit listed in any program or library uses clause where it occurs

Ademas ese stdcall tampoco me gusta nada  , si realmente quieres algo "estándar" deberias de usar punteros (PChar) y no Strings.

[eduarcol]

Eso era lo que faltaba el ShareMem en el proyecto, si trabajo con pChar evito la necesidad de esa libreria?

[seoane]

Pues ya lo dice la ayuda de delphi:

On Win32, if a DLL exports routines that pass long strings or dynamic arrays as parameters or function results (whether directly or nested in records or objects), then the DLL and its client applications (or DLLs) must all use the ShareMem unit. The same is true if one application or DLL allocates memory with New or GetMem which is deallocated by a call to Dispose or FreeMem in another module.

Es decir, si no se pasan como parámetros strings o arrays dinámicos, y ademas cada modulo gestiona "su memoria" no hace falta usar ShareMem.

Y aquí un ejemplo de regalo:

delphi

library Prueba;
uses
  SysUtils,
  Classes;
 
{$R *.res}
 
function Test(Src, Dst: PChar; Count: PInteger): Integer; stdcall;
var
  Str: String;
begin
  Str:= String(Src);
  // Lo que quieras hacer con la cadena
  Str:= Str + Str + Str;
  if Length(Str) + 1 <= Count^ then
  begin
    StrCopy(Dst,PChar(Str));
    Result:= Length(Str);
  end else
  begin
    Result:= -1;
    Count^:= Length(Str) + 1;
  end;
end;
 
exports Test;
 
begin
end.

A la función se le pasa como parámetros un puntero a la cadena de origen, un puntero al resultado y un integer con el tamaño máximo (incluido el cero final) que puede tener el resultado. Si todo va bien la función devuelve el tamaño del resultado, pero si no tiene espacio suficiente devuelve -1 y el tamaño necesario lo guarda en el parámetro Count. Muchas funciones de la API funcionan así, no es nada nuevo

Un ejemplito:

delphi

function Test(Src, Dst: PChar; Count: PInteger): Integer; stdcall;
  external 'Prueba.dll';
 
function TestStr(Str: String): String;
var
  i: Integer;
begin
  Result:= EmptyStr;
  i:= 0;
  if Test(PChar(Str),nil,@i)= -1 then
  begin
    SetLength(Result,i);
    if Test(PChar(Str),PChar(Result),@i) < 0 then
      Result:= EmptyStr
    else
      SetLength(Result,StrLen(PChar(Result)));
  end;
end;
 
 
// Por ejemplo
ShowMessage(TestStr('Hola mundo'));

[eduarcol]

Ok Muchas gracias amigo, eso era todo doy el tema por resuelto.

Gracias a los dos por la ayuda