29 replies to this topic

[enecumene]

Pues eso, con esta función podemos contar la cantidad de palabras que existe en un string separado entre espacio:

delphi

function CuentaPalabras( s : string )
  : integer;
var
  ps      : PChar;
  nSpaces,
  n        : integer;
begin
  n  := 0;
  s  := s + #0;
  ps := @s[ 1 ];
  while ( #0 <> ps^ ) do
  begin
    while (' ' = ps^)and(#0 <> ps^) do
    begin
      inc( ps );
    end;
 
    nSpaces := 0;
    while (' ' <> ps^)and(#0 <> ps^) do
    begin
      inc( nSpaces );
      inc( ps );
    end;
    if ( nSpaces > 0 ) then
    begin
      inc( n );
    end;
  end;
  Result := n;
end;

Saludos.

[egostar]

Hey amigo, llevas 3 al hilo

Salud OS

[Caral]

Hola
Es que esta sacando el repertorio del baúl...
Saludos

[Master23]

No se puede mostrar viendo length de el string simplemente ?

[Delphius]

No se puede mostrar viendo length de el string simplemente ?

Pues me temo que no Master23. Length solamente regresa la longitud del string, y aquí lo que se busca es contar las palabras que éste tenga. Esto requiere más que un simple length.

Saludos,

[Fenareth]

No se puede mostrar viendo length de el string simplemente ?

No amigo, porque el length te muestra el total de caracteres contenido en un String, no el total de palabras

Saludox !

[Khronos]

Hola enecumene, buena función, pero creo que se puede pulir un poco más:

delphi

function CuentaPalabras(S: string): Cardinal;
var
i: integer;
begin
  result:= 0;
    S:= Trim(S);
    for i := 0 to Length(S) - 1 do
        if (S[i] = ' ') and (S[i + 1] <> ' ') then
          Inc(Result);
    If Length(S) > 0 then Inc(Result);
end;

Saludos.

[enecumene]

Excelente amigo Khronos, menos líneas mejor

[lezamablr]

O tambien:

delphi

var
  cuenta : TStringList;
begin
 
  cuenta := TStringList.Create;
 
  cuenta.Delimiter := ' ';
  cuenta.DelimitedText := 'Texto del cual se van a contar las palabras';
 
  ShowMessage(IntToStr(cuenta.Count));
 
  cuenta.Free;
end;

 

[egostar]

Hola lezamablr

Simple, ingenioso y efectivo

Salud OS

[Jagluiperd]

Muy, muy bueno.

Funciona incluso con la siguiente cadena:

delphi

    cuenta.DelimitedText := 'Texto  del  cual se  van a contar las palabras  ';

Solo falla si encuentra algún caracter que no conforma una palabra, como por ejemplo con la siguiente cadena:

delphi

  cuenta.DelimitedText := 'Texto  del  . , ? cual se  van a contar las palabras  ';

Ya que cuenta esos ". , ?" como si fuesen una palaba cada uno.

De ello desprendo la simple lógica del proceso:
1- Cualquier cosa al principio y al final de una cadena que no sea un SPACE, es una palabra ->Sumo.
2- Cualquier cosa que esté entre 2 SPACE, que no sea un SPACE, y que no esté al principio
    o al final de una cadena, es una palabra->Sumo.

Podría mejorarse, pero aún así es elegante, simple y efectiva.

Gracias por el aporte.

(Probado en Lazarus 0.9.28.2/WXP_SP3)

Saludos.

[bigleaguer]

A petición de Jagluiperd, podemos mejorar un poco más el método para que solo cuente las palabras con letras ó que contengan un símbolo ó número seguido de una letra, Por ejm: ¿Hola?.
NOTA: El código está escrito en Delphi 2010.

delphi

function CantidadPalabras(const AValor: string): Integer;
const
  CharSet: TSysCharSet = ['A'..'Z', 'Á'..'Ú', 'Ñ'];
var
  Cadena: TStringList;
  Str: string;
  Total: Integer;
begin
  Total  := 0;
  Cadena := TStringList.Create;
  try
    Cadena.DelimitedText := AnsiUpperCase(Trim(AValor));
 
    { Recorremos cada palabra }
    for Str in Cadena do
      if CharInSet(Str[1], CharSet) then
        Inc(Total)
      else if (Length(Str) > 1) and (CharInSet(Str[2], CharSet)) then
        Inc(Total);
 
    Result := Total;
  finally
    Cadena.Free;
  end;
end;

Y su uso sería:

delphi

var
Cant: Integer;
begin
  Cant := CantidadPalabras('Texto  del  . , ? cual se  van a contar las palabras  ');
// Cant. Palabras = 9
end;

Espero ayude un poco...

[Jagluiperd]

delphi

// Cant. Palabras = 9

Premio.

Gracias y un saludo.

[escafandra]

Propongo esta variante usando la API IsCharAlpha.

delphi

function ContarPalabras(const S: string): integer;
var
  i, L: integer;
begin
  L:= Length(S);
  Result:= 0;
  for i:= 1 to L do
    if IsCharAlpha(S[i]) and (S[i-1] = ' ') then inc(Result);
  if (L>0) and IsCharAlpha(S[L]) then inc(Result);
end;

Saludos.

[escafandra]

Y con esta otra versión, si me perdonáis el uso de punteros, mi propuesta para C/C++

cpp

int ContarPalabras(char* S)
{
  int Result = 0;
  int L = lstrlen(S);
  for(char *c = S; *c;)
    if(IsCharAlpha(*c++) && *c == ' ') Result++;
  if (L>0 && IsCharAlpha(*(S+L-1))) Result++;
  return Result;
}

Saludos.

[Jagluiperd]

Hola escafandra.

El código que propones no funciona al 100%.

Ejemplos de testeo:

delphi

ContarPalabras('Texto '); {Devuelve 0 Palabras}
ContarPalabras('Texto'); {Devuelve 1 Palabra}
ContarPalabras('Texto  del  . , ? cual se  van a contar las palabras'); {Devuelve 9 Palabas}
ContarPalabras('Texto  del  . , ? cual se  van a contar las palabras '); {Devuelve 8 Palabas}

Supongo que se deberá a la siguiente linea...

delphi

if (L>0) and IsCharAlpha(S[L]) then inc(Result);

... Cuando la cadena finaliza con caracter SPACE.

Si me lo permites, he retocado un poco el código para que recoja y recupere ese error, y
además hacerlo independiente del S.O. y de la versión de este, al no depender de API alguna:

delphi

{Añadir esta función tras la clausula Implementation}
Function IsCharAlpha(Const Caracter: Char): Boolean;
Begin
  {No tiene en cuenta caráteres especiales, solo letras y números}
  Result:=(Caracter IN['A'..'Z','a'..'z','0'..'9']);
End;
 
{...}
function ContarPalabras(const S: string): integer;
var
  i, L: integer;
begin
  L:= Length(S);
  While Not(IsCharAlpha(S[L])) do
    Begin
      dec(L);
    end;
  Result:= 0;
  for i:= 1 to L do
    Begin;
      if IsCharAlpha(S[i]) and (S[i-1] = ' ') then inc(Result);
    end;
  if (L>0) and IsCharAlpha(S[L]) then inc(Result);
 
end; 
 
{Ejemplos de testeo:
ShowMessage(IntToStr(ContarPalabras('Texto  del  . , ? cual se  van a contar las palabras. ? ')));
ShowMessage(IntToStr(ContarPalabras('Texto  del  . , ? cual se  van a contar las palabras')));
}

Saludos.

[escafandra]

oops    Cierto.

La función que propuse en C/C++ no tiene ese bug, por algo es mi lenguaje favorito .

Bueno, el problema se corrige mejor y mas simple de esta manera:

delphi

function ContarPalabras(const S: string): integer;
var
  i, L: integer;
begin
  L:= Length(S);
  Result:= 0;
  for i:= 0 to L-1 do
    if IsCharAlpha(S) and (S[i+1] = ' ') then inc(Result);
  if (L>0) and IsCharAlpha(S[L]) then inc(Result);
end;

Aunque todavía podemos preguntarnos una cosa. ¿Los caracteres numéricos cuentan? si es así debemos cambiar la API IsCharAlpha por IsCharAlphaNumeric
 

delphi

function ContarPalabras_(const S: string): integer;
var
  i, L: integer;
begin
  L:= Length(S);
  Result:= 0;
  for i:= 0 to L-1 do
    if IsCharAlphaNumeric(S[i]) and (S[i+1] = ' ') then inc(Result);
  if (L>0) and IsCharAlphaNumeric(S[L]) then inc(Result);
end;

Saludos.

[egostar]

Todos los días me recuerdan que debo aprender C++

Salud OS

[escafandra]

Todos los días me recuerdan que debo aprender C++

Salud OS

Amigo, el C/C++ es la base de la ciencia... . Es broma.

A pesar de su sintaxis, a mi me resulta mucho mas cómodo en tareas de bajo nivel y punteros. Creo que su sintaxis en esto ayuda mucho, al menos para mi es muy clara.

Aunque he de decir que mi experiencia escribiendo en delphi es limitada... 


Saludos.

[egostar]

Todos los días me recuerdan que debo aprender C++

Salud OS

Amigo, el C/C++ es la base de la ciencia... . Es broma.

A pesar de su sintaxis, a mi me resulta mucho mas cómodo en tareas de bajo nivel y punteros. Creo que su sintaxis en esto ayuda mucho, al menos para mi es muy clara.

Aunque he de decir que mi experiencia escribiendo en delphi es limitada... 


Saludos.

A eso me refiero, he hecho algunas cosas con java, con C#, cosas no complejas, pero la forma como utilizan los recursos de C me parece genial, la verdad es que aprendo mucho de todos ya sea C, RIA, SQL, etc... el punto es que la mayoría de las veces me cuesta trabajo entender el código

Salud OS