7 respuestas en este tema

[agag4]

Ya se ha tratado más de una vez este tema, lo quiero abrir de nuevo para ver si me pueden ayudar en que estoy mal, tengo una aplicación que esta monitoreando si se esta ejecutando otro programa, si no esta en ejecución lo mando llamar, para hacer eso tengo un timer y adentro del evento ontimer tengo lo siguiente:

delphi

  CreateMutex(nil, True, 'PROG_EXTERNO');
 
  // Si no esta en ejecución lo llamamos
  if GetLastError <> ERROR_ALREADY_EXISTS then
    WinExec('C:\PROG_EXTERNO.exe',6);

Todo funciona de maravilla la 1era vez que ejecuta el programa al revisar que no esta en ejecución, pero si intento cerrar el PROG_EXTERNO.exe atravez del administrador de tareas, vuelve entrar al evento ontimer en mi aplicación pero no lo llama porque aun supone que esta en ejecución 

Me faltará algun REFRESH como después de crear el Mutex ??

[felipe]

Podría pensar que no se libera completamente PROG_EXTERNO en la memoria; me sucedía algo similar al validar si un formulario estaba o no creado luego de cerrarlo por action := caFree, esto lo cambié con mejores resultado por FreeAndNil()... en fin, no va al caso, lo importante sería revisar como bien dices la forma de hacer un "refresh"


Saludos!

[seoane]

Para saber si un programa externo esta activo lo mejor es examinar la lista de procesos.

Aqui te dejo un ejemplo:

delphi

program watchdog;
 
uses
  Windows, SysUtils, PsApi, ShellApi;
 
function CuantosSon(Path: String): Integer;
var
  Procesos: array[1..1024] of DWORD;
  Needed, i: DWORD;
  Process: THandle;
  ModName: array[0..MAX_PATH] of Char;
begin
  Result:= 0;
  if EnumProcesses(@Procesos,SizeOf(Procesos),Needed) then
  begin
    for i:= 1 to (Needed div Sizeof(DWORD)) do
    begin
      Process := OpenProcess(PROCESS_QUERY_INFORMATION or PROCESS_VM_READ,
        FALSE,Procesos[i]);
      if Process <> 0 then
      begin
        if GetModuleFileNameEx(Process,0,ModName,SizeOf(ModName)-1)>0  then
        begin
          if StrIComp(ModName,PChar(Path)) = 0 then
            inc(Result);
        end;
        CloseHandle(Process);
      end;
    end;
  end;
end;
 
begin
  if ParamCount < 1 then
    Exit;
  if not FileExists(ParamStr(1))  then
    Exit;
  while TRUE do
  begin
    if CuantosSon(ParamStr(1)) < 1 then
      ShellExecute(0,nil,PChar(ParamStr(1)),nil,nil,SW_SHOW);
    // Aqui pones el retardo que quieras
    Sleep(1000);
  end;
end.

Por ejemplo si queremos tener el bloc de notas siempre abierto:

delphi

watchdog "C:\Windows\notepad.exe"

[felipe]

Podrías también cambiar la forma de capturar la ejecución de la aplicación.

Alguna vez elaboré este procedimiento:

delphi

//Añadir al uses TLHelp32
 
function TForm1.procrunning: Boolean;
var
  Proceso : TProcessEntry32;
  ProcessHandle : THandle;
  Sproceso   : Boolean;
  Nproceso : String;
begin
  Result := False;
  Proceso.dwSize := SizeOf(TProcessEntry32);
  ProcessHandle := CreateToolHelp32Snapshot(TH32CS_SNAPPROCESS, 0);
  if Process32First(ProcessHandle, Proceso) then
  begin
    Nproceso:= String(Proceso.szExeFile);
    repeat Sproceso := Process32Next(ProcessHandle, Proceso);
      Nproceso:= String(Proceso.szExeFile);
      if Nproceso = 'elproceso.exe' then
        Result := True;
    until not Sproceso;
  end;
  CloseHandle(ProcessHandle);
end;

El cual busca el proceso por su nombre y retorna un valor Falso o Verdadero.



Saludos!

[felipe]

seoane me ganaste por un click


Saludos!

[agag4]

Gracias compañeros, voy a probar sus sugerencias....

[escafandra]

El uso de tlhelp32 o enumerar los procesos es muy eficaz y es una forma bastante fiable de localizar si un proceso está corriendo aunque depende del nombre de dicho proceso...

El uso del mutex no es descartable en este caso. Si lo queremos usar, yo crearía el mutex en el proceso externo destruyéndolo al terminarse.

En el proceso principal colocaría algo así:

delphi

var
  Mutex: THandle;
begin
    Mutex:= CreateMutex(nil, FALSE, 'PROG_EXTERNO');
    if GetLastError = 0 then
      ShellExecute(0, 'open', Proceso_externo, Argumentos, nil, SW_HIDE);
    if Mutex<>0 then CloseHandle(Mutex);
 
end;

Este es el método que usé en una ocasión en un sistema de Vigilancia mutua entre dos procesos. El principal comprueba el mutex creado por el secundario, ese mutex se creaba con el nombre del principal que se pasa como parámetro al secundario usándolo para crear el mutex y arrancar al principal si no está en ejecución, comprobado esta vez usando tlhelp32 . El principal comprobaba el mutex de su propio nombre y si no existía ejecutaba al secundario.

Este sistema doble lo implementé porque el programa secundario lo usaba como vigilante de uno o dos procesos principales, de este modo podía tener una o dos copias del proceso vigilante secundario sin problemas. 

Saludos.

[agag4]

Gracias compañeros por sus sugerencias ya me funciono me fui por el método de felipe, probe los demas y tmb me funcionan, estuvo dificil la decisión por cual tomar