7 respuestas en este tema

[jc]

Hola a todos

Estaba haciendo un pequeño proyecto y me surgió hacer una lista de enteros, pensé usar un TList, pero nunca lo había usado y tampoco encontré mucha información, así que me armé un pequeño ejempo, pongo un poco de lo que hice:

delphi

//    VaciarLista
procedure TVprincipal.VaciarLista;
var
    i: integer;
    n: ^integer;
begin
    for i := 0 to (ListaEnteros.Count - 1) do
        begin
        n := ListaEnteros[i];
        Dispose(n);
        end;
    ListaEnteros.Clear;
end;
 
//    OnClose
procedure TVprincipal.FormClose(Sender: TObject; var CloseAction: TCloseAction);
begin
    VaciarLista;
    ListaEnteros.Free;
    CloseAction := caFree;
end;
 
//    OnShow
procedure TVprincipal.FormShow(Sender: TObject);
begin
    ListaEnteros := TList.Create;
    Randomize;
end;
 
//    edNum KeyPress
//
//    edNum es un componente TEditMask
procedure TVprincipal.edNumKeyPress(Sender: TObject; var Key: char);
var
    n: ^integer;
begin
    if Key = #13 then
    begin
    New(n);
    n^ := StrToInt(edNum.Text);
    ListaEnteros.Add(n);
    edNum.Clear;
    end;
end;
 
 
//    bLlenarClick
//
//    mete 10 enteros aleatorios en la lista
procedure TVprincipal.bLlenarClick(Sender: TObject);
var
    i: integer;
    n: ^integer;
begin
  for i := 1 to 10 do
        begin
        New(n);
        n^ := Random(100);
        ListaEnteros.Add(n);
        end;
end;

Funcionar funciona, mi duda es si lo hago bien, si libero bien toda la memoria y eso, si hay una forma más sencilla, etc.

Saludos

[Marc]

Bueno una simple matriz de enteros y un contador apuntando al último valor asignado también te servirían perfectamente. No hay necesidad de complicarse mucho para mantener una lista de enteros.

Saludos.

[jc]

Hola

Bueno una simple matriz de enteros y un contador apuntando al último valor asignado también te servirían perfectamente. No hay necesidad de complicarse mucho para mantener una lista de enteros.

El problema es que no hay forma de saber cuantos enteros habrá en la lista, depende de las acciones del usuario. La lista va a contener un índice de los registros borrados en un archivo de datos, para sobreescribirlos a la hora de guardar uno nuevo.

En principio cabe esperar que los registros borrados no sean muchos, y, como se van sobreescribiendo, es de esperar que la lista no crezca mucho, pero nada impide que crezca bastante y con un array siempre puedo quedarme corto o pasarme en exceso, por eso se me ocurrió hacer esa lista.

Saludos

[Marc]

Hola.

Hola

Bueno una simple matriz de enteros y un contador apuntando al último valor asignado también te servirían perfectamente. No hay necesidad de complicarse mucho para mantener una lista de enteros.

El problema es que no hay forma de saber cuantos enteros habrá en la lista, depende de las acciones del usuario. La lista va a contener un índice de los registros borrados en un archivo de datos, para sobreescribirlos a la hora de guardar uno nuevo.

En principio cabe esperar que los registros borrados no sean muchos, y, como se van sobreescribiendo, es de esperar que la lista no crezca mucho, pero nada impide que crezca bastante y con un array siempre puedo quedarme corto o pasarme en exceso, por eso se me ocurrió hacer esa lista.

Saludos

No es que me gusten mucho, pero también tienes las matrices dinámicas.

Se declaran : var M: array of integer;

Y después le puedes ir cambiando el tamaño con el procedimiento SetLength.

Ejplo (pondremos el tamaño de la matriz anterior a 50 enteros) : SetLength(M, 50);

Saludos.

[eduarcol]

y pregunto, no es mas facil un TStringList y hacer un cast??? 

delphi

MiEntero := StrtoInt(Milista.Strings[0]);

[jc]

Hola

y pregunto, no es mas facil un TStringList y hacer un cast??? 

delphi

MiEntero := StrtoInt(Milista.Strings[0]);

Ahora mismo lo tengo así 

Pensaba que estaría un poquito más ¿elegante?, ¿correcto? empleando enteros y ahorrándome la conversión.

Saludos

[cadetill]

Buenas,

Un día que tenía poco que hacer, hice una clase TIntegerList que básicamente se basaba en un TStringList haciendo un cast, pero que de cara al programador es totalmente transparente. Aquí te la dejo por si te interesa

delphi

interface
 
uses
  Classes, SysUtils;
 
type
  TIntegerList = class
  private
    List: TStringList;
    function GetCount: Integer;
  protected
    function Get(Index: Integer): integer; virtual;
    procedure Put(Index, Item: integer); virtual;
  public
    constructor Create; virtual;
    destructor Destroy; override;
 
    function Add(Item: integer): Integer;
    function IndexOf(Item: integer): Integer;
    function First: integer;
    function Last: integer;
    function Remove(Item: integer): Integer;
 
    procedure Clear; virtual;
    procedure Delete(Index: Integer);
    procedure Insert(Index, Item: integer);
    procedure Move(CurIndex, NewIndex: Integer);
 
    property Count: Integer read GetCount;
    property Items[Index: Integer]: integer read Get write Put; default;
  end;
 
implementation
 
{ TIntegerList }
 
constructor TIntegerList.Create;
begin
  List := TStringList.Create;
end;
 
destructor TIntegerList.Destroy;
begin
  if Assigned(List) then FreeAndNil(List);
 
  inherited;
end;
 
function TIntegerList.Add(Item: integer): Integer;
begin
  Result := -1;
  if Assigned(List) then Result := List.Add(IntToStr(Item));
end;
 
procedure TIntegerList.Clear;
begin
  List.Clear;
end;
 
procedure TIntegerList.Delete(Index: Integer);
begin
  List.Delete(Index);
end;
 
function TIntegerList.First: integer;
begin
  Result := -1;
  if Assigned(List) and (List.Count > 0) then Result := StrToInt(List[0])
end;
 
function TIntegerList.Get(Index: Integer): integer;
begin
  Result := StrToInt(List[Index]);
end;
 
function TIntegerList.IndexOf(Item: integer): Integer;
begin
  Result := -1;
  if Assigned(List) then Result := List.IndexOf(IntToStr(Item));
end;
 
procedure TIntegerList.Insert(Index, Item: integer);
begin
  List.Insert(Index, IntToStr(Item));
end;
 
function TIntegerList.Last: integer;
begin
  Result := -1;
  if Assigned(List) then Result := StrToInt(List[List.Count - 1]);
end;
 
procedure TIntegerList.Move(CurIndex, NewIndex: Integer);
begin
  List.Move(CurIndex, NewIndex);
end;
 
procedure TIntegerList.Put(Index, Item: integer);
begin
  List[Index] := IntToStr(Item);
end;
 
function TIntegerList.Remove(Item: integer): Integer;
begin
  Result := -1;
  if Assigned(List) then
  begin
    Result := Self.IndexOf(Item);
    if Result >= 0 then Self.Delete(Result);
  end;
end;
 
function TIntegerList.GetCount: Integer;
begin
  Result := List.Count;
end;
 
end.

Nos leemos

[jc]

Hola

.... Aquí te la dejo por si te interesa ...

Gracias por el aporte.

Tenía pensado precisamente hacer una clase para que manejara la lista de enteros, como ya hice todo el código que puse al principio para manejar la lista de enteros, ya la haré así. Aunque tomaré nota de como la hiciste tú.

Saludos