11 respuestas en este tema

[Delphius]

Hola,
Aquí dejo un pequeño truco que nos permite generar imágenes en escala de grises a 8 bits.

 

Revisión 22/08/16:

NOTA: Este truco tiene un error. Se ha asignado de manera errónea los valores de la paleta a la imagen resultante.

Para un código óptimo y probado se sugiere seguir este hilo. Lo que puede ser de utilidad aquí es la discusión de como proceder a calcular el valor de gris en base a dos modos:

Como bien sabemos, el esquema RGB trabaja con 24 bits, 1 byte para cada canal: Rojo, Verde y Azul. Y también conocemos que para lograr imágenes en escala de grises debemos recurrir a una "transformación" de color.

Básicamente hay dos ecuaciones que calculan el valor de gris para un valor RGB.

Basada en el brillo

Valor = 0.3 * Rojo + 0.59 * Verde + 0.11 * Azul

Basada en la Intensidad

Valor = 1/3 * (Rojo + Verde + Azul)

Cuando ya tenemos el color, que no es más que un valor en rango [0,255] debemos alterar el color de cada canal por este. Es decir:

Rojo = Valor
Verde = Valor
Azul = Valor

El defecto de esta técnica es que la imagen sigue siendo de formato a 24 bits y estamos desperdiciando 16 de ellos por cada pixel, ¡estamos guarda el mismo valor en cada canal!. Uno piensa que bastaría entonces con hacer algo como:
 

delphi

Bitmap.PixelFormat := pf8bit;
Bitmap.SaveToFile(...);

Pero no. No es tan simple, y NO... NO es una imagen de escala de gris. La imagen que hemos pintado si está en tonos de grises... y si vemos las propiedades de la imagen parece está todo en orden ¡leemos bit de profundidad: 8!
¿Porqué dices que no funciona?

Pues déjame contarte que en realidad eso es un camuflaje, intermente esa imagen de mapa de bits sigue utilizando una paleta de colores basada en el tradicional RGB. Una prueba bastará para demostrarlo.

Deje (o asigne) al bitmap el formato pf8bit.
Luego modifique algunos pixeles, para unas pruebas yo he asignado valores al azar:
 

delphi

  bmp := TBitmap.Create;
 
  //asignamos formato de bits y tamaño
  bmp.PixelFormat := pf8bit;
  bmp.Width := 92;
  bmp.Height := 112;
 
  // "pintamos"
  for j := 0 to bmp.Height - 1 do
    begin
      p := bmp.ScanLine[j];
      for i := 0 to bmp.Width - 1 do
        begin
          b := Random(256);
          p^[1] := b;
          Inc(p);
        end;
    end;
 
  bmp.SaveToFile('...');
  ie1.Picture.Bitmap := bmp;
 
  FreeAndNil(bmp);

Aquí una explicación de las variables:
bmp es de la clase TBitmap.
ie1 es un TImage, ubicado en el form.
i,j: son dos variables enteros.
b es de tipo byte.

La variable que quizá desconcierte a muchos es p:
 

delphi

p: P8BitsChannel;

Ese tipo especial no es más que un puntero:
 

delphi

type
 
T8bitsChannel = array[1..1] of Byte;
P8BitsChannel = ^T8BitsChannel;

Cuando asignamos un valor a PixelFormat lo más adecuado es trabajar con SanLine ya que está preparado para aceptar el formato establecido.

Si todo sale como lo planeado dicha imagen tiene la forma de estática de cuando perdemos señal en el TV a todo color. ¡Un momento... pero si es formato a 8 bits! ¿Cómo es posible ver esa colorida imagen?

Ya le avisé: todo está en la paleta de color por defecto que está utilizando el bitmap.

La solución: debemos crear una propia y asociar los niveles de grises. Para ello nos apoyaremos en un tipo especial tagLOGPALETTE.

Defina la paleta como un record:
 

delphi

type
  // Mi tipo de paleta de colores
  MiPaleta = record
  lpal: TLogPalette;
  // espacio de colores de grises de 8 bits
  EspacioColor: array[0..255] of TPaletteEntry;
  end;

Declare una variable:
 

delphi

pal: MiPaleta;

Ahora debemos "crearla" y llenarla:
 

delphi

// creamos la paleta!
  pal.lpal.palVersion := $300;  // ¡constante!
  pal.lpal.palNumEntries := 256; // 256 tonos de grises
  for i := 0 to 255 do
  begin
    with pal.lpal.palPalEntry[i] do
    begin
      peRed := i;
      peGreen := i;
      peBlue := i;
    end;
  end;

La explicación es simple. Se hace corresponder cada valor RGB con el tono de gris.

Sólo nos resta asociar la paleta al bitmap para que cada vez que el bitmap lea un valor RGB lo pinte como queremos:
 

delphi

bmp.Palette := CreatePalette(Pal.lpal);

A todo esto el código final resulta en un:
 

delphi

procedure TForm1.bn2Click(Sender: TObject);
type
  // Mi tipo de paleta de colores
  MiPaleta = record
  lpal: TLogPalette;
  // espacio de colores de grises de 8 bits
  EspacioColor: array[0..255] of TPaletteEntry;
  end;
 
var i,j: Integer;
    bmp: TBitmap;
    p: P8BitsChannel;
    //paleta de colores a 8 bits
    pal: MiPaleta;
 
    b: Byte;
begin
  // creamos la paleta!
  pal.lpal.palVersion := $300;  // ¡constante!
  pal.lpal.palNumEntries := 256; // 256 tonos de grises
  for i := 0 to 255 do
  begin
    with pal.lpal.palPalEntry[i] do
    begin
      peRed := i;
      peGreen := i;
      peBlue := i;
    end;
  end;
 
  bmp := TBitmap.Create;
 
  //asignamos formato de bits y tamaño
  bmp.PixelFormat := pf8bit;
  bmp.Width := 92;
  bmp.Height := 112;
 
  bmp.Palette := CreatePalette(Pal.lpal);
 
  // "pintamos"
  for j := 0 to bmp.Height - 1 do
    begin
      p := bmp.ScanLine[j];
      for i := 0 to bmp.Width - 1 do
        begin
          b := Random(256);
          p^[1] := b;
          Inc(p);
        end;
    end;
 
  bmp.SaveToFile('...');
  ie1.Picture.Bitmap := bmp;
 
  FreeAndNil(bmp);
end;

Ahora si tenemos una imagen a todas luces en formato 8bits y escala de grises. Lo lindo de esta técnica es que es muy rápida y tenemos bmps mucho más livianos. Muchas veces en el tratamiento de imagen se utilizan imágenes en escala de grises, nos podemos ahorrar mucho al trabajar con un único canal.

Esto también es válido para repintar una imagen de forma directa, cree la paleta como en el ejemplo y vinculada al bmp. Luego directamente pinte el original sobre el bitmap temporal. Por ejemplo suponga que la imagen original está en un TImage1:
 

delphi

bmp.Canvas.Draw(0,0,Image1.Picture.Graphic);

Espero que le sea de utilidad.

Saludos,

[egostar]

Muy interesante amigo Marcelo, gracias

Salud OS

[felipe]

Gracias por el aporte, se nota que lo estudiaste bastante



[off-topic]En estos casos es más rápido Photoshop [/off-topic]



Saludos!

[Wilson]

Gracias Delphius, buen aporte.

[Delphius]

Gracias a ustedes amigos.

Es que justo necesitaba explorar el tema de la conversión real a 8 bits y con escala (con delphi).

Lo bueno de asignar una paleta al bitmap es que podemos hacer conversiones directas, no hay que explorar pixels, etc. Con sólo hacer un Draw y la paleta apropiada podemos hacer muchas creaciones.

Prueben alterando el color de peRed, peGreen, y peBlue de otras formas y vean sus resultados. Por ejemplo esta:

delphi

peBlue := i;
peRed := Round((255 - i) * 0.1);
peGreen := Round((255 - i) * 0.2);

Eso debería llevar todo al azul (tendencia al oscuro) y negro 

Saludos,

[felipe]

Una de las cosas importantes de este truco es el manejo de recursos y bytes al hacer este cambio.


Saludos!

[sergiocapillera2013]

Marcelo, recien estoy familiarizandome con delphi y me encantaria llevar a cabo mi idea de proyecto este código lo coloco una vez que en el form una imagen??? , me salen errores como ; unit1.pas(31,5) Error: Illegal expression y  unit1.pas(31,15) Fatal: Syntax error, ";" expected but "identifier TFORM1" found

[Delphius]

Hola sergiocapillera2013,
¡Bienvenido a Delphiaccess! Espero que esta comunidad sea un segundo hogar para ti.

No es posible saber cual es el verdadero error que tienes, hace falta ver tu código para eso.
Te invito a que inicies un hilo propio para tratar tus dudas al respecto.
Este foro, Trucos y Consejos, es una sección en donde uno puede ir colocando aportes personales que considera útiles compartir en sus momentos de descubrimientos e investigaciones.

Como tu duda hacen a algo puntual, considero oportuno que se le dedique un hilo propio. En todo caso en tus post haz referencia a éste.

Saludos,

[ELKurgan]

Muchas gracias por el aporte, maestro

[poliburro]

Gracias por compartirnos este excelente truco. Un abrazo amigo

[sergiocapillera2013]

Marcelo tengo éste código y no me funciona quizas coloco las lineas mal ??? en form1 coloco una imagen junto a un boton y deberia pasarla escala gris y no pasa nada , podr{ias darme una orientación , lo que quiero lograr es hacer el promedio RGB y pasarla a escala de gris ,acordate que estoy empezando podrías orientarme paso a paso?? saludos.
begin
BMP1 := TBitmap.Create;
  BMP1.LoadFromFile('/home/mariposa.bmp'); //Imagen de 8 bits
  BMP2 := TBitmap.Create;
  BMP2.PixelFormat := pf1bit;
  BMP2.Height := BMP1.Height;
  BMP2.Width := BMP1.Width;
  for X := 0 to BMP1.Width - 1 do
    for Y := 0 to BMP1.Height - 1 do
      BMP2.Canvas.Pixels[X, Y] := BMP1.Canvas.Pixels[X, Y];
  BMP1.Free;

end;                     

supuestamente explora toda la imagen esta en formato BMP en  home y no pasa nada podrás probar éste codigo si realmente funciona, saludos, espero tu respuesta a la brevedad.

[Delphius]

Cito y repito:

Como tu duda hacen a algo puntual, considero oportuno que se le dedique un hilo propio. En todo caso en tus post haz referencia a éste.

Por favor inicia un hilo propio para tratar tus dudas puntuales y explica detalladamente el problema. Partamos de tres cosas:
1. ¿Te aseguraste de que efectivamente la imagen leída sea de escala de grises a 8bits? Porque esto me lleva al punto 2.
2. En tu código se aprecia que asignas el valor pf1bit.
3. Si resulta ser que el BMP2 muestra una imagen a todo color es resultado a como he expresado en este "truco" que el problema está en la paleta de colores por defecto que emplea la clase TBitmap.

No voy a responder tus dudas aquí. Incisto en que abras tu propio hilo en el foro apropiado. Respeta las normas y sugerencias, porque tal parece que no has tenido en cuenta mis palabras anteriores.

Saludos,