21 replies to this topic

[egostar]

Pues eso


¿ Es posible hacer que curl se conecte a un sFTP y transferir  archivos ?


Salud OS

[seoane]

Pues parece que si:

Get a file from an SSH server using SFTP:

        curl -u username sftp://shell.example.com/etc/issue

Pero para tener algo de código necesito mas tiempo    y un servidor sftp para probar

[egostar]

Te servirá este ?

http://www.secureftp-test.com/

Salud OS

[seoane]

Partiendo de los ejemplos anterirores sobre libcurl, podemos hacer algo como esto:

delphi

function SaveToStream(Buffer: PAnsiChar; Size, Count: Integer;
  Stream: TStream): Integer; cdecl;
begin
  Result:= Stream.Write(Buffer^,Size*Count) div Size;
end;
 
function Bajar(Usuario, Clave, URL: AnsiString): Boolean;
var
  Curl: TCURL;
  Stream: TMemoryStream;
begin
  Result:= FALSE;
  Curl:= curl_easy_init;
  if Curl <> nil then
  try
    if curl_easy_setopt(Curl, CURLOPT_VERBOSE, TRUE) <> CURLE_OK then
      Exit;
    if curl_easy_setopt(Curl, CURLOPT_USE_SSL, CURLUSESSL_ALL) <> CURLE_OK then
      Exit;
    // No verificamos la identidad del servidor, suponemos que es quien dice ser
    if curl_easy_setopt(Curl, CURLOPT_SSL_VERIFYPEER, FALSE) <> CURLE_OK then
      Exit;
    if curl_easy_setopt(Curl, CURLOPT_USERNAME, PAnsiChar(Usuario)) <> CURLE_OK then
      Exit;
    if curl_easy_setopt(Curl, CURLOPT_PASSWORD, PAnsiChar(Clave)) <> CURLE_OK then
      Exit;
    if curl_easy_setopt(Curl, CURLOPT_URL, PChar(URL)) <> CURLE_OK then
      Exit;
    if curl_easy_setopt(Curl, CURLOPT_WRITEFUNCTION, @SaveToStream) <> CURLE_OK then
      Exit;
    Stream:= TMemoryStream.Create;
    try
      if curl_easy_setopt(Curl, CURLOPT_FILE, Stream) <> CURLE_OK then
        Exit;
      Result:= curl_easy_perform(Curl) = CURLE_OK;
      // Con los datos del stream podemos hacer cualquier cosa
      Stream.SaveToFile('C:\1.txt');
    finally
      Stream.Free;
    end;
  finally
    curl_easy_cleanup(Curl);
  end;
end;
 
Bajar('test','test','ftps : / / ftp. secureftp-test. com :990 / pigs. xml');

¿Nos estamos acercando a lo que buscas egostar?

[seoane]

En el ejemplo anterior quitar los espacios en blanco de la url.

[egostar]

A probar, aunque no entiendo mucho el codigo, eso es para bajar archivo, pero para subir que función se utiliza

Salud OS

[egostar]

Probado y se conecta perfectamente, descarga el archivo sin problema, ahora, con que función se sube archivos al sFTP ? he visto en otros procesos esto


if curl_easy_setopt(Curl, CURLOPT_UPLOAD, TRUE) <> CURLE_OK then

Será con eso ?

Muchas gracias amigo Domingo

Salud OS

[seoane]

Ya te estoy preparando un ejemplo de como subir un archivo.

De todas formas fíjate que el ftp de prueba que me pasaste es ftps y no sftp, que aunque se parecen no son lo mismo, son protocolos diferentes y si no lo tienes en cuenta puedes perder un monton de tiempo como me paso a mi por la mañana

Para probar un sftp me he bajado un programita de internet que actúa como servidor sftp.
http://portableapps.com/node/19958

[egostar]

Ya te estoy preparando un ejemplo de como subir un archivo.

De todas formas fíjate que el ftp de prueba que me pasaste es ftps y no sftp, que aunque se parecen no son lo mismo, son protocolos diferentes y si no lo tienes en cuenta puedes perder un monton de tiempo como me paso a mi por la mañana

Para probar un sftp me he bajado un programita de internet que actúa como servidor sftp.
http://portableapps.com/node/19958

Ah vaya, en este caso la propiedad conmutativa si altera el producto sFTP <> FTPs

Salud OS

[seoane]

Aqui el ejemplo:

delphi

function ReadFromStream(Buffer: PAnsiChar; Size, Count: Integer;
  Stream: TStream): Integer; cdecl;
begin
  Result:= Stream.Read(Buffer^,Size*Count) div Size;
end;
 
function SaveToStream(Buffer: PAnsiChar; Size, Count: Integer;
  Stream: TStream): Integer; cdecl;
begin
  Result:= Stream.Write(Buffer^,Size*Count) div Size;
end;
 
function Subir(Usuario, Clave, URL, Archivo: AnsiString): Boolean;
var
  Curl: TCURL;
  Stream: TFileStream;
begin
  Result:= FALSE;
  Curl:= curl_easy_init;
  if Curl <> nil then
  try
    // Indicamos que muestre mensajes de todo lo que va haciendo
    if curl_easy_setopt(Curl, CURLOPT_VERBOSE, TRUE) <> CURLE_OK then
      Exit;
    // Le decimos que uses SSL
    if curl_easy_setopt(Curl, CURLOPT_USE_SSL, CURLUSESSL_ALL) <> CURLE_OK then
      Exit;
    // No verificamos la identidad del servidor, suponemos que es quien dice ser.
    if curl_easy_setopt(Curl, CURLOPT_SSL_VERIFYPEER, FALSE) <> CURLE_OK then
      Exit;
    // Indicamos el usuario
    if curl_easy_setopt(Curl, CURLOPT_USERNAME, PAnsiChar(Usuario)) <> CURLE_OK then
      Exit;
    // El password
    if curl_easy_setopt(Curl, CURLOPT_PASSWORD, PAnsiChar(Clave)) <> CURLE_OK then
      Exit;
    // La URL del tipo: sftp://servidor/rutadelfichero
    if curl_easy_setopt(Curl, CURLOPT_URL, PAnsiChar(URL)) <> CURLE_OK then
      Exit;
    // Le indicamos que funcion debe usar para leer el stream
    if curl_easy_setopt(Curl, CURLOPT_READFUNCTION, @ReadFromStream) <> CURLE_OK then
      Exit;
    // Creamos un stream a partir de un archivo
    Stream:= TFileStream.Create(Archivo,fmOpenRead);
    try
      // Aqui le indicamos el stream que debe subir
      if curl_easy_setopt(Curl, CURLOPT_INFILE, Stream) <> CURLE_OK then
        Exit;
      // Aqui le indicamos que la operacion es de subida
      if curl_easy_setopt(Curl, CURLOPT_UPLOAD, TRUE) <> CURLE_OK then
        Exit;
      // Ejecutamos el comando
      Result:= curl_easy_perform(Curl) = CURLE_OK;
    finally
      Stream.Free;
    end;
  finally
    curl_easy_cleanup(Curl);
  end;
end;
 
// Sube el archivo "C;\ART.DAT" al servidor con el nombre "2.txt"
  Subir('test','test','sftp://169.254.0.2:999/2.txt','C:\ART.DAT');

Como veras el ejemplo es muy sencillo y va comentado.


Por otro lado el que se utilice un protocolo u otro solo varia en que el url debe empezar por sftp o por ftps y curl ya se encarga del resto.

[egostar]

Wow!!!

Eres genial amigo Domingo , ya te comento como me fué con las pruebas

salud OS

[egostar]

¡Caramba! Me quito el sombrero amigo, funcionó como los mismísimos ángeles. Ya no sé cuantas te debo

Salud OS

[Wilson]

Gracias Domingo, a mi también me viene de perlas ese code. 

[DIEGO.CHAVEZ]

hola ayer instale unos componentes de delphi para curl,  y estoy tratando de reproducir el codigo para subir archivos a un servidor SFTp pero me marca
"Undeclared identifier: CURLOPT_USE_SSL ", buscando encontre que eso se definia en el cul_h.pas creo que la version que estoy utilizando no soporta SFTP entonces como puedo actualizar mi version o que me podrian sugerir para solucionar esto,  utilizo el wrapper de curl "curlpas" o ustedes como le hicieron para lograr subir archivos a servidor SFTP.

[Ana]

Buenos días,

he conseguido subir ficheros a una sftp, pero ahora me surge la necesidad de bajar todos los ficheros de un directorio de una sftp. He visto el código de bajar, pero es para un único fichero, ¿como puedo descargar todos los ficheros del directorio?

 

Gracias.

[egostar]

Buenos días,
he conseguido subir ficheros a una sftp, pero ahora me surge la necesidad de bajar todos los ficheros de un directorio de una sftp. He visto el código de bajar, pero es para un único fichero, ¿como puedo descargar todos los ficheros del directorio?
 
Gracias.

 
Hola Ana, bienvenida a DelphiAccess
 
Si cambias pigs.xml por *.* servirá

 

Saludos

[Ana]

 
Hola Ana, bienvenida a DelphiAccess
 
Si cambias pigs.xml por *.* servirá

 

Saludos

 

Hola 

ya lo he cambiado y me devuelve el siguiente error "CURLE_REMOTE_FILE_NOT_FOUND"

[seoane]

Buenas tardes,

 

Ahora mismo no tengo instalado Delphi asi que no puedo probarlo, pero si no recuerdo mal si pones como la ruta la del directorio se descarga un fichero tal que asi:

 

Bajar('demo','password','sftp : //test. rebex. net: 22/');

php

drwx------ 2 demo users          0 Jul 26  2017 .
drwx------ 2 demo users          0 Jul 26  2017 ..
drwx------ 2 demo users          0 Dec 03  2015 aspnet_client
drwx------ 2 demo users          0 Oct 27  2015 pub
-rw------- 1 demo users        403 Apr 08  2014 readme.txt

Puedes "parsear" ese fichero linea a linea para saber que ficheros tienes que bajar, y luego bajar uno a uno.

 

Saludos

 

PD: Me tengo que instalar delphi en una maquina virtual, muchas veces me quedo con ganas de responder en el foro por no disponer de un Delphi a mano

[seoane]

Buenas otra vez. Al final he instalado Delphi y lo he probado.

 

Parece ser que hay que añadir una opcion mas:

php

if curl_easy_setopt(Curl, CURLOPT_DIRLISTONLY, TRUE) <> CURLE_OK then
      Exit;

Y asi el listado que se descarga ya solo tiene los nombres de los fichero, lo que es mas fácil de procesar

php

.
..
aspnet_client
pub
readme.txt

[Ana]

Buenas otra vez. Al final he instalado Delphi y lo he probado.
 
Parece ser que hay que añadir una opcion mas:

delphi

if curl_easy_setopt(Curl, CURLOPT_DIRLISTONLY, TRUE) <> CURLE_OK then
      Exit;

Y asi el listado que se descarga ya solo tiene los nombres de los fichero, lo que es mas fácil de procesar

delphi

.
..
aspnet_client
pub
readme.txt

 
Hola 
he probado, pero alguna cosa me falta, mejor dicho, no sé como obtener la lista, el codigo que tengo es el siguiente
 
 

delphi

function DameFichero_SFTP(servidor,Usuario, Clave, ruta: AnsiString): integer;
 
var
 
  Curl: TCURL;
 
  Stream: TMemoryStream;
 
  respuesta:curlcode;
 
begin
  servidor:='sftp://'+servidor+'/'+ruta+'/';
  Curl:= curl_easy_init;
  if Curl <> nil then
  try
    if curl_easy_setopt(Curl, CURLOPT_VERBOSE, TRUE) <> CURLE_OK then
      Exit;
    if curl_easy_setopt(Curl, CURLOPT_USE_SSL, CURLUSESSL_ALL) <> CURLE_OK then
      Exit;
    // No verificamos la identidad del servidor, suponemos que es quien dice ser
    if curl_easy_setopt(Curl, CURLOPT_SSL_VERIFYPEER, FALSE) <> CURLE_OK then
      Exit;
    if curl_easy_setopt(Curl, CURLOPT_USERNAME, PAnsiChar(Usuario)) <> CURLE_OK then
      Exit;
    if curl_easy_setopt(Curl, CURLOPT_PASSWORD, PAnsiChar(Clave)) <> CURLE_OK then
      Exit;
    if curl_easy_setopt(Curl, CURLOPT_URL, PChar(servidor)) <> CURLE_OK then
      Exit;
 
 
    if curl_easy_setopt(Curl, CURLOPT_DIRLISTONLY, true) <> CURLE_OK then
      Exit;
 
 
    try
       respuesta:=curl_easy_perform(Curl);
    finally
    end;
  finally
    curl_easy_cleanup(Curl);
  end;
end;

 
ruta es la carpeta de la ftp que tengo que leer, la respuesta que me devuelve es curle_ok, pero ahora no sé como leer o guarda la lista , porque si pongo lo siguiente
 

 if curl_easy_setopt(Curl, CURLOPT_WRITEFUNCTION, @SaveToStream) <> CURLE_OK then
        Exit;
 
para guardar el listado en un stream me da un acces violation.