6 replies to this topic

[escafandra]

A raíz de una pregunta realizada en este sentido en CD recordé un artículo que trataba de estos temas. El rendimiento grafico de los ejemplos que propone el autor no me convence, aunque los efectos son muy vistosos. Así me animé a realizar un ejemplo sencillo en delphi.

Se trata de realizar una semitransparencia en la barra de título y borde de un formulario, manteniendo opaco su contenido.

El truco comienza diseñando nuestro formulario como semitransparente con la propiedad  AlphaBlend y su valor. Luego Creamos en tiempo de  ejecución un segundo Form, sin borde, sin Caption y opaco, que colocamos enzima, ocupando  todo el área cliente. Posteriormente cambiamos el Parent de todos los  controles a este nuevo Form. Para que esto funcione debemos reescribir  parte de la función de tratamiento de mensajes del Form original.

El código que realiza el efecto:

delphi

procedure TForm1.WndProc(var Message: TMessage);
begin
  case Message.Msg of
  WM_SYSCOMMAND:
    case Message.WParam of
    SC_MAXIMIZE, SC_MINIMIZE, SC_RESTORE:
      SetWindowPos(FForm.Handle, 0, Left + GetSystemMetrics(SM_CXFRAME),
                   Top + GetSystemMetrics(SM_CYCAPTION) + GetSystemMetrics(SM_CYFRAME),
                   Width - 2*GetSystemMetrics(SM_CXFRAME),
                   Height - GetSystemMetrics(SM_CYCAPTION) - 2*GetSystemMetrics(SM_CYFRAME), 0);
    end;
  WM_CLOSE:
    FForm.Close;
  WM_MOVING:
    SetWindowPos(FForm.Handle, 0, PRECT(Message.lParam).left + GetSystemMetrics(SM_CXFRAME),
                 PRECT(Message.lParam).top + GetSystemMetrics(SM_CYCAPTION) + GetSystemMetrics(SM_CYFRAME), 0, 0, SWP_NOSIZE);
  WM_SIZING:
    SetWindowPos(FForm.Handle, 0, PRECT(Message.lParam).left + GetSystemMetrics(SM_CXFRAME),
                 PRECT(Message.lParam).top + GetSystemMetrics(SM_CYCAPTION) + GetSystemMetrics(SM_CYFRAME),
                 PRECT(Message.lParam).Right - PRECT(Message.lParam).Left - 2*GetSystemMetrics(SM_CXFRAME),
                 PRECT(Message.lParam).Bottom - PRECT(Message.lParam).Top - GetSystemMetrics(SM_CYCAPTION) - 2*GetSystemMetrics(SM_CYFRAME), 0);
  WM_SIZE:
    if FForm <> nil then
       SetWindowPos(FForm.Handle, 0, Left + GetSystemMetrics(SM_CXFRAME),
                    Top + GetSystemMetrics(SM_CYCAPTION) + GetSystemMetrics(SM_CYFRAME),
                    Width - 2*GetSystemMetrics(SM_CXFRAME),
                    Height - GetSystemMetrics(SM_CYCAPTION) - 2*GetSystemMetrics(SM_CYFRAME), 0);
  WM_SETFOCUS:
    PostMessage(FForm.Handle, WM_SETFOCUS, 0, 0);
  end;
  inherited WndProc(Message);
end;
 
procedure TForm1.FormCreate(Sender: TObject);
begin
  FForm:= TForm.Create(self);
  FForm.Left:= Left + GetSystemMetrics(SM_CXFRAME);
  FForm.Top:= Top + GetSystemMetrics(SM_CYCAPTION) + GetSystemMetrics(SM_CYFRAME);
  FForm.Width:= Width - 2 * GetSystemMetrics(SM_CXFRAME);
  FForm.Height:= Height - GetSystemMetrics(SM_CYCAPTION) - 2*GetSystemMetrics(SM_CYFRAME);
  FForm.BorderStyle:= bsNone;
  FForm.Show;
 
  while ControlCount > 0 do
    Controls[0].Parent:= FForm;
 
end;

 
Subo los archivos de ejemplo.

Espero que sea de utilidad y base para desarrollos mas complejos.


Saludos.

[enecumene]

Excelente maestro!!!

[egostar]

Muy bueno, primera vez que veo la función GetSystemMetrics

Eso me recuerda que debo estudiar más

SaludOS

[egostar]

Caray, ya he ejecutado tu ejemplo, que buen "truco" de empalmar otro form encima y que no se note .

SaludOS

[escafandra]

Caray, ya he ejecutado tu ejemplo, que buen "truco" de empalmar otro form encima y que no se note .

SaludOS

Bueno, cuando el S.O. no te permite ciertas cosas de forma directa, pues...

Haces trampas. 



Saludos.

[egostar]

Caray, ya he ejecutado tu ejemplo, que buen "truco" de empalmar otro form encima y que no se note .

SaludOS

Bueno, cuando el S.O. no te permite ciertas cosas de forma directa, pues...

Haces trampas.   

Saludos.

Lo malo es que esas "trampas" no se me ocurren a mi jajajajajaja y aunque se me ocurrieran, no sabría como implementarlas. Honor a quien honor merece mi estimado escafandra.

SaludOS

[wilox]

Sin comentarios, hasta ahora lo probe y maravilloso