2 respuestas en este tema

[egostar]

Hola

Estoy desarrollando un programa para subir archivos a un ftp y esperar por la respuesta (en otro archivo), descargarlo y borrarlo.

Ya tengo 2/3 partes es decir, subir y bajar archivos, ¿Alguien sabe (seaone ) cual es la función que se utiliza para indicarle que borre el archivo descargado ?

Saludos

[seoane]

Un ejemplo rapidito que aquí son la 01:20 AM 
El truco esta en ejecutar comandos en el servidor ftp. En el caso de un servidor sftp los comandos permitidos son (chgrp, chmod, chown, ln, mkdir, pwd, rename, rm, rmdir, symlink ) y en para el ftp normal los tienes aqui http://www.ietf.org/rfc/rfc959.txt
Vamos a suponer que el servidor es sftp, asi que vamos a usar el comando rm (borrar)
Partiendo de los ejemplos anteriores

delphi

// Esto sirve para ignorar la respuesta del servidor
function Ignorar(Buffer: PAnsiChar; Size, Count: Integer;
  Stream: TStream): Integer; cdecl;
begin
  Result:= Count;
end;
 
function Borrar(Usuario, Clave, Servidor, Archivo: AnsiString): Boolean;
var
  Curl: TCURL;
  Comandos: pcurl_slist;
begin
  Result:= FALSE;
  Curl:= curl_easy_init;
  if Curl <> nil then
  try
    if curl_easy_setopt(Curl, CURLOPT_VERBOSE, TRUE) <> CURLE_OK then
      Exit;
    if curl_easy_setopt(Curl, CURLOPT_USE_SSL, CURLUSESSL_ALL) <> CURLE_OK then
      Exit;
    // No verificamos la identidad del servidor, suponemos que es quien dice ser
    if curl_easy_setopt(Curl, CURLOPT_SSL_VERIFYPEER, FALSE) <> CURLE_OK then
      Exit;
    if curl_easy_setopt(Curl, CURLOPT_USERNAME, PAnsiChar(Usuario)) <> CURLE_OK then
      Exit;
    if curl_easy_setopt(Curl, CURLOPT_PASSWORD, PAnsiChar(Clave)) <> CURLE_OK then
      Exit;
    if curl_easy_setopt(Curl, CURLOPT_URL, PChar(Servidor)) <> CURLE_OK then
      Exit;
    if curl_easy_setopt(Curl, CURLOPT_WRITEFUNCTION, @Ignorar) <> CURLE_OK then
      Exit;
    if curl_easy_setopt(Curl, CURLOPT_FILE, nil) <> CURLE_OK then
      Exit;
    Comandos:= nil;
    Comandos:= curl_slist_append(Comandos,PAnsiChar('rm ' + Archivo));
    try
      if curl_easy_setopt(Curl, CURLOPT_QUOTE, Comandos) <> CURLE_OK then
        Exit;
      Result:= curl_easy_perform(Curl) = CURLE_OK;
    finally
      curl_slist_free_all(Comandos);
    end;
  finally
    curl_easy_cleanup(Curl);
  end;
end;
 
 
  Borrar('usuario','password','sftp://127.0.0.1/','/test/test/test.txt');

Fíjate que la dirección del servidor termina en "/" y que la ruta del archivo es absoluta, es decir desde el directorio raíz.
Puedes ejecutar mas de un comando utilizando varias veces la función  curl_slist_append 
Creo que eso es todo mañana vemos si te funciono

[egostar]

Ya lo pruebo amigo, muchas gracias, mas tarde publico los resultados

Salud OS