15 respuestas en este tema

[enecumene]

Tengo el siguiente procedimiento:

delphi

procedure ShowCatalog(Forma: TForm; TreeItem: TTreeview; Page: TPageControl; TreeIndex,PageIndex: Integer);
begin
  Forma := TForm(Forma).Create(Application);
    try
      TreeItem.Items[TreeIndex].Selected := True;
      Page.ActivePageIndex := PageIndex;
      Forma.ShowModal;
    finally
      Forma.Free;
    end;
end;

Pero al ejecutar me manda una ejecucion, y es cuando intento crear el formulario, su uso es el siguiente, suponiendo que tengo un formlario llamado FCatalogo:

delphi

ShowCatalog(FCatalogo, FCatalogo.Treeview1,FCatalogo.PageControl1,2,2);

Saludos.

[cadetill]

Buenas,

Creo que lo que deberías de pasar por parámetro no es el formulario, sino la clase de éste. Algo así:

delphi

procedure ShowCatalog(FormClass: TFormClass; TreeItem: TTreeview; Page: TPageControl; TreeIndex,PageIndex: Integer);
var
  Forma: TForm;
begin
  Forma := FormClass.Create(Application);
    try
      TreeItem.Items[TreeIndex].Selected := True;
      Page.ActivePageIndex := PageIndex;
      Forma.ShowModal;
    finally
      Forma.Free;
    end;
end;

A parte de eso, estas pasando por parámetro un TTreeview y un TPageControl que aun no han sido creados dado que pertenecen a un formulario aun no creado, por lo que estás pasando un nil.

No lo he probado, pero la idea debería de ser esa ;-)

Nos leemos

[Delphius]

Hola Fernando,
¿Cuál es el error que te aparece?


Si la idea es comprobar antes si existe debes disponer de las variables para cada uno, o bien recorrer la propiedad Forms[] para determinar si existe la ventana abierta gracias a Assigned y en caso negativo recién crear.
Otro motivo de posibles problemas está en el hecho de que si defines un dueño al momento de crear un form no deberías liberarlo. Precisamente esa es la idea del dueño.


Si tu quieres liberar los forms una ves presentados recomiendo que no le asignes dueño:

delphi

Forma := TForma.Create(nil);

Y aquí aprovecho para hacer un paréntesis. Si bien es legal hacer:

delphi

Forma := TForm(Forma).Create();

Y aparentemente funciona, recuerda que estás haciendo un cast hacia una clase base. Por defecto cuando creamos un form, Delphi genera una nueva clase por cada uno: Form1 -> TForm1, Form2 -> TForm2, etc... Debería ser la propia de la propia clase y tipo al momento de crear.


Puedes hacer uso de las referencias de clases:

delphi

type
TFormClass = class of TForm;
 
 
var
  miFormClass: TFormClass;
  form: TForm;
 
 
begin
  miFormClass := TFormClass(Forma);
  Forma := miFormClass.Create(nil);  // O Application si es el caso
end;

De este modo te garantizas de que se haga uso del constructor y tipo adecuado y como extra no hay moldeo.


Saludos,

[enecumene]

Hola a ambos y gracias por su respuestas, aplicando sus consejos no me funcionaron, pero, me parece que los tiros vienen como dice Cadetill, estoy llamando a componentes que aun no existen aunque esten ahi, dejame como re-estructuro ese codigo.


Saludos.

[enecumene]

Bueno, yo aqui me ando complicando mas de la cuenta

delphi

procedure ShowCatalog(Forma: TForm; TreeName,PageName: String; TreeIndex,PageIndex: Integer);
var idx: Integer;
begin
  Forma := TForm(Forma).Create(Application);
    try
      for idx := 0 to Forma.ComponentCount - 1 do begin
        if (Forma.Components[idx] is TTreeView) And
           (Forma.Components[idx].Name = TreeName) then
              TTreeView(Forma.Components[idx]).Items[TreeIndex].Selected := True
        else if (Forma.Components[idx] is TPageControl) And
                (Forma.Components[idx].Name = PageName)  then
              TPageControl(Forma.Components[idx]).ActivePageIndex := PageIndex;
      end;
      Forma.ShowModal;
    finally
      Forma.Free;
    end;
end;

Resultado:

delphi

---------------------------
Cobros
---------------------------
Access violation at address 005874E9 in module 'Cobros.exe'. Read of address 00000000.
---------------------------
Aceptar   
---------------------------

[cadetill]

Buenas,

El AV te lo da en esta linea, verdad?

delphi

Forma := TForm(Forma).Create(Application);

Es debido a lo mismo de antes, Forma no es una clase, es un objeto y que aun no está creado, por lo que no puedes realizar el casting

Prueba como te he dicho antes

delphi

procedure ShowCatalog(FormClass: TFormClass; TreeName,PageName: String; TreeIndex,PageIndex: Integer);
var
  Forma: TForm;
  idx: Integer;
begin
  Forma := FormClass.Create(Application);
  try
    for idx := 0 to Forma.ComponentCount - 1 do begin
      if (Forma.Components[idx] is TTreeView) And
         (Forma.Components[idx].Name = TreeName) then
        TTreeView(Forma.Components[idx]).Items[TreeIndex].Selected := True
      else if (Forma.Components[idx] is TPageControl) And
                (Forma.Components[idx].Name = PageName)  then
              TPageControl(Forma.Components[idx]).ActivePageIndex := PageIndex;
    end;
    Forma.ShowModal;
  finally
    FreeAndNil(Forma);
  end;
end;

Ejemplo de llamada..

delphi

ShowCatalog(TCatalogo, '', '', 0, 0);

Nos leemos

[enecumene]

delphi

[DCC Error] Funciones.pas(188): E2010 Incompatible types: 'TFormClass' and 'TForm'

[andres1569]

Hola,

como ha dicho Cadetill al principio, debes crear el formulario a partir de una clase, en tu caso de la clase del formulario que sirve de patrón o maestro. Esta clase la puedes tomar directamente del mismo formulario que pasas como parámetro, así que con la misma declaración que pusiste al principio del hilo serviría, cambiando la sentencia donde creas el formulario "clonado".

Pero veo también ahí un error en que pasas un parámetro, Forma, que utilizas luego para que apunte al nuevo formulario creado, y deberían ser dos diferentes: el parámetro Forma apuntando al formulario que sirve de patrón, y dentro de la función NewForma que debe apuntar al nuevo formulario que vamos a crear:

delphi

procedure ShowCatalog(Forma: TForm; TreeName,PageName: String; TreeIndex,PageIndex: Integer);
var 
  NewForma : TForm;  
  idx: Integer;
begin
  NewForma := TFormClass(Forma.ClassType).Create(Application);
  try
    for idx := 0 to NewForma.ComponentCount - 1 do begin
      if (NewForma.Components[idx] is TTreeView) And
         (NewForma.Components[idx].Name = TreeName) then
            TTreeView(NewForma.Components[idx]).Items[TreeIndex].Selected := True
      else if (NewForma.Components[idx] is TPageControl) And
              (NewForma.Components[idx].Name = PageName)  then
            TPageControl(NewForma.Components[idx]).ActivePageIndex := PageIndex;
    end;
    NewForma.ShowModal;
  finally
    NewForma.Free;
  end;
end;

[Wilson]

Yo cambiaría un poco el diseño a algo mas flexible, algo así:

delphi

unit UBase;
 
 
interface
 
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ComCtrls;
 
 
type
  TBase = class(TForm)
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure FormShow(Sender: TObject);
  protected
    FTreeView: String;
    FPageControl: string;
    FTreeIndex: Integer;
    FPageIndex: Integer;
  public
    class function Ejecutar(TreeName, PageName: String;
      TreeIndex, PageIndex: Integer; AOwner: TComponent = nil): TModalResult;
  end;
 
 
implementation
 
 
{$R *.dfm}
{ TBase }
 
 
class function TBase.Ejecutar(TreeName, PageName: String;
  TreeIndex, PageIndex: Integer; AOwner: TComponent): TModalResult;
 
 
begin
  if AOwner = nil then
    AOwner := Application.MainForm;
  with Create(AOwner) do
    try
      FTreeView := TreeName;
      FPageControl := PageName;
      FTreeIndex := TreeIndex;
      FPageIndex := PageIndex;
      Result := ShowModal;
    finally
      Free;
    end;
end;
 
 
procedure TBase.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  Action := caFree;
end;
 
 
procedure TBase.FormShow(Sender: TObject);
var
  idx: Integer;
begin
  for idx := 0 to Self.ComponentCount - 1 do
  begin
    if (Self.Components[idx] is TTreeView) And
      (Self.Components[idx].Name = FTreeView) then
      TTreeView(Self.Components[idx]).Items[FTreeIndex].Selected := True
    else if (Self.Components[idx] is TPageControl) And
      (Self.Components[idx].Name = FPageControl) then
      TPageControl(Self.Components[idx]).ActivePageIndex := FPageIndex;
  end;
end;
 
 
end.

Y llamaría a los forms heredados de TBase así:

delphi

procedure TForm1.Button1Click(Sender: TObject);
begin
  TDescendiente.Ejecutar('Tu tree view', 'Tu PageName', 'tu treeIndex', 'Tu pageIndex');
end;
 
 
//o así
 
 
procedure TForm1.Button2Click(Sender: TObject);
begin
  if TDescendiente.Ejecutar('Tu tree view', 'Tu PageName', 'tu treeIndex',
    'Tu pageIndex') = mrOk then
    // Hacer cosas
  else
    // Hacer otras cosas
  end;
 
 
end.

Saludos.

[enecumene]

@andres:

delphi

---------------------------
Debugger Exception Notification
---------------------------
Project Cobros.exe raised exception class EAccessViolation with message 'Access violation at address 00403E78 in module 'Cobros.exe'. Read of address 00000000'.
---------------------------
Break   Continue   Help   
---------------------------

[cadetill]

Pon el código que te da esa excepción, porque (al menos el que yo puse) lo probé antes de ponerlo y me funcionaba correctamente

Nos leemos

[enecumene]

Pon el código que te da esa excepción, porque (al menos el que yo puse) lo probé antes de ponerlo y me funcionaba correctamente

Nos leemos

Pues es tal como lo coloca Andres:

delphi

//Procedimiento que maneja el formulario de Catalogo
//Asi me evito demasiadas lineas en cada menu
procedure ShowCatalog(Forma: TForm; TreeName,PageName: String; TreeIndex,PageIndex: Integer);
var
  NewForm: TForm;
  idx: Integer;
begin
  NewForm := TFormClass(Forma.ClassType).Create(Application);
    try
      for idx := 0 to NewForm.ComponentCount - 1 do begin
        if (NewForm.Components[idx] is TTreeView) And
           (NewForm.Components[idx].Name = TreeName) then
              TTreeView(NewForm.Components[idx]).Items[TreeIndex].Selected := True
        else if (NewForm.Components[idx] is TPageControl) And
                (NewForm.Components[idx].Name = PageName)  then
              TPageControl(NewForm.Components[idx]).ActivePageIndex := PageIndex;
      end;
      NewForm.ShowModal;
    finally
      NewForm.Free;
    end;
end;

El objetivo de ese codigo, es para ahorrarme la cantidad de lineas en mi proyecto, imaginense colocar este codigo en 10 menus diferentes:

delphi

procedure TFMain.UsuariosdelSistema1Click(Sender: TObject);
begin
  FCatalogo := TFCatalogo.Create(Self);
    try
      FCatalogo.lbCatInfo.Caption := 'Usuarios del Sistema';    
      FCatalogo.trCatMenu.Items[3].Selected := True;
      UnTab(FCatalogo.pcCatalogo,3);
      FCatalogo.ShowModal;
    finally
      FCatalogo.Free;
    end;
end;

asi que ando buscando casi un 90% de ahorro en lineas

[cadetill]

Buenas,

Sigo diciendo lo mismo, el obejto Forma no está creado, por lo que no puedes acceder a su propiedad ClassType, de ahí que te salte el AV.

Prueba a hacerlo de la forma que te indiqué más arriba.

Además, puedes evitar el bucle haciendo algo así que creo queda más "limpio"

delphi

procedure ShowCatalog(FormClass: TFormClass; TreeName,PageName: String; TreeIndex,PageIndex: Integer);
var
  Forma: TForm;
  Comp: TComponent;
begin
  Forma := FormClass.Create(Application);
  try
    Comp := Forma.FindComponent(TreeName);
    if Comp is TTreeView then
      TTreeView(Comp).Items[TreeIndex].Selected := True;
    Comp := Forma.FindComponent(PageName);
    if Comp is TPageControl then
      TPageControl(Comp).ActivePageIndex := PageIndex;
    Forma.ShowModal;
  finally
    FreeAndNil(Forma);
  end;
end;
 
procedure TForm1.Button1Click(Sender: TObject);
begin
  ShowCatalog(TForm2, '', '', 0, 0);
end;

Nos leemos

[enecumene]

delphi

---------------------------
Debugger Exception Notification
---------------------------
Project Cobros.exe raised exception class EAccessViolation with message 'Access violation at address 0042900C in module 'Cobros.exe'. Read of address 00000010'.
---------------------------
Break   Continue   Help   
---------------------------

Lo raro que al ignorar el error si me abre el formulario, y al hacer un break me marca en

delphi

Forma.ShowModal:

[cadetill]

Si haces un debug (breakpoint en la 1era linea del procedimiento) en qué linea te salta el error? Porque he probado el código y me funciona bien

Nos leemos

[Wilson]

El código de Cadetill debería funcionar bien, pienso que el AV  podría ocurrir si pasas como parámetro un índice inexistente ante todo para el TPageControl.

Saludos