11 respuestas en este tema

[enecumene]

Pues eso, he hecho el simple truco de:

delphi

syslocale.MiddleEast := True;
Edit1.BiDiMode := bdRightToLeft;

He intentado castearlo creandome un componente sin instalar, solo como unidad:

delphi

unit EditsExt;
 
interface
 
Uses
  Windows, StdCtrls, Classes, Controls;
 
type
  TEditExt  = class(TCustomEdit)
    private
      FAlignment: TAlignment;
      procedure CreateParams(var Params: TCreateParams);
      procedure SetAlignment(const Value: TAlignment);
    published
      property Alignment: TAlignment read FAlignment write SetAlignment default taLeftJustify;
  end;
 
implementation
 
procedure TEditExt.CreateParams(var Params: TCreateParams);
const
  Alignments: array[TAlignment] of DWord = (ES_LEFT, ES_RIGHT, ES_CENTER);
begin
  inherited CreateParams(Params);
  Params.Style := Params.Style or Alignments[FAlignment]; 
end;
 
procedure TEditExt.SetAlignment(const Value: TAlignment);
begin
  if FAlignment <> Value then
  begin
    FAlignment := Value;
    RecreateWnd ;
  end;
end;
 
end.

Usandolo de esta Manera:

delphi

TEditExt(Edit1).Alignment := taRightJustify;

Y no me funciona!!!

[cadetill]

Buenas,

Puébalo como una clase interpuesta a ver

Nos leemos

[enecumene]

Hola, hice esto:

delphi

type
  TEdit  = class(StdCtrls.TEdit)
    private
      FAlignment: TAlignment;
      procedure CreateParams(var Params: TCreateParams);
      procedure SetAlignment(const Value: TAlignment);
    published
      property Alignment: TAlignment read FAlignment write SetAlignment default taLeftJustify;
  end;

y luego:

delphi

TEdit(Edit1).Alignment := taRightJustify;

Y aun sigue sin alinearmelo a la derecha.

[escafandra]

¿Te sirve esto?

delphi

type
  TEditExt  = class(TCustomEdit)
    public
      constructor Create(AOwner: TComponent); override;
 
  end;
 
implementation
 
constructor TEditExt.Create(AOwner: TComponent);
begin
   syslocale.MiddleEast := True;
  inherited Create(AOwner);
end;

delphi

procedure TForm1.FormCreate(Sender: TObject);
begin
    Edit1:= TEditExt.Create(self);
    Edit1.Parent:= self;
    Edit1.BiDiMode:= bdRightToLeft;
end;

Así si funciona....


Saludos.

[cadetill]

Buenas,

El casteo no hace falta que lo hagas dado que todo TEdit que aparezca en esa unit se tratará como la nueva clase que has creado.

Este código funciona, el Edit1 estará alineado a la derecha y el Edit2 a la izquierda

delphi

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;
 
type
  TEdit  = class(StdCtrls.TEdit)
    private
      FAlignment: TAlignment;
      procedure SetAlignment(const Value: TAlignment);
    protected
      procedure CreateParams(var Params: TCreateParams); override;
    published
      property Alignment: TAlignment read FAlignment write SetAlignment default taLeftJustify;
  end;
 
  TForm1 = class(TForm)
    Edit1: TEdit;
    Edit2: TEdit;
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
procedure TForm1.FormCreate(Sender: TObject);
begin
  Edit1.Alignment := taRightJustify;
end;
 
{ TEdit }
 
procedure TEdit.CreateParams(var Params: TCreateParams);
const
  Alignments: array[TAlignment] of DWord = (ES_LEFT, ES_RIGHT, ES_CENTER);
begin
  inherited CreateParams(Params);
  Params.Style := Params.Style or Alignments[FAlignment];
end;
 
procedure TEdit.SetAlignment(const Value: TAlignment);
begin
  if FAlignment <> Value then
  begin
    FAlignment := Value;
 
    RecreateWnd ;
  end;
end;
 
end.

Nos leemos


EDITO: se me olvidaba. Si pones la nueva clase de TEdit en una unit a parte, tienes que asegurarte de que la incluyes en el uses de la unit donde quieras usarla y que esté detrás de la unit StdCtrls

delphi

unit Unit1;
 
interface
 
uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Controls, Forms, Dialogs, StdCtrls, MI_UNIT

[cadetill]

Buenas escafandra,

El único problema que le veo a tu método es que no puedes ver en diseño el aspecto de la pantalla. Por lo demás es una solución perfectamente válida

Nos leemos

[enecumene]

@cadetill: Pues sigue sin funcionarme

@escafandra: la solucion es valida como bien dice cadetill, pero no puedo verlo en tiempo de diseno

[cadetill]

enecumene, he editado el mensaje añadiendo un comentario, mira que no sea por eso

Nos leemos

[enecumene]

enecumene, he editado el mensaje añadiendo un comentario, mira que no sea por eso

Nos leemos

Pues asi la tengo

[cadetill]

Te adjunto demo que funciona (Delphi 6) para que puedas mirar el código a ver qué diferencias hay

Espero te sierva

Nos leemos

[escafandra]

Buenas escafandra,

El único problema que le veo a tu método es que no puedes ver en diseño el aspecto de la pantalla. Por lo demás es una solución perfectamente válida

Nos leemos

Si, es un inconveniente, pero se puede compilar como un componente...

De todas formas , puestos a simplificar, se puede simular con una sóla función:

delphi

function  TEditExt(Edit: TCustomEdit): TCustomEdit;
begin
   syslocale.MiddleEast := True;
   Result:= Edit;
end;

delphi

procedure TForm1.FormCreate(Sender: TObject);
begin
    TEditExt(Edit1).BiDiMode:= bdRightToLeft;
end;

Bueno, no es un cast, pero... ¿A que es simple? 

Saludos.

[enecumene]

@escafandra: No manches , pero yo no se por que a mi no me funciona lo del BiDiMode

@cadetill: ya pude ver el demo y vi lo que me faltaba, un override en createparams y ya me funciono.

Muchas gracias a todos, hoy aprendi sobre las clases interpuestas