8 respuestas en este tema

[monchito_elroro]

Buenas chicos yo aquí de nuevo con una pequeña consultita.....

Resulta que estoy pensando crear una pequeña aplicación q pueda buscar texto o parte de este, de toda una lista, por ejemplo tener un listado de nombres y en la parte de encima tenga un TEDIT en el cual cuando ni bien comienze a escribir se vaya filtrando los resultados......

Estuve pensando en usar el componente TStringGrid pero no se si será la mejor opción.....

Espero sus consejos de como puedo comenzarlo, gracias.


PD: les adjunto una imagen de como pensaba hacerlo. 

Archivos adjuntos

•  3931_78968c1219c45d81b6ad9e2495e50b8a664eb82e.jpg   34,78KB   15 descargas

[Caral]

Hola
la informacion estara en una bd ?
Saludos

[monchito_elroro]

Gracias por su pronta respuesta, con lo de BD supongo que se refieren a "Base de Datos"....
De momento quisiera comenzar con lo básico de lo básico por ejemplo escribir manualmente los datos o sino extraerlos de un archivito de texto....

[Caral]

Hola
Un buscador es esencialmente un filtro.
Lo mas facil es hacer una Bases de datos con una tabla y de ahi sacar los datos.
Un archivo texto no es tan sencillo ni practico.
Por ejemplo se podria usar una BD access.
Saludos

[Wilson]

Aquí te pongo algo de código para empezar.  Puedes mirar como se asigna el contenido de un archivo de texto plano (.txt) a un memo. El procedimiento Buscar  limpia el Memo2, posteriormente recorre las líneas del Memo1, buscando si el contenido del TEdit1 se encuentra en alguna  línea, en caso afirmativo las líneas que contengan el texto del TEdit1 son agregadas al Memo2.

delphi

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;
 
type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    Memo2: TMemo;
    Edit1: TEdit;
    procedure Button1Click(Sender: TObject);
    procedure Edit1Change(Sender: TObject);
  private
    procedure buscar;
  public
    { Public declarations }
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
procedure TForm1.Button1Click(Sender: TObject);
var
  sFileName: string;
begin
  sFileName := ExtractFilePath(Application.EXEName) + 'Texto.txt';
  if FileExists(sFileName) then
    Memo1.Lines.LoadFromFile(sFileName);
end;
 
procedure TForm1.buscar;
var
  k: integer;
begin
  Memo2.Clear;
  for k := 0 to Memo1.Lines.Count - 1 do
    if pos(trim(Edit1.Text), Memo1.Lines[k]) > 0 then
      Memo2.Lines.Add(Memo1.Lines[k]);
end;
 
procedure TForm1.Edit1Change(Sender: TObject);
begin
  Buscar
end;
 
end.

Es obvio que se puede optimizar de muchas formas, como por ejemplo, poner un Timer para no hacer el proceso con cada letra digitada, sino cada lapso de tiempo.

Saludos

[Wilson]

Aqui te pongo algo de código para hacerlo con un StringGrid, lo probé y funciona perfectamente.

delphi

procedure TForm1.Button2Click(Sender: TObject);  {llena el StrigGrid a partir de
un archivo .txt}
var
  sFileName: string;
  Lista: TStringList;
  K: integer;
begin
  StringGrid1.Cells[1, 0] := 'Nombres';
  sFileName := ExtractFilePath(Application.EXEName) + 'Texto.txt';
  Lista := TStringList.Create;
  try
    if FileExists(sFileName) then
    begin
      Lista.LoadFromFile(sFileName);
      StringGrid1.rowcount := Lista.Count + 1;
      for K := 1 to Lista.Count do
        StringGrid1.Cells[1, K] := Lista[K - 1];
    end;
  finally
    Lista.Free;
  end;
end;
 
 
 
procedure TForm1.Edit2Change(Sender: TObject); //filtra  el stringGrid
var
  sFileName: string;
  Lista: TStringList;
  K, h: integer;
begin
  sFileName := ExtractFilePath(Application.EXEName) + 'Texto.txt';
  Lista := TStringList.Create;
  try
    if FileExists(sFileName) then
    begin
      Lista.LoadFromFile(sFileName);
      StringGrid1.rowcount := Lista.Count + 1;
      if trim(Edit2.Text) = '' then // No hay filtro
      begin // Carga completo
        for K := 1 to Lista.Count do
          StringGrid1.Cells[1, K] := Lista[K - 1];
      end // fin de carga completo
      else // hay filtro
      begin
        for K := 1 to Lista.Count do
          StringGrid1.Cells[1, K] := ''; // limpia  todo
        h := 1; // Para evitar huecos en el grid
        for K := 1 to Lista.Count do // carga lineas filtradas
          if pos(trim(Edit2.Text), Lista[K - 1]) > 0 then
          begin
            StringGrid1.Cells[1, h] := Lista[K - 1];
            Inc(h);
          end;
      end;
    end;
  finally
    Lista.Free;
  end;
end;

Saludos

[fredycc]

Que tal monchito_elroro; si hablamos de Lazarus hay una buena alternativa, donde se trata a los archivos planos como si fuera una tabla de una base de datos y hacer consultas tipo LIKE de SQL. Con esto se evita bombardear la base de datos.

ZMSQL is an open source, TBufDataset SQL enhanced in-memory database for FreePascal (FPC), operating with semicolon-separated values flat text tables as a persistence store.
This means you can use files to store your data but get the speed of in-memory processing. Completely written in Pascal, it has no dependencies on external libraries.
It offers:

Loading from and saving to flat text tables
Use of SQL to query the data
Copy data and schema from other datasets
Option to predefine fielddefs or create it on-the fly
Master/detail filtering
Referential integrity
Parameterized queries

ZMSQL : http://wiki.freepascal.org/ZMSQL


Si encuentras bugs reportalos por favor, para mi es una alternativa tipo LINQ en .Net; pues LINQ precisamente lo uso para realizar filtros complejos sin volver a ejecutar SP's complejos y hacer dar cierta rapidez al programa.

Creo uno de estos días haré algo similar como lo que buscas pero en Lazarus, es muy aplicable.

También lo puedes usar con base de datos además pudieras encriptar este archivo plano si la seguridad se ve comprometida en el equipo cliente si es que es necesario mantenerlo mucho tiempo.

Saludos

[monchito_elroro]

Gracias los probaré y les comentaré mis avances..........

[fredycc]

También podría interesarte: JCSV http://wiki.freepasc...CSV_Components)

Saludos