4 respuestas en este tema

[monchito_elroro]

Buenas chicos, como les va, vengo con una nueva interrogante a suplicarles su ayuda.....
Como dice el título estoy deseando saber la manera de como Subir y bajar el volumen del sistema Windows, por ahí encontré este pedacito de código:

delphi

uses MMSystem;
 
type
  TVolumeRec = record
    case Integer of
      0: (LongVolume: Longint) ;
      1: (LeftVolume, RightVolume : Word) ;
    end;
 
const DeviceIndex=5
      {0:Wave
        1:MIDI
        2:CDAudio
        3:Line-In
        4:Microphone
        5:Master
        6:PC-loudspeaker}
   
procedure SetVolume(aVolume:Byte) ;
var Vol: TVolumeRec;
begin
  Vol.LeftVolume := aVolume shl 8;
  Vol.RightVolume:= Vol.LeftVolume;
  auxSetVolume(UINT(DeviceIndex), Vol.LongVolume) ;
end;
 
function GetVolume:Cardinal;
var Vol: TVolumeRec;
begin
  AuxGetVolume(UINT(DeviceIndex),@Vol.LongVolume) ;
  Result:=(Vol.LeftVolume + Vol.RightVolume) shr 9;
end;

Tiene buena pinta pero no logro implementarlo en Lazarus, haber si me dan una manito.......

[escafandra]

Este volumen te puede resultar interesante.


Este código funciona en Lazarus. Los valores de volumen van de 0 a 65535

delphi

uses
  Windows, MMSystem;
 
....................................
 
 
function GetControl(Mixer: DWORD; Control: LPMIXERCONTROL; CtlType: DWORD): DWORD;
var
  Line: MIXERLINE;
  Controls: MIXERLINECONTROLS;
begin
  ZeroMemory(@Line, sizeof(Line));
  ZeroMemory(@Controls, sizeof(Controls));
  Line.cbStruct:= sizeof(Line);
  Line.dwComponentType:= MIXERLINE_COMPONENTTYPE_DST_SPEAKERS;
  Result:= mixerGetLineInfo(Mixer, @Line, MIXER_GETLINEINFOF_COMPONENTTYPE);
  if Result = MMSYSERR_NOERROR then
  begin
    Controls.cbStruct:= sizeof(Controls);
    Controls.dwLineID:= Line.dwLineID;
    Controls.cControls:= 1;
    Controls.dwControlType:= CtlType;
    Controls.cbmxctrl:= sizeof(MIXERCONTROL);
    Controls.pamxctrl:= Control;
    Result:= mixerGetLineControls(Mixer, @Controls, MIXER_GETLINECONTROLSF_ONEBYTYPE);
  end;
end;
 
 
function SetMasterVolume(Mixer: HMIXEROBJ; Value: DWORD): DWORD;
var
  MasterVolume: MIXERCONTROL;
  Details: TMIXERCONTROLDETAILS;
  UnsignedDetails: MIXERCONTROLDETAILS_UNSIGNED;
begin
  ZeroMemory(@Details, sizeof(Details));
  Result:= GetControl(0, @MasterVolume, MIXERCONTROL_CONTROLTYPE_VOLUME);
  if Result = MMSYSERR_NOERROR then
  begin
    Details.cbStruct:= sizeof(MIXERCONTROLDETAILS);
    Details.dwControlID:= MasterVolume.dwControlID;
    Details.cChannels:= 1;
    Details.cMultipleItems:= 0;
    Details.cbDetails:= sizeof(MIXERCONTROLDETAILS_UNSIGNED);
    Details.paDetails:= @UnsignedDetails;
    UnsignedDetails.dwValue:= Value;
    Result:= mixerSetControlDetails(Mixer, @Details, MIXER_SETCONTROLDETAILSF_VALUE);
  end;
end;
 
function GetMasterVolume(Mixer: HMIXEROBJ; Value: LPDWORD): DWORD;
var
  MasterVolume: MIXERCONTROL;
  Details: TMIXERCONTROLDETAILS;
  UnsignedDetails: MIXERCONTROLDETAILS_UNSIGNED;
begin
  Value^:= 0;
  Result:= GetControl(0, @MasterVolume, MIXERCONTROL_CONTROLTYPE_VOLUME);
  if Result = MMSYSERR_NOERROR then
  begin
    Details.cbStruct:= sizeof(MIXERCONTROLDETAILS);
    Details.dwControlID:= MasterVolume.dwControlID;
    Details.cChannels:= 1;
    Details.cMultipleItems:= 0;
    Details.cbDetails:= sizeof(MIXERCONTROLDETAILS_UNSIGNED);
    Details.paDetails:= @UnsignedDetails;
    mixerGetControlDetails(Mixer, @Details, MIXER_SETCONTROLDETAILSF_VALUE);
  end;
  Value^:= UnsignedDetails.dwValue;
end;                             

Saludos.

[monchito_elroro]

Gracias escafranda por su ayuda, mas como implementaría su respectiva llamada.... ???

[escafandra]

Para ajustar un volumen (entre 0 y 65535)

delphi

SetMasterVolume(0, 20000);

Para conocer el volumen:

delphi

var
  Vol: DWORD;
begin
  GetMasterVolume(o, @Vol);
end;

Saludos.

[monchito_elroro]

Gracias amigo, me tome tiempo para probarlo en windows xp, y si funciona, aún no lo pruebo en windows 7, pero tuve la oportunidad de probarlo en windows 8 y en este sistema no obecede...... Será por ser nuevo....?

Seguiré probandolo y de ahí les aviso...