9 respuestas en este tema

[lKinGl]

He Aqui un Truco bastante sencillo pero muy util

1) Agregamos 2 Edits a Nuetro Formulario.
2) Seleccionamos El Edit1
3) En El Evento OnEnter Ponemos Este Código.

delphi

Edit1.Color := clGradientInactiveCaption;

4) En el Evento OnExit este código

delphi

Edit2.Color := clWindow;

y Repetimos los mismos 4 pasos para el Edit2 Salu2 Espero que les guste

[eduarcol]

Bueno si la idea es resaltar el foco, comparto este componente con ustedes, solo tienen que instalarlo y listo para funcionar:

delphi

unit EditResalte;
 
interface
 
uses
  SysUtils, Classes, Controls, StdCtrls, graphics, types;
 
type          
  //Edit
  TEditResalte = class(TEdit)
  private
    { Private declarations }
    cOldColor: TColor;
    FAlignment: TAlignment;
    procedure SetAlignment(const Value: TAlignment);
  protected
    { Protected declarations }
    procedure DoEnter; override;
    procedure DoExit; override;
  public
    { Public declarations }
  published
    { Published declarations }
    procedure CreateParams(var Params: TCreateParams); override;
    property Alignment: TAlignment read FAlignment write SetAlignment default taLeftJustify;
  end;
 
  //Memo
  TMemoResalte = class(TMemo)
  private
    { Private declarations }
    cOldColor: TColor;
  protected
    { Protected declarations }
    procedure DoEnter; override;
    procedure DoExit; override;
  public
    { Public declarations }
  published
    { Published declarations }
  end;
 
const
   cColorResalte = $00B1F2FE;
 
procedure Register;
 
implementation
 
procedure Register;
begin
  RegisterComponents('Standard', [TEditResalte, TMemoResalte]);
end;
 
 
procedure TEditResalte.DoEnter;
begin
   //Resalta el cuadro de texto
   inherited;
   cOldColor := Color;
   Color := cColorResalte;  
   SelectAll;
end;
 
procedure TEditResalte.DoExit;
begin
   //Quita el Resalte del cuadro de texto
   Color := cOldColor;
   inherited;
end;
 
procedure tEditResalte.CreateParams(var Params: TCreateParams);
const
  Alignments: array[TAlignment] of DWord = (0, 2, 1);
begin
  inherited CreateParams(Params);
  Params.Style := Params.Style or Alignments[FAlignment];
end;
 
procedure tEditResalte.SetAlignment(const Value: TAlignment);
begin
  if FAlignment <> Value then
  begin
    FAlignment := Value;
    RecreateWnd ;
  end;
end;
 
 
//Valores del MEMo
procedure TMemoResalte.DoEnter;
begin
   //Resalta el cuadro de texto
   inherited;
   cOldColor := Color;
   Color := cColorResalte;
   SelectAll;
end;
 
procedure TMemoResalte.DoExit;
begin
   //Quita el Resalte del cuadro de texto
   Color := cOldColor;
   inherited;
end;
 
end.

Anexo el .Pas y el .Dpk

Archivos adjuntos

•  26_.zip   1,14KB   12 descargas

[lKinGl]

eduarcol falta esto para instalarlo

  rtl,
  vcl,
  pkTexto;

[eduarcol]

crea un dpk nuevo y añades el .pas, no deberia pedirte mas nada

[lKinGl]

bueno ahora me da error en zCore70

[eduarcol]

algun problemilla de configuración debes tener por ahi, si quieres al que tengo en el adjunto quitale el pktexto del uses (que lo deje por error).  y compilas, lo otro lo agrega cualquier DPK por defecto.

Si eso no funciona, entra en File --> New --> Other y eliges Package, alli le das al boton Add y le agregas el .pas que te envio.

[lKinGl]

algun problemilla de configuración debes tener por ahi, si quieres al que tengo en el adjunto quitale el pktexto del uses (que lo deje por error).  y compilas, lo otro lo agrega cualquier DPK por defecto.

Si eso no funciona, entra en File --> New --> Other y eliges Package, alli le das al boton Add y le agregas el .pas que te envio.

Thank you, esa era la solucion

[eduarcol]

y cual de las dos opciones soluciono el problema?

[lKinGl]

File --> New --> Other y eliges Package, alli le das al boton Add y le agregas el .pas

[luk2009]

bueno a mi me gusto el 1er truquito y me sirvio de mucho
es simple pero muy util
gracias