9 respuestas en este tema

[darkerviti]

Buenos días,

Estoy pegándome con un dbgrid que tiene dentro un checkbox, he probado varias versiones, buscando por internet he encontrado esto:

delphi

procedure TForm1.DBGrid1DrawColumnCell(
  Sender: TObject; const Rect: TRect; DataCol: 
  Integer; Column: TColumn; State: TGridDrawState);
  
const IsChecked : array[Boolean] of Integer = 
      (DFCS_BUTTONCHECK, DFCS_BUTTONCHECK or DFCS_CHECKED);
var
  DrawState: Integer;
  DrawRect: TRect;
begin
  if (gdFocused in State) then
  begin
    if (Column.Field.FieldName = DBCheckBox1.DataField) then
    begin
     DBCheckBox1.Left := Rect.Left + DBGrid1.Left + 2;
     DBCheckBox1.Top := Rect.Top + DBGrid1.top + 2;
     DBCheckBox1.Width := Rect.Right - Rect.Left;
     DBCheckBox1.Height := Rect.Bottom - Rect.Top;
 
     DBCheckBox1.Visible := True;
    end
  end
  else
  begin
    if (Column.Field.FieldName = DBCheckBox1.DataField) then
    begin
      DrawRect:=Rect;
      InflateRect(DrawRect,-1,-1);
 
      DrawState := ISChecked[Column.Field.AsBoolean];
 
      DBGrid1.Canvas.FillRect(Rect);
      DrawFrameControl(DBGrid1.Canvas.Handle, DrawRect, 
                       DFC_BUTTON, DrawState);
    end;
  end; 
end;

Y luego una versión infinitamente más sencilla:

delphi

procedure TForm1.DBGrid1DrawColumnCell(Sender: TObject;
  const Rect: TRect; DataCol: Integer; Column: TColumn; State: TGridDrawState);
const
   CtrlState: array[Boolean] of integer = (DFCS_BUTTONCHECK, DFCS_BUTTONCHECK or DFCS_CHECKED) ;
begin
   if (Column.Field.DataType=ftBoolean) then
   begin
     DBGrid1.Canvas.FillRect(Rect) ;
     if VarIsNull(Column.Field.Value) then
       DrawFrameControl(DBGrid1.Canvas.Handle,Rect, DFC_BUTTON, DFCS_BUTTONCHECK or DFCS_INACTIVE) {grayed}
     else
       DrawFrameControl(DBGrid1.Canvas.Handle,Rect, DFC_BUTTON, CtrlState[Column.Field.AsBoolean]) ; {checked or unchecked}
   end;
end;

Funcionar funciona, el problema es que al lado de checkbox me muestra true/false en la linea seleccionada del grid (el grid solo muestra informacion, no se puede editar)

Os adjunto pantallazo de como queda.



¿Alguno sabe como evitar que muestre el True/False?

Muchas gracias.

[egostar]

Es raro, yo he hecho la prueba y no tengo ese detalle

¿ Será que le asignaste algún valor al campo en tiempo de diseño ?
¿ Qué base de datos usas ? el ejemplo que muestro es con tablas paradox.

A mi me muestra únicamente el checkBox.

Saludos

Archivos adjuntos

•  4160_ada3b2a359e5319d01e49dcacdbd5c1ffe23e561.jpg   197,98KB   12 descargas

[darkerviti]

Si, el datasource esta conectado a un clientdataset que genero en tiempo de ejecución.

El funcionamiento es el siguiente, tengo varias tablas postgresql, y al iniciar el form hago lo siguiente:

delphi

procedure TDataAvailable.FormCreate(Sender: TObject);
var
  I : Integer;
  Method, msg : string;
begin
  if not DM.cdsMethodShow.Active then
    DM.cdsMethodShow.Open;
  SetLength(Methods, DM.cdsMethodShow.RecordCount);
  I := 0;
  DM.cdsMethodShow.First;
  With cdsPatientDataAvailable do
  begin
    FieldDefs.Add('id', ftInteger);
    FieldDefs.Add('name', ftString, 60);
    FieldDefs.Add('lastname', ftString, 60);
    while not DM.cdsMethodShow.Eof do
    begin
      Methods[I] := DM.cdsMethodShow.FieldByName('acronym').AsString;
      FieldDefs.Add(Methods[I], ftBoolean);
      I := I + 1;
      DM.cdsMethodShow.Next;
    end;
    CreateDataSet;
    LogChanges := False;
  end;
  DM.cdsMethodShow.Close;
  cdsPatientDataAvailable.Open;
  if not DM.cdsPatientShow.Active then
    DM.cdsPatientShow.Open;
  DM.cdsPatientShow.First;
  if not DM.cdsDataShow.Active then
    DM.cdsDataShow.Open;
  while not DM.cdsPatientShow.Eof do
  begin
    cdsPatientDataAvailable.Insert;
    cdsPatientDataAvailable.FieldByName('id').AsInteger := DM.cdsPatientShow.FieldByName('idpatient').AsInteger;
    cdsPatientDataAvailable.FieldByName('name').AsString := DM.cdsPatientShow.FieldByName('name').AsString;
    cdsPatientDataAvailable.FieldByName('lastname').AsString := DM.cdsPatientShow.FieldByName('lastname').AsString;
    for method in Methods do
    begin
      cdsPatientDataAvailable.FieldByName(method).AsBoolean := DM.cdsDataShow.Locate('method', VarArrayOf([method]),[]);
    end;
    cdsPatientDataAvailable.Post;
    DM.cdsPatientShow.Next;
  end;
  ResizeDBGrid(dbgPatients);
  for method in Methods do
  begin
    with TDBCheckBox.Create(scbxChecks) do
    begin
      DataField := method;
      Color := dbgPatients.Color;
      Name := 'dbckbx' + method;
      Caption := '';
      ValueChecked := 'Yes';
      ValueUnchecked := 'No';
    end;
  end;
  ResizeDBGrid(DBGrid1);
end;

[FerCastro]

Compañero

A falta del ejemplo, que tengo en casa, te dejo la página de donde tomé la solución para el problema que tu tienes

http://delphi.about....l/aa082003a.htm

El gran gurú Zarko ya lo puso hace unos añitos.

Saludos!! y espero te sirva, y si no le hallas mañana lo busco y con gusto.

[darkerviti]

Compañero

A falta del ejemplo, que tengo en casa, te dejo la página de donde tomé la solución para el problema que tu tienes

http://delphi.about....l/aa082003a.htm

El gran gurú Zarko ya lo puso hace unos añitos.

Saludos!! y espero te sirva, y si no le hallas mañana lo busco y con gusto.

Lo primero, gracias por la ayuda, justo una de las 2 versiones que tengo en pruebas esta sacada de esa web, la verdad es que ahí se encuentra muchisima información.

El tema es que sigue pasando, no se si será por que los datos están generados en un clientdataset q cargo "a mano" y no desde una db.

He encontrado una "chapuza" que me permite saltar el problema, pero me gustaría encontrar el problema.

Por ahora lo he solucionado de la siguiente forma:

Como no quería que pudiesen editar el grid, que es solo de consulta, tengo por costumbre seleccionar toda la linea, pero eso hace que me muestre los textos,  por ahora he quitado la selección de la linea completa y le he forzado a que siempre me marque la primera columna.

delphi

procedure FocusCell(
   const DBGrid : TDBGrid;
   const column : integer) ; overload;
begin
   with TStringGrid(DBGrid) do
   begin
     Col := column;
     SetFocus;
   end;
end;
 
procedure FocusCell(
   const DBGrid : TDBGrid;
   const fieldName : string) ; overload;
var
   column : integer;
   idx : integer;
begin
   column := 0;
   for idx:= 0 to -1 + DBGrid.Columns.Count do
   begin
     if DBGrid.Columns[idx].FieldName = fieldName then
     begin
       column := 1 + idx;
       Break;
     end;
   end;
 
   if column > 0 then FocusCell(DBGrid,column) ;
end;
 
procedure TDataAvailable.dbgPatientsCellClick(Column: TColumn);
begin
  FocusCell(dbgPatients,'id') ;
end;

Si se os ocurre cualquier otra posible solución, será recibida con los brazo abiertos.

[Wilson]

Se me ocurre una chapuza más breve, prueba a ver si te funciona, se trata de asignar al color de la fuente de la columna en cuestión, el mismo color del fondo, lo cual haría invisibles las letras, quedaría más o menos así:

delphi

procedure TForm1.DBGrid1DrawColumnCell(Sender: TObject;
  const Rect: TRect; DataCol: Integer; Column: TColumn; State: TGridDrawState);
const
   CtrlState: array[Boolean] of integer = (DFCS_BUTTONCHECK, DFCS_BUTTONCHECK or DFCS_CHECKED) ;
begin
   if (Column.Field.DataType=ftBoolean) then
   begin
     DBGrid1.Canvas.FillRect(Rect) ;
     DBGrid1.Canvas.Font.Color := DBGrid1.Canvas.Brush.Color; //Esta es la línea sugerida
     if VarIsNull(Column.Field.Value) then
       DrawFrameControl(DBGrid1.Canvas.Handle,Rect, DFC_BUTTON, DFCS_BUTTONCHECK or DFCS_INACTIVE) {grayed}
     else
       DrawFrameControl(DBGrid1.Canvas.Handle,Rect, DFC_BUTTON, CtrlState[Column.Field.AsBoolean]) ; {checked or unchecked}
   end;
end;

No he probado.

Un saludo

[Wilson]

Saqué un poco de tiempo y probé lo que te puse en el post anterior y no funciona.

Pero acabo de diseñar una solución que si funciona y bien, presta atención:

Primero que todo NO vamos a crear columnas para los campos booleanos, en su defecto vamos a agregar  columnas  al DbGrid pero sin asignar ningún campo en la propiedad FieldName de estas, lo único que necesitamos conocer es el índice de las recién creadas columnas.

En el ejemplo siguiente tengo 3 campos booleanos persistentes de nombres Bol1, Bol2 y Bol3  y he creado las columnas de índices, (2, 3 y 4) que dibujarán los respectivos checkbox de los tres campos.

He creado un procedimiento para dibujar cada checkBox y se lo he pasado en el evento OnDrawCollumnCell del DBgrid y funciona de maravilla.

delphi

procedure TForm1.DibujarCheckBox(Grid: TDBGrid; Campo: TField; const Rect: TRect);
const
  CtrlState: array [Boolean] of Integer = (DFCS_BUTTONCHECK, DFCS_BUTTONCHECK or
    DFCS_CHECKED);
begin
  Grid.Canvas.FillRect(Rect);
  if VarIsNull(Campo.Value) then
    DrawFrameControl(Grid.Canvas.Handle, Rect, DFC_BUTTON, DFCS_BUTTONCHECK or
      DFCS_INACTIVE) { grayed }
  else
    DrawFrameControl(Grid.Canvas.Handle, Rect, DFC_BUTTON,
      CtrlState[Campo.AsBoolean]); { checked or unchecked }
end;
 
procedure TForm1.DBGrid1DrawColumnCell(Sender: TObject; const Rect: TRect;
  DataCol: Integer; Column: TColumn; State: TGridDrawState);
begin
  case DataCol of
    2:
      DibujarCheckBox(DBGrid1, Bol1,Rect);
    3:
      DibujarCheckBox(DBGrid1, Bol2, Rect);
    4:
      DibujarCheckBox(DBGrid1, Bol3, Rect);
  end;
end;

En la imagen puedes ver que tengo seleccionado un registro sin letrero alguno, espero te sirva.

Saludos.

Archivos adjuntos

•  4162_7c79d783a078fb6123d257f5d6359a9193a367ab.jpg   17,31KB   11 descargas

[darkerviti]

No he debido entender bien tu código, si no le asigno los FieldName, ¿como hago para que me pille los valores que necesito?

He probado con tu código, pasándole el valor de Column.Field y no me pinta los checkbox.

Saqué un poco de tiempo y probé lo que te puse en el post anterior y no funciona.

Pero acabo de diseñar una solución que si funciona y bien, presta atención:

Primero que todo NO vamos a crear columnas para los campos booleanos, en su defecto vamos a agregar  columnas  al DbGrid pero sin asignar ningún campo en la propiedad FieldName de estas, lo único que necesitamos conocer es el índice de las recién creadas columnas.

En el ejemplo siguiente tengo 3 campos booleanos persistentes de nombres Bol1, Bol2 y Bol3  y he creado las columnas de índices, (2, 3 y 4) que dibujarán los respectivos checkbox de los tres campos.

He creado un procedimiento para dibujar cada checkBox y se lo he pasado en el evento OnDrawCollumnCell del DBgrid y funciona de maravilla.

delphi

procedure TForm1.DibujarCheckBox(Grid: TDBGrid; Campo: TField; const Rect: TRect);
const
  CtrlState: array [Boolean] of Integer = (DFCS_BUTTONCHECK, DFCS_BUTTONCHECK or
    DFCS_CHECKED);
begin
  Grid.Canvas.FillRect(Rect);
  if VarIsNull(Campo.Value) then
    DrawFrameControl(Grid.Canvas.Handle, Rect, DFC_BUTTON, DFCS_BUTTONCHECK or
      DFCS_INACTIVE) { grayed }
  else
    DrawFrameControl(Grid.Canvas.Handle, Rect, DFC_BUTTON,
      CtrlState[Campo.AsBoolean]); { checked or unchecked }
end;
 
procedure TForm1.DBGrid1DrawColumnCell(Sender: TObject; const Rect: TRect;
  DataCol: Integer; Column: TColumn; State: TGridDrawState);
begin
  case DataCol of
    2:
      DibujarCheckBox(DBGrid1, Bol1,Rect);
    3:
      DibujarCheckBox(DBGrid1, Bol2, Rect);
    4:
      DibujarCheckBox(DBGrid1, Bol3, Rect);
  end;
end;

En la imagen puedes ver que tengo seleccionado un registro sin letrero alguno, espero te sirva.

Saludos.

[Wilson]

No he debido entender bien tu código, si no le asigno los FieldName, ¿como hago para que me pille los valores que necesito?

He probado con tu código, pasándole el valor de Column.Field y no me pinta los checkbox.

Si le pasas Column.FieldName no te los va a pintar porque justo esas columnas no tienen nada en FieldName, en ese punto justo bebes pasarle es el nombre de los campos booleanos, si estás creando el dataset dinámicamente puede hacer uso de la función FieldByName que devuelve un TField.

Saludos

delphi

procedure TForm1.DBGrid1DrawColumnCell(Sender: TObject; const Rect: TRect;
  DataCol: Integer; Column: TColumn; State: TGridDrawState);
begin
  case DataCol of
    2:
      DibujarCheckBox(DBGrid1, ClientDataSet1.FieldByName('Bol1'), Rect);
    3:
      DibujarCheckBox(DBGrid1, ClientDataSet1.FieldByName('Bo2'), Rect);
    4:
      DibujarCheckBox(DBGrid1, ClientDataSet1.FieldByName('Bol3'), Rect);
  end;
end;

[look]

Hola amigos ,el JvDbGrid de las JEDI tiene una propiedad que se llama EditControls la cual te permite asignar un control al campo en el grid , sea CheckBox, Combo y otros.

Saludos!