10 respuestas en este tema

[egostar]

Hola

Estoy haciendo una ventana de Acerca de.... y dentro de esa ventana quiero poner algunos detalles sobre el espacio de disco duro.

Tengo este código:

delphi

procedure TForm2.Button1Click(Sender: TObject);
var
  lpRoot: PChar;
  lpFreeBytesToCaller,lpTotalBytes,lpFreeBytes: PLargeInteger;
  int64Total,int64Free: Int64;
begin
     lpRoot := 'C:\';
     if Windows.GetDiskFreeSpaceEx( lpRoot,
                                    lpFreeBytesToCaller,
                                    lpTotalBytes,
                                    lpFreeBytes ) then begin
        int64Total := int64(lpTotalBytes);
        int64Free  := int64(lpFreeBytes);
        Memo1.Lines.Add('Espacio Total del Disco: ' + Format('%d',[int64Total]));
        Memo1.Lines.Add('Espacio Libre del Disco: ' +  Format('%d',[int64Free]));
     end;
end;

Pero me muestra el siguiente error:

---------------------------
Debugger Fault Notification
---------------------------
Project C:\Desarrollo\TDelphi\Comun\API MS\Project2.exe faulted with message: 'access violation at 0x00438aff: read of address 0x00000003'. Process Stopped. Use Step or Run to continue.
---------------------------
OK 
---------------------------

Debo comentar que además del error que me enví­a no me muestra los datos correctamente.

También usaba la función Windows.GetDiskFreeSpace la cual no me muestra ningún error sin embargo no me muestran tampoco los datos correctamente.

delphi

function EspacioLibreEnDisco( const Drive : char ) : Int64;
 begin
       lpRootPathName := PChar( Drive + ':\' );
       if Windows.GetDiskFreeSpace( lpRootPathName,
                                    lpSectorsPerCluster,
                                    lpBytesPerSector,
                                    lpNumberOfFreeClusters,
                                    lpTotalNumberOfClusters ) then
          Result := lpNumberOfFreeClusters * lpBytesPerSector * lpSectorsPerCluster
       else
          Result := -1;
 end;

¿Que estoy haciendo mal?

Salud OS

[enecumene]

Prueba con esto amigo:

delphi

procedure TForm1.Button1Click(Sender: TObject);
var
  freeSpace, totalSpace: Double;
  s: Char;
begin
  // Drive letter
  s := 'D';
 
  freeSpace  := DiskFree(Ord(s) - 64);
  totalSpace := DiskSize(Ord(s) - 64);
 
  label1.Caption := Format('Espacio Disponible: %12.0n', [freeSpace]);
  Label2.Caption := Format('Total de Espacio: %12.0n', [totalSpace]);
  Label3.Caption := IntToStr(Round((totalSpace - freeSpace) / totalSpace * 100)) +
    ' Porciento usado.';
end;

Saludos.

[egostar]

Gracias amigo enecumene, pues si, efectivamente si me muestra correctamente los datos, que estoy haciendo mal con el API

Salud OS

[enecumene]

Ah qué bien te haya funcionado, pues de API ni idea , vamos a esperar a los maestros de esa area a ver qué dicen.

Saludos.

[egostar]

Ah qué bien te haya funcionado, pues de API ni idea , vamos a esperar a los maestros de esa area a ver qué dicen.

Saludos.

Yeap, aunque tu respuesta soluciona mi "problema" me gustarí­a saber que tan "wey" soy con el API

Salud OS

[cHackAll]

delphi

// el compilador realiza "imul" a 32 bits
// el casting obliga a llamar a "_llmul" a 64 bits
function EspacioLibreEnDisco(const Drive: Char): Int64;
var SectorsPerCluster, BytesPerSector, NumberOfFreeClusters, TotalNumberOfClusters: Cardinal;
begin
 if Windows.GetDiskFreeSpace(PChar(Drive + ':\'), SectorsPerCluster, BytesPerSector, NumberOfFreeClusters, TotalNumberOfClusters) then
  Result := BytesPerSector * SectorsPerCluster * Int64(NumberOfFreeClusters) // Int64()
 else
  Result := -1;
end;
 
// problema con puntero (ultimo parámetro)
procedure TForm1.Button1Click(Sender: TObject);
var FreeBytesToCaller, TotalBytes, FreeBytes: Int64;
begin
 if Windows.GetDiskFreeSpaceEx('c:\', FreeBytesToCaller, TotalBytes, @FreeBytes) then
  begin
   Memo1.Lines.Add('Espacio Total del Disco: ' + Format('%u', [TotalBytes]));
   Memo1.Lines.Add('Espacio Libre del Disco: ' +  Format('%u', [FreeBytesToCaller]));
 
   Memo1.Lines.Add('"EspacioLibreEnDisco": ' +  IntToStr(EspacioLibreEnDisco('c')));
  end;
end;

[egostar]

Vaya, esos pequeños detalles que hacen que una aplicación sea defectuosa.

Gracias little Bro

Salud OS

[egostar]

Hola

Gracias por la ayuda amigos, me he decidido por el uso del API GetDiskFreeSpaceEx.

Salud OS

[egostar]

Hola

Pues ya estoy agregando mas datos, utilizando la función GetSystemInfo() obtenemos el tipo de procesador.

delphi

var 
  siSysInfo: SYSTEM_INFO;
  pType: string;
 
  //Obtener Tipo de procesador
  Windows.GetSystemInfo(siSysInfo);
  case siSysInfo.dwProcessorType of
     386  : pType := 'Intel® 386';
     486  : pType := 'Intel® 486';
     586  : pType := 'Intel® Pentium®';
     2200 : pType := 'Intel® IA64';
     8664 : pType := 'AMD® x8664';
  end;
  Label6.Caption := 'Procesador ' + pType;

Salud OS

[AngelF]

¿Y existe alguna función que nos dé el número de serie de un disco duro? Pero me refiero al número de serie que permanece inmutable aún cuando se formatee el disco.

Un saludo.

[cHackAll]

delphi

procedure TForm1.Button1Click(Sender: TObject);
var
 hDevice, Dummy: Cardinal;
 Buffer: array [0..527] of Char;
begin
 hDevice := _lopen('\\.\C:', OF_READWRITE);
 if hDevice <> INVALID_HANDLE_VALUE then
  begin
   DeviceIoControl(hDevice, $0007C088, PChar(#0#2#0#0#0#1#1#0#0#176#236#0#0#0#0#0#0#0#0#0#0#0#0#0#0#0#0#0#0#0#0#0), 32, @Buffer, SizeOf(Buffer), Dummy, nil);
   MessageBox(Handle, @Buffer[36], nil, MB_ICONINFORMATION); // 20 chars
   CloseHandle(hDevice);
  end;
end;