Detectado javascript desactivado

Tienes el javascript desactivado en este momento. Muchas funciones podrían no funcionar. Por favor reactiva el javascript para obtener una funcionalidad completa.

[RESUELTO] Cargando Playlists de winamp en un listbox [Problema]

Comenzado por enecumene , oct 16 2009 07:05

Por favor identifícate para responder

4 respuestas en este tema

#1 enecumene

Webmaster

Administrador
7.419 mensajes

LocationRepública Dominicana

Escrito 16 octubre 2009 - 07:05

Hola amigos, estoy haciendo un procedimiento que carga un achivo .M3u de winamp en un listbox, hasta ahora me va funcionando bien, lo teng así:

delphi

Type
  TMiObjeto = class(TObject)
    sPath: String;
  end;
 
procedure CargarM3u(M3u: string; Src: TListbox);
var m3ufile: TStringList;
    i: integer;
    Temp, Cancion: string;
    obj: TMiObjeto;
begin
      obj := TMiObjeto.Create;
      m3ufile := TStringList.Create;
      m3ufile.LoadFromFile(M3u);
 
      for i := 0 to m3ufile.Count -1 do
         begin
           Temp := UpperCase(Trim(m3ufile[i]));
             if Copy(Temp, 1, 1) <> &#39;#&#39; then
                obj.sPath := m3ufile[i]
             else
                if Copy(Temp, 1, 8) = &#39;#EXTINF:&#39; then
                   Cancion := Copy(m3ufile[i], Pos(&#39;,&#39;, m3ufile[i]) + 1, Length(m3ufile[i]));
 
                   Src.AddItem(Cancion, TMiobjeto(obj));
         end;
          m3ufile.Free;
          obj.Free;
end;

El resultado es el siguiente:

Imagen Enviada

Problema número 1, se me repite dos veces la canción, problema número 2, cuanto intento el valor del objeto de un item del listbox me da error:

---------------------------

Debugger Exception Notification
---------------------------
Project Project1.exe raised exception class EAccessViolation with message 'Access violation at address 004032B2 in module 'Project1.exe'. Read of address BAADF00D'. Process stopped. Use Step or Run to continue.
---------------------------
OK Help
---------------------------

El code lo tengo así:

delphi

procedure TForm1.Button2Click(Sender: TObject);
var
  Obj: TmiObjeto;
  i: integer;
begin
  i := ListBox1.ItemIndex;
  Obj := ListBox1.Items.Objects[ListBox1.Items.IndexOf(ListBox1.Items[i])] as TmiObjeto;
  ShowMessage(Obj.sPath);
end;

Ya probé con el paso a paso (F4 y F7) y se obitenen los valores correctamente, así que no sé por donde anda el problema. ¿me pueden echar una mano?.

Saludos.

0

Volver arriba

#2 Héctor Randolph

501st Legion

Moderadores
664 mensajes

LocationMéxico

Escrito 16 octubre 2009 - 08:43

Hola enecumene

Debes crear un objeto por cada elemento de la lista, revisando tu código solamente creas un objeto.

delphi

  obj := TMiObjeto.Create; //Esta línea debe ir dentro del ciclo for

Por otra parte, me parece que esto lo puedes simplificar

delphi

  Obj := ListBox1.Items.Objects[ListBox1.Items.IndexOf(ListBox1.Items[i])] as TmiObjeto;

Tal vez con esto sea suficiente

delphi

  Obj := ListBox1.Items.Objects[i] as TmiObjeto;

Saludos

0

Volver arriba

#3 enecumene

Webmaster

Administrador
7.419 mensajes

LocationRepública Dominicana

Escrito 17 octubre 2009 - 08:10

Gracias Héctor, colocando la creación del objeto dentro del ciclo For se resuelve el problema del error, el problema 1 sigo sin resolver, se repite dos veces y la primera de cada una no tiene valor en su objeto pero en la segunda sí

.

0

Volver arriba

#4 seoane

Advanced Member

Administrador
1.259 mensajes

LocationEspaña

Escrito 17 octubre 2009 - 03:38

Aquí un ejemplo:

delphi

type
  TMiObjeto = class(TObject)
    sPath: String;
    sTitulo: String;
  end;
 
procedure CargarM3U(Filename: String; Dst: TListbox);
var
  i: Integer;
  Str,Titulo: String;
  MiObjeto: TMiObjeto;
begin
  with TStringList.Create do
  try
    Titulo:= EmptyStr;
    LoadFromFile(Filename);
    for i:= 0 to Count - 1 do
    begin
      Str:= Trim(Strings[i]);
      if Str <> EmptyStr then
      begin
        if Copy(Str,1,1) = '#' then
        begin
           if Copy(Uppercase(Str),1,8) = '#EXTINF:' then
           begin
             System.Delete(Str,1,8);
             if Pos(',',Str) > 0 then
             begin
               System.Delete(Str,1,Pos(',',Str));
               if Pos(',',Str) > 0 then
               begin
                 System.Delete(Str,Pos(',',Str),MAXINT);
               end;
               Titulo:= Trim(Str);
             end;
           end;
        end else
        begin
          MiObjeto:= TMiObjeto.Create;
          MiObjeto.sPath:= Str;
          MiObjeto.sTitulo:= Titulo;
          if Titulo <> EmptyStr then
            Dst.AddItem(Titulo,MiObjeto)
          else
            Dst.AddItem(Str,MiObjeto);
          Titulo:= EmptyStr;
        end;
      end;
    end;
  finally
    Free;
  end;
end;

En cuanto a tu código, fíjate que añades un nuevo item siempre, da igual que sea una linea que empiece por #, un archivo o simplemente una linea en blanco. Creo que por ahí te falta algún if o quizá algún else