Javascript Disabled Detected

You currently have javascript disabled. Several functions may not work. Please re-enable javascript to access full functionality.

Rutinas pequeñas que pueden ayudar

Started by egostar , Jan 15 2009 12:33 PM

Prev

Please log in to reply

27 replies to this topic

#21 Al González

Advanced Member

Miembro Platino
99 posts

Posted 09 February 2009 - 11:49 PM

¡Hola!

Antes que nada un saludo a todos, hace días que no venía por aquí. :$

Aprovecho para saludar especialmente a Cadetill, de quien tengo muy gratos recuerdos de otro lugar y época. Cómo los he echado de menos a ti y a el resto de la pandilla de aquellos viejos tiempos. Los relaciono mucho con mi feliz estancia en Cuernavaca del 2004 a pesar de estar a miles de jornadas de mula. Aquellas noches de descubrimiento de Firebird, romance y filosofía eran increíbles.

Bueno, aquí mi aportación:

delphi

  Function Uno (Const Valor :Boolean) :Integer;
  Begin
    Result := (Byte (Valor) * 2) - 1;
  End;

Esta función convierte un valor Boolean, False o True, en un entero de valor -1 o +1, respectivamente.

¿Utilidad? Podría ser el transferir una bandera que indica ir hacia adelante —True— o hacia atrás —False— en el valor entero (+1 o -1) que habría que sumar a una propiedad para realizar la acción en el sentido indicado.

Internamente False es 0 y True 1. Lo que hace esta función es darle simetría aritmética a esos valores lógicos. De otra forma, si sólo intentáramos un clásico molde de tipo como "Byte (Valor)", con False sumaríamos 0 (no se movería para ningún lado) y sólo con True se movería.

Sucede que a veces una rutina recibe un parámetro Boolean llamado, por ejemplo, "GoForward", para indicar si queremos que avance o retroceda (True o False). Dentro de la función, si ese avance o retroceso implica un incremento o decremento de igual magnitud pero de signo contrario a un contador, propiedad de posición, etc., dicha función puede llamar a Uno para obtener el incremento en sí o el factor por el cual haya que multiplicar el incremento.

delphi

Position := Position + Uno (GoForward);

Perdón si fue mucho rollo. (~)

Uno (abrazo);

Al González.

0

Back to top

#22 Héctor Randolph

501st Legion

Moderadores
664 posts

LocationMéxico

Posted 10 February 2009 - 10:27 AM

Seguramente te ha sucedido que al realizar una búsqueda por internet, el motor de búsqueda te muestra algunas sugerencias con palabras "muy similares" a la que has escrito.

Por ejemplo, si escribes "Delfi" o "Delpi" probablemente el motor de búsqueda responderá:

"Quizás quiso decir Delphi" 8-|

Pero, ¿cómo logra el motor determinar cuales palabras se parecen entre sí?. La respuesta puede ser muy compleja, sin embargo, la pieza principal en este tipo de algoritmos es encontrar una función que me diga qué tan lejos se encuentra una palabra de otra.

Alguna vez un matemático ruso llamado Vladimir Levenshtein propuso una función muy simple para determinar la distancia que existe entre un par de palabras.

Se le llama Distancia de Levenshtein o distancia de edición al número mínimo de operaciones requeridas para transformar una cadena de caracteres en otra.

Es útil en programas que determinan cuán similares son dos cadenas de caracteres, como es el caso de los correctores de ortografía.

Por ejemplo, la distancia de Levenshtein entre "kitten" y "sitting" es de 3 porque se necesitan al menos tres ediciones elementales para cambiar uno en el otro.

1. kitten ? sitten (sustitución de 'k' por 's')
2. sitten ? sittin (sustitución de 'e' por 'i')
3. sittin ? sitting (inserción de 'g' al final)

Bueno dejo aquí la implementación en Delphi del algoritmo de Levenshtein.

delphi

function DistanciaLevenshtein(Str1, Str2: String): Integer;
var
  d : array of array of Integer;
  Len1, Len2 : Integer;
  i, j, cost: Integer;
begin
  Len1:=Length(Str1);
  Len2:=Length(Str2);
  SetLength(d,Len1+1);
  for i := Low(d) to High(d) do
    SetLength(d[i],Len2+1);
 
  for i := 0 to Len1 do
    d[i,0]:=i;
 
  for j := 0 to Len2 do
    d[0,j]:=j;
 
  for i:= 1 to Len1 do
    for j:= 1 to Len2 do
    begin
      if Str1[i]=Str2[j] then
        cost:=0
      else
        cost:=1;
      d[i,j]:= Min(d[i-1, j] + 1,     // costo de borrar,
                   Min(d[i, j-1] + 1, // costo de insertar
                       d[i-1, j-1] + cost));   // costo de sustituir                            
    end;
  Result:=d[Len1,Len2];
end;

Ejemplo de uso:

delphi

  ShowMessageFmt('La distancia entre kitten y sitting es : %d',[DistanciaLevenshtein('kitten','sitting')]);

Esta función por si misma resuelve el problema de determinar qué tan parecidas son las palabras entre sí, sin embargo, existe una limitante que se origina por el número de operaciones que se deben realizar y aún utilizando una poderosa computadora, aplicar la función sobre un enorme conjunto de datos no es eficiente. Por lo tanto, para utilizar esta función en la práctica, debemos idear un buen algoritmo que minimice el número de comparaciones entre palabras.

Saludos

0

Back to top

#23 poliburro

Advanced Member

Administrador
4945 posts

LocationMéxico

Posted 10 February 2009 - 10:51 AM

Interesante algoritmo amigo hector muchas gracias por la aportación

0

Back to top

#24 seoane

Advanced Member

Administrador
1259 posts

LocationEspaña

Posted 15 February 2009 - 12:11 PM

Comprobar si una dirección ip es valida.

delphi

uses WinSock;
 
function IPValida(IP: String): Boolean;
begin
  Result:= inet_addr(PChar(IP)) <> INADDR_NONE;
end;
 
// Por ejemplo
SHowMessage(BoolToStr(IPValida('256.168.1.1'),TRUE));

0

Back to top

#25 escafandra

Advanced Member

Administrador
4107 posts

LocationMadrid - España

Posted 24 February 2009 - 10:13 AM

Esta rutina la he posteado en C/C++, pero por los comentarios, la reescribo aquí.

Se trata de averiguar las fechas de semana santa, tan "imprevisibles" a la hora de realizar los calendarios laborales.

delphi

function GetPascua(year: Integer):TDate;
var
   a, b, c, AA, BB : Integer;
begin
   // Limites de la Semana Santa 22 de marzo hasta 25 de abril
   // Solo desde 1900 hasta el año 2100 las cifras 24 y 5 son cte y válidas
   a := year mod 19;
   b := year mod 4;
   c := year mod 7;
   AA := (19*a + 24) mod 30;
   BB := (2*b  + 4*c + 6*AA + 5) mod 7;
 
   Result := EncodeDate(year, 3, 1) + AA + BB + 22 -1;
end;

Este es el Domingo de Pascua. El jueves Santo será, Pascua-3 y el Viernes Santo, Pascua-2.

Saludos.

0

Back to top

#26 seoane

Advanced Member

Administrador
1259 posts

LocationEspaña

Posted 09 April 2009 - 05:54 AM

Obtener los archivos de un directorio ordenados por fecha de modificación:

delphi

function Comparar(List: TStringList; Index1, Index2: Integer): Integer;
begin
  Result:= Integer(List.Objects[Index1]) - Integer(List.Objects[Index2]);
end;
 
procedure Buscar(Path,Mask: string; Attr: Integer; Lista: TStringList);
var
  SearchRec: TSearchRec;
begin
  if Copy(Path,Length(Path),1) <> '\' then
    Path:= Path + '\';
  if FindFirst(Path + Mask,Attr,SearchRec) = 0 then
  repeat
    Lista.AddObject(Path + SearchRec.Name, TObject(SearchRec.Time));
  until FindNext(SearchRec) <> 0;
  FindClose(SearchRec);
  Lista.CustomSort(Comparar);
end;

Por ejemplo:

delphi

var
  Lista: TStringList;
begin
  Lista:= TStringList.Create;
  try
    Buscar('C:\Directorio','*.*',faAnyFile,Lista);
    Memo1.Lines.Assign(Lista);
  finally
    Lista.Free;
  end;
end;