18 respuestas en este tema

[FGarcia]

Hola!
De nuevo yo...
En un form tengo 8 Edits y algunos botones y combos, necesito llevar a la bd el texto de los edit. Escribi esto pero me manda un mensaje de Access Violation. ¿Que es lo que no esta mal? 

delphi

procedure TfmCFGBasculas.btAceptarClick(Sender: TObject);
var
  i: integer;
begin
  dmDatos.dstNombres.Open ;
 
  for i := 0 to Pred(fmCFGBasculas.ControlCount) do
    with (fmCFGBasculas.Controls[i] as TEdit) do
      begin
        dmDatos.dstNombres.Insert;
        dmDatos.dstNombresID.Value := 0;
        dmDatos.dstNombresNombre.Value := Trim(text);
        dmDatos.dstNombres.Post;
      end;
 
  dmDatos.dstNombres.Close;
 
end;

y este es el mensaje de horror:

---------------------------
Debugger Exception Notification
---------------------------
Project Ezcatch.exe raised exception class EAccessViolation with message 'Access violation at address 0047E3EA in module 'Ezcatch.exe'. Read of address 000001D4'.
---------------------------
Break  Continue  Help 
---------------------------

[cHackAll]

Talvez un;

delphi

// . . .
 
 if fmCFGBasculas.Controls[i] is TEdit then
  with // . . .

[FGarcia]

mi no entender
nada, nada
limonada!

Tu de pocos caracteres, yo de pocas neuronas.....

[egostar]

mi no entender
nada, nada
limonada!

Tu de pocos caracteres, yo de pocas neuronas.....

Lo que pasa es que estar recorriendo todos los componentes sin validar que el que estas leyendo sea un TEdit, por eso es que te falta esa comparación cuando sea TEdit haga lo que quieras.

Salud OS

[FGarcia]

Sin meterme en profundidades que no conosco me parece que AS implicitamente lleva la utilidad de IS. Por otro lado el mensaje de horror sigue igual.

[eduarcol]

en que linea te da??

eso sucede porque referencias un objeto no creado

[FGarcia]

El error se ocasiona al entrar en el ciclo if, despues de abrir el dataset.

He modificado de diversas formas el codigo y el error sigue el mismo, esta es la actual.

delphi

procedure TfmCFGBasculas.btAceptarClick(Sender: TObject);
var
  i: integer;
begin
  dmDatos.dstNombres.Open ;
 
  for i := 0 to Pred(fmCFGBasculas.ControlCount) do
    if fmCFGBasculas.Controls[i] is TEdit then
      //with (fmCFGBasculas.Controls[i] as TEdit) do
        begin
          dmDatos.dstNombres.Insert;
          dmDatos.dstNombresID.Value := 0;
          dmDatos.dstNombresNombre.Value := Trim((fmCFGBasculas.Controls[i] as TEdit).text);
 
        end;
  dmDatos.dstNombres.Post;
  //dmDatos.dstNombres.Close;
 
end;

[enecumene]

Me da la impresión de que se trata de la función pred, ¿intentaste hacerlo del modo tradicional?:

delphi

for i := 0 to fmCFGBasculas.ControlCount - 1 do

Saludos.

[FGarcia]

Pues al parecer es un error del d2009 con la propiedad ControlCount. Simplifique todo hasta que solo me mostrara una ventanita con el valor de 'i'  y funciono ok. Puse la sentencia de

delphi

for i := 0 to fmCFGBasculas.ControlCount - 1 do
   showMessage(InttoStr(i));

y aparecio el error.

Y si, probe de la manera tradicional y lo mismo.

[enecumene]

Vaya ...prueba con ComponentCount entonces, hay que descartar que sea problema del controlCount.

Saludos.

[eduarcol]

no sera que tienes otro control con el mismo nombre de fmCFGBasculas???

yo que yu probara con una aplicacion en blanco a ver por donde vienen los tiros

[Al González]

¡Hola Fidel!

Descarta que se trate de un problema de Delphi.

Según parece, la variable formulario fmCFGBasculas no está inicializada y es por ello que casi cualquier cosa que escribas, con "fmCFGBasculas." te causará una excepción como la que señalas.  La causa puede estar en la manera en que estás creando la instancia de clase TfmCFGBasculas.

También recuerda que dentro de un método no es necesario referirse de forma explí­cita al objeto sobre el que se está ejecutando ese método.  Así­ que en lugar de "fmCFGBasculas.ControlCount", puedes escribir simplemente "ControlCount" (porque ya estás dentro de un TfmCFGBasculas).  Y haciéndolo de esa manera, no será relevante que la variable fmCFGBasculas tenga valor o no, mientras el formulario de clase TfmCFGBasculas realmente exista (aunque no esté asignado a esa variable).

Espero haberme explicado.

Un saludo.

Al González.

[FGarcia]

Disculpas, ayer otros deberes me alejaron de aqui pero me hicieron darme cuenta de que ¡tengo muy mala condicion fisica!

Gracias por responder Al.

El fmCFGBasculas es un formulario que creo desde un elemento de menu asi:

delphi

with TfmCFGBasculas.Create(Application) do
          try
            showmodal;
          finally
            free;
          end;

He modificado el procedimiento del boton a esto

delphi

procedure TfmCFGBasculas.btAceptarClick(Sender: TObject);
var
  i: integer;
begin
  dmDatos.dstNombres.Open ;
 
  //Si lo dejo en el ciclo For aparece un mensaje de que el dataset no esta en INSERT
  dmDatos.dstNombres.Insert;  
  
  for i := 0 to ControlCount - 1 do
    if Controls[i] is TEdit then
      with (Controls[i] as TEdit) do
        begin
          dmDatos.dstNombresID.Value := 0;
          dmDatos.dstNombresNombre.Value := Trim(text);
          dmDatos.dstNombres.Post;
        end;
 
  //dmDatos.dstNombres.Post;  Aqui marca un error de que el campo ID debe de tener un valor
  //dmDatos.dstNombres.Close;
 
  //ShowMessage(IntToStr(i));
 
end;

Y despues del post hago esto (un modulo de datos):

delphi

procedure TdmDatos.dstNombresAfterPost(DataSet: TDataSet);
begin
  Transaction.CommitRetaining ;
end;

¿Porque tanto rollo? Ahora ya no registra error alguno pero no guarda datos en la BD 

[enecumene]

delphi

dmDatos.dstNombresID.Value := 0;

creo que esa parte va así­:

delphi

dmDatos.dstNombresID.Value := Null;

Me imagino que usas algún trigger o generador, deberí­a de dispararse sólo.

Saludos.

[FGarcia]

En este hilo hice mencion a ese pequeño detalle y el como lo solucione. Al momento de responder este, he hecho otras combinaciones con el codigo y he observado detalle en la ventana de mensaje que puse que la cuenta de controles solo llega a 10.

1 GroupBox
  2 Labels
  1 Edit
  1 ComboBox
  1 Boton
Total = 6 Componentes

Si lo multiplicamos por 8 son 48 componentes. El ciclo for para ControlCount solo cuenta 10 ¿Realmente cuenta los EDIT? 

[eduarcol]

Lo que sucede es que el control solo cuenta los controles cuyo parent sea directamente el Form o el componente que esta contando, para lo que quieres necesitas es componentcount

[FGarcia]

Aun Hay mucho que aprender de Delphi......

Al final quedo asi:

delphi

procedure TfmCFGBasculas.btAceptarClick(Sender: TObject);
var
  i: integer;
begin
  dmDatos.dstNombres.Open ;
 
  for i := 0 to componentCount - 1 do
    begin
      if Components[i] is TEdit then
        with (Components[i] as TEdit) do
          begin
            dmDatos.dstNombres.Insert;
            dmDatos.dstNombresID.Value := 0;
            dmDatos.dstNombresNombre.Value := text;
            dmDatos.dstNombres.Post;
          end;
    end;
  dmDatos.dstNombres.Close;
end;

Seguro aun se puede mejorar!

[enecumene]

Vaya ...prueba con ComponentCount entonces, hay que descartar que sea problema del controlCount.

Saludos.

8-)  8-) post #9

Me alegro que hayas salido de ese atolladero

[Al González]

¡Hola de nuevo!

Al final quedo asi:...

Seguro aun se puede mejorar!

Una versión alternativa:

delphi

procedure TfmCFGBasculas.btAceptarClick(Sender: TObject);
Var
  I :Integer;
begin
  dmDatos.dstNombres.Open;
 
  Try
    For I := 0 To ComponentCount - 1 Do
      If Components [I] Is TEdit Then
        dmDatos.dstNombres.AppendRecord (
          [0, Trim (TEdit (Components [I]).Text)]);
  Finally
    dmDatos.dstNombres.Close;
  End;
end;

Suponiendo que ID y Nombre  son los dos primeros campos en el conjunto de datos.  De estar separados, hay que agregar "Null" para los campos intermedios (para los finales no es necesario).

Espero sea de utilidad, feliz domingo.

Al González.