9 respuestas en este tema

[seoane]

Pues jugando un poco llegue a esta pequeña aplicación que nos permite actualizar el estado de twitter desde la linea de comandos.

Se utiliza de la siguiente manera:

delphi

twitter usuario contraseña "El nuevo estado"

El código es el siguiente (es una aplicación de consola):

delphi

program twitter;
 
{$APPTYPE CONSOLE}
 
uses
  Windows, SysUtils, Classes, Wininet, base64;
 
function URLEncode(Str: String): String;
var
  i: integer;
begin
  Result:= '';
  for i:= 1 to Length(Str) do
    if Str[i] in ['A'..'Z','a'..'z','0'..'9','-','_','.'] then
      Result:= Result + Str[ i ]
    else
      Result:= Result + '%' + IntToHex(Ord(Str[ i ]),2);
end;
 
function Post(Servidor, Url, Cabeceras, Parametros: String; Puerto: Word;
  Stream: TStream): Boolean;
var
  hNet: HINTERNET;
  hCon: HINTERNET;
  hReq: HINTERNET;
  Context: DWORD;
  BytesRead: DWORD;
  Buffer: array[0..10240] of Char;
begin
  Context:= 0;
  Result := FALSE;
  hNet := InternetOpen('Agent', INTERNET_OPEN_TYPE_PRECONFIG, nil, nil, 0);
  if (hNet <> nil) then
  begin
    FillChar(Buffer,Sizeof(Buffer),#0);
    hCon:= InternetConnect(hNet,PChar(Servidor),Puerto,nil,nil,
      INTERNET_SERVICE_HTTP,0,Context);
    if (hCon <> nil) then
    begin
      hReq:= HttpOpenRequest(hCon,'POST',PChar(Url),nil,nil,nil,
        INTERNET_FLAG_RELOAD,Context);
      if (hReq <> nil) then
      begin
        try
          if Length(Cabeceras) > 0  then
            Cabeceras:= 'Content-Type: application/x-www-form-urlencoded'
              + #13#10 + Cabeceras
            else
              Cabeceras:= 'Content-Type: application/x-www-form-urlencoded';
          if HttpSendRequest(hReq,PChar(Cabeceras),Cardinal(-1),
            PChar(Parametros),Length(Parametros)) then
          begin
            while (InternetReadFile(hReq,@Buffer,sizeof(Buffer),BytesRead)) do
            begin
              if (BytesRead = 0) then
              begin
                Result := TRUE;
                break;
              end;
              Stream.Write(Buffer,BytesRead);
            end;
          end;
          except end;
        InternetCloseHandle(hReq);
      end;
      InternetCloseHandle(hCon);
    end;
    InternetCloseHandle(hNet);
  end;
end; 
 
function UpdateStatus(Username, Password, Status: String): Boolean;
var
  Cabeceras: String;
  Parametros: String;
  Stream: TMemoryStream;
begin
  Cabeceras:= Username + ':' + Password;
  Cabeceras:= BinToStr(PByte(PChar(Cabeceras)),Length(Cabeceras));
  Cabeceras:= Trim('Authorization: Basic ' + Cabeceras);
  Parametros:= 'status=' + UrlEncode(UTF8Encode(Status));
  Stream:= TMemoryStream.Create;
  try
    Result:= Post('twitter.com','statuses/update.xml',Cabeceras,Parametros,
      80,Stream);
    Writeln;
    with TStringStream.Create(EmptyStr) do
    try
      Stream.Position:= 0;
      CopyFrom(Stream,0);
      Writeln(UTF8Decode(DataString));
    finally
      Free;
    end;
  finally
    Stream.Free;
  end;
end;
 
begin
  Writeln;
  if not UpdateStatus(ParamStr(1),ParamStr(2),ParamStr(3)) then
    Writeln('Error');
  Writeln;
end.

Y todo junto y envuelto para regalo un poco mas abajo 

Archivos adjuntos

•  1344_7f6ec5ab65ea19261c727a1c50a91ef5dc472a81.zip   5,65KB   4 descargas

[seoane]

Y por si alguien lo quiere probar y no le compila (la función UTF8Decode no se incluye en Delphi 7) dejo por aquí el programa ya compilado.

Archivos adjuntos

•  1345_944669dd54c72793498352e77e090a10e85e0890.zip   44,9KB   5 descargas

[egostar]

Genial amigo seoane , una pregunta, ¿ que es lo que se debe "pasar" en el parámetro status ?

Salud OS

[seoane]

¿ que es lo que se debe "pasar" en el parámetro status ?

Me parece que tu eres casi tan novato como yo usando el twitter, y yo me acabo de registrar hoy 

El "status" son las entradas de texto, de 140 caracteres como máximo, que se envían para ser  publicadas. Ese es el nombre que se le da en la API de twitter, pero creo que por ahí los conocen como "tweets", para mi es lo que se envía en el cuadro de texto de la pagina de twitter justo debajo de la pregunta  What’s happening? 

[egostar]

es que me confundió eso de Status. Ya caigo

Salud OS

[escafandra]

Buen trabajo  .

Y por si alguien lo quiere probar y no le compila (la función UTF8Decode no se incluye en Delphi 7) dejo por aquí el programa ya compilado.

¿De donde sacaste la función UTF8Decode? ¿Se incluye en versiones mayores de delphi 7?

Saludos.

[egostar]

Yo tengo Turbo Delphi que es 2006 y ya la trae incluida.

Salud OS

[escafandra]

Pues mirándolo mejor, si viene en mi delphi 6 y delphi 7, donde no viene es en mi Builder 5  aunque si viene en el Builder 6  .

Saludos.

[seoane]

Pues mirándolo mejor, si viene en mi delphi 6 y delphi 7, donde no viene es en mi Builder 5  aunque si viene en el Builder 6  .

Pues para los que no la tengan una alternativa:

delphi

function Utf8Decode2(Src: String): String;
var
  Size: Integer;
  Str: PWChar;
begin
  Size:= MultiByteToWideChar(CP_UTF8,0,PChar(Src),
    Length(Src),nil,0);
  if Size > 0 then
  begin
    GetMem(Str,(Size+1)*Sizeof(WideChar));
    FillChar(Str^,(Size+1)*Sizeof(WideChar),#0);
    try
      if MultiByteToWideChar(CP_UTF8,0,PChar(Src),
         Length(Src),Str,Size) > 0 then
      begin
        Result:= WideString(Str);
      end;
    finally
      FreeMem(Str);
    end;
  end;
end;

[egostar]

Ah vaya, pues tengo mi Delphi 4 que le va a venir muy bien esa función

Salud OS