31 respuestas en este tema

[TiammatMX]

Chavos:

Resulta que ahora debo llenar un TTreeView con los datos de una tabla, con una profundidad de cuatro ramas...

Es decir:
Sector
        |_SubSector
                        |_Oficina
                                    |_Encargado

Y del encargado, mostrar sus datos en DbEdit's o Edit's. Los "cortes" están definidos perfectamente puesto que en cualquier momento puedo "saber" dónde me encuentro, pero llenar el TTreeView se me ha complicado por que no sé manejarlo.Chapuceramente he diseñado algo así:
[/]

delphi

procedure TfrmPrncpl.LlnrArblArs;
var
  tnSuperior, tnPadre, tnHijo, tnNieto, tnGato : TTreeNode;
  sInsttcn, sDrccnGnrl, sDrccn, sSubDrccn : string;
begin
  TreVewArblArs.Items.Clear;
  tnSuperior := TreVewArblArs.Items.Add(NIL,'Gobierno del Distrito Federal');
 
  dtamdlDts.ADOQryDts.First;
  tnPadre := TreVewArblArs.Items.AddChild(tnSuperior,dtamdlDts.ADOQryDts.FieldByName('Ca_area').AsString);
  sInsttcn := dtamdlDts.ADOQryDts.FieldByName('Ca_institucion').AsString;
  sDrccnGnrl := dtamdlDts.ADOQryDts.FieldByName('Ca_DirG').AsString;
  sDrccn := dtamdlDts.ADOQryDts.FieldByName('Ca_Dir').AsString;
  sSubDrccn := dtamdlDts.ADOQryDts.FieldByName('Ca_Sub').AsString;
  dtamdlDts.ADOQryDts.Next;
 
  while not dtamdlDts.ADOQryDts.Eof do
  begin
    if sInsttcn = dtamdlDts.ADOQryDts.FieldByName('Ca_institucion').AsString then
    begin
      tnGato := TreVewArblArs.Items.AddChild(tnPadre,dtamdlDts.ADOQryDts.FieldByName('Ca_area').AsString);
      dtamdlDts.ADOQryDts.Next;
    end
    else
    begin
      tnPadre := TreVewArblArs.Items.AddChild(tnSuperior,dtamdlDts.ADOQryDts.FieldByName('Ca_area').AsString);
      sInsttcn := dtamdlDts.ADOQryDts.FieldByName('Ca_institucion').AsString;
    end;
  end;
  dtamdlDts.ADOQryDts.First;
 
    TreVewArblArs.FullExpand;
end;

[][]

Pero como pueden ver, es demasiado "sucio" como para quedar elegante. Además que no es recursivo ni permite adaptarse a algún cambio en la estructura..., ¿alguna idea que pueda ayudarme? [/][/]

[Caral]

Hola
Me encontré este ejemplo de treeview que hace un manejo interesante de la bd,
No es mio, me lo encontré por ahí, tal vez te sirva de algo.
Saludos
PD: No es tu caso, pero creo que esta interesante.

Archivos adjuntos

•  1295_abeeef504b6f097f213ba36559c8f099a2b1b88b.zip   448,45KB   19 descargas

[TiammatMX]

...PD: No es tu caso, pero creo que esta interesante.

Sí, es muy interesante..., tan interesante que fue uno de los primeros ejemplos que encontré y comencé a desmenuzar anoche para construir éste mamotreto que me pidieron. Pero como bien dices, no me ayuda a solucionar mi caso.

Gracias por tu ayuda, muy valiosa.

[Rolphy Reyes]

Saludos.

TiammatMX, las JEDI tienen un TJvDBTreeView, no lo he utilizado pero quizás te pueda servir.

[TiammatMX]

...las JEDI tienen un TJvDBTreeView, no lo he utilizado pero quizás te pueda servir.

Yo también lo intenté, pero resulta que aún no está "maduro" el componente y jamás respondió. De hecho, un par de veces "colgó" a Delphi. Y obviamente, no lo utilicé más.

[Rolphy Reyes]

Saludos.

Chanfle quizás tienes un montón de datos y puede ser lo que mencionas sobre no estar maduro (aunque lo verde hace daño a menos que sea Dolares).

Tengo este ejemplo de como llevar un TMenu a un TTreeView y puede que te ayude:

delphi

function TForm1.Retira(Str: String; Chr: Char): String;
var
  i: Integer;
begin
  Result:='';
  for i:=1 to Length(Str) do
    begin
      if Str[i]<>Chr then
        Result:=Result+Str[i];
    end;
end;
 
procedure TForm1.MenuToTreeView;
var
  i: Integer;
  Root,Node: TTreeNode;
 
procedure SubItems(MenuItem: TMenuItem; ParentNode: TTreeNode);
var
  i: Integer;
  Node: TTreeNode;
begin
  for i:=0 to MenuItem.Count-1 do
    begin
      if MenuItem.Items[i].Caption='-' then
        Continue;
          Node:=TreeView1.Items.AddChild(ParentNode,Retira(MenuItem.Items[i].Caption,'&'));
          Node.Data:=MenuItem.Items[i];
          if MenuItem.Items[i].Count>0 then
             SubItems(MenuItem.Items[i],Node);
   end;
end;
 
begin
  TreeView1.Items.Clear;
  Menu:=NIL; // turns off the main menu
  Root:=TreeView1.Items.Add(NIL,'Menu');
  for i:=0 to MainMenu1.Items.Count-1 do
    begin
          Node:=TreeView1.Items.AddChild(Root,Retira(MainMenu1.Items[i].Caption,'&'));
          Node.Data:=MainMenu1.Items[i];
          if MainMenu1.Items[i].Count>0 then
            SubItems(MainMenu1.Items[i],Node)
    end;
  TreeView1.FullExpand;
end;

[enecumene]

Pues aquí te dejo una idea de un código mío que tengo por ahí, ésta llena dos niveles (Padre e Hijo) pero puedes agregar más:

delphi

Var
    I,CampoCount:Integer;
    Nodo:Packed Array[0..99] of TTreenode;
    NodoValor:Packed array[0..99] of Variant;
begin
    TreeView1.Items.Clear;
    ZDptos.First;
    CampoCount:=ZDptos.FieldCount;
    While not ZDptos.Eof do
    begin
        if NodoValor[0]<> ZDptos.Fields[0].Value then
            Nodo[0]:=TreeView1.Items.Add(nil,Vartostr(ZDptos.Fields[0].Value));
        for I:=1 to ZDptos.FieldCount-1 do
        begin
            if NodoValor[i]<> ZDptos.Fields[i].Value then
                Nodo[i]:=TreeView1.Items.AddChild(Nodo[I-1],Vartostr(ZDptos.Fields[i].Value));
        Nodo[i].Data := pointer(ZDptos.FieldByName('ID').AsInteger);
      if Nodo[i].Level = 2 then
        begin
          Nodo[i].Delete;
        end;
              NodoValor[i]:=ZDptos.Fields[i].Value;
        end;
        NodoValor[0]:=ZDptos.Fields[0].Value;
        ZDptos.next;
    end;

Espero te sea de utilidad.

Saludos.

[andres1569]

Hola TiammatMX,

en primer lugar, supongo que la tabla en cuestión está ordenada de forma que después de cada nivel le siguen los subniveles correspondientes, y así hasta llegar al último, después del cual empieza otra vez ¿con el nivel superior (sector)? ¿puede ser que al acabar con el nivel 4 (encargado) siga con nodos hermanos del nivel 3 (oficina) al estilo de un arbol de directorios?

¿Qué campo empleas para saber el nivel en que estás situado? Veo que comparas el campo 'Ca_institucion' para saber sin has cambiado de nivel, ¿es este campo o hay más campos que comparar?

Saludos

[TiammatMX]

...en primer lugar, supongo que la tabla en cuestión está ordenada de forma que después de cada nivel le siguen los subniveles correspondientes, y así hasta llegar al último, después del cual empieza otra vez ¿con el nivel superior (sector)...

Correctísimo, es un ADOQuery que está ordenado por los campos que serán considerados como cortes y cambios.

...¿puede ser que al acabar con el nivel 4 (encargado) siga con nodos hermanos del nivel 3 (oficina) al estilo de un arbol de directorios?...

De hecho, como están ordenados por cuatro columnas, el query me permite "saber" en cualquier momento cuándo hay que hacer un corte. Así, sería como un árbol de directorios de cuatro niveles.

...¿Qué campo empleas para saber el nivel en que estás situado? Veo que comparas el campo 'Ca_institucion' para saber sin has cambiado de nivel, ¿es este campo o hay más campos que comparar?...

Las columnas te las listo a continuación:
sInsttcn, sDrccnGnrl, sDrccn, sSubDrccn. sInsttcn es el primer corte y con el que estaba probando que todo funcionara correctamente.

[TiammatMX]

Pues aquí te dejo una idea de un código mío que tengo por ahí, ésta llena dos niveles (Padre e Hijo) pero puedes agregar más...

Es excelente..., pero soy medio tonto (aún no domino éste condenado componente TTreeView), ¿dónde le puedo añadir los demás niveles?, ilústrame, por favor.

[TiammatMX]

Saludos.

Chanfle quizás tienes un montón de datos y puede ser lo que mencionas sobre no estar maduro (aunque lo verde hace daño a menos que sea Dolares).

Tengo este ejemplo de como llevar un TMenu a un TTreeView y puede que te ayude:

Gracias, Rolphy. Lo probaré de inmediato.

[escafandra]

Puedes estudiar este código que despliega el árbol de directorios de los discos del sistema incluidos los archivos.

Te dejo un ejemplo simple y rápido de como llenar un árbol:

delphi

procedure TForm1.Button1Click(Sender: TObject);
var
  n, i: integer;
  Nodo: TTreeNode;
begin
 
   for n:= 0 to 10 do
   begin
      Nodo:= nil;
      for i:=0 to 4 do
      begin
        Nodo:= TreeView1.Items.AddChild(Nodo, IntToStr(i));
      end;
   end;
   TreeView1.FullExpand;
 
end;

Saludos.

[kafastoforman]

Hola tiammat, segun lo que te entendi, se me ocurrio hacer esto que tal vez te pueda ayudar:

delphi

procedure TForm1.AddItemsFromQuery(const aColumna: integer;
   const aPadre: TTreeNode; const aQuery: TAdoQuery);
 
  var lPadre: TTreeNode;
 
begin
 
if aColumna >= aQuery.Fields.Count then //Verificamos que la columna pasada exista
  begin
    aQuery.Next;
    exit;
  end;
 
  if trim(aQuery.Fields[aColumna].AsString) = '' then //Verificamos que tenga un valor
  begin
    aQuery.Next;
    exit;
  end;
 
  while not aquery.Eof do
  begin
 
    if (aPadre = nil) then
       AddItemsFromQuery(aColumna+1,
                          TreeView1.Items.AddChild(aPadre,aQuery.Fields[aColumna].AsString),
                          aQuery)
    else
      if aPadre.Text <> aQuery.Fields[aColumna - 1].AsString then
        break
      else
        AddItemsFromQuery(aColumna+1,
                          TreeView1.Items.AddChild(aPadre,aQuery.Fields[aColumna].AsString),
                          aQuery);
 
  end;
 
end;
 
procedure TForm1.Button1Click(Sender: TObject);
begin
 
  TreeView1.Items.Clear;
  AddItemsFromQuery(0,nil,ADOQuery1);
 
end;

Segun la estructura de datos que yo probe y resulto fue la siguiente:

mexico df xochimilco concha angel
mexico df xochimilco concha armando
mexico df xochimilco concha gonzalez
mexico df ao roma gerardo
mexico df ao roma martinez
mexico df ao villas pancho
mexico df ao villas lopez
mexico chiapas municipio pueblo rodrigo
mexico chiapas municipio publito escamilla
españa madrid versa micolonia antonio
españa barcelona catalunia pueblochico raafel

Saludos

Kafastoforman

[TiammatMX]

Hola tiammat, segun lo que te entendi, se me ocurrio hacer esto que tal vez te pueda ayudar:
.
.
.

Segun la estructura de datos que yo probe y resulto fue la siguiente:

mexico  df  xochimilco  concha  angel
mexico  df  xochimilco  concha  armando
mexico  df  xochimilco  concha  gonzalez
mexico  df  ao  roma  gerardo
mexico  df  ao  roma  martinez
mexico  df  ao  villas  pancho
mexico  df  ao  villas  lopez
mexico  chiapas  municipio  pueblo  rodrigo
mexico  chiapas  municipio  publito  escamilla
españa  madrid  versa  micolonia  antonio
españa  barcelona  catalunia  pueblochico  raafel

¡¡EXCELENTE, KASTAFORMAN!!, de hecho, se aproxima mucho al requerimiento...

Solamente que yo desearía algo así:
(mexico  df  xochimilco  concha)  angel
(mexico  df  xochimilco  concha)  armando
(mexico  df  xochimilco  concha)  gonzalez
(mexico  df  ao  roma)  gerardo
(mexico  df  ao  roma)  martinez
(mexico  df  ao  villas)  pancho
(mexico  df  ao  villas)  lopez
(mexico  chiapas  municipio  pueblo)  rodrigo
(mexico  chiapas  municipio  publito)  escamilla
(españa  madrid  versa  micolonia)  antonio
(españa  barcelona  catalunia  pueblochico)  raafel

Donde lo que se encuentra entre paréntesis no debe aparecer. Estoy en lo dicho, seguiré sus consejos.

[andres1569]

TiammatMX, no entiendo que no quieras quen salga lo que está entre paréntesis, supongo que te refieres a que no aparezca todo en la misma linea, aunque sí escalonado: ¿Algo como esto?

mexico 
        df 
          xochimilco 
                  concha 
                          angel
                          armando
                          gonzalez
          ao 
                  roma 
                          gerardo
                          martinez
          ao 
                  villas 
                          pancho


etc.

[TiammatMX]

De hecho, el resultado actual es el que se muestra en la ilustración. Pero si se dan cuenta, se repiten las ramas, por que el contenido de la etiqueta no se ha modificado.

La idea es compactar el resultado a una línea por registro, pero conservando la "arborización" del contenido.

Archivos adjuntos

•  1297_32bbe230069668057c6db148085974e0de4fb503.jpg   118,67KB   13 descargas

[TiammatMX]

Y perdón, se me olvidó poner el código..., casi nada... 

delphi

procedure TfrmPrncpl.LlnrArblArs;
var
  i, count, L_Acc_Fieldcount : Integer;
  L_Acc_Treenode : Packed Array[0..99] of TTreenode;
  L_Acc_value : Packed array[0..99] of Variant;
begin
  TreVewArblArs.Items.Clear;
  L_Acc_Treenode[0]:= TreVewArblArs.Items.Add(NIL,'Gobierno del Distrito Federal');
  dtamdlDts.ADOQryDts.First;
  L_Acc_Fieldcount := dtamdlDts.ADOQryDts.FieldCount;
 
  while not dtamdlDts.ADOQryDts.Eof do
  begin
 
    if L_Acc_Value[0] <> dtamdlDts.ADOQryDts.Fields[0].Value then
//      L_Acc_Treenode[0] := TreVewArblArs.Items.Add(nil,Vartostr(dtamdlDts.ADOQryDts.Fields[0].Value));
      L_Acc_Treenode[0] := TreVewArblArs.Items.Add(nil,VarToStr(dtamdlDts.ADOQryDts.FieldByName('ca_area').Value));
 
    for i := 1 to dtamdlDts.ADOQryDts.FieldCount -2 do
    begin
            if L_Acc_Value[i] <> dtamdlDts.ADOQryDts.Fields[i].Value then
//                L_Acc_Treenode[i] := TreVewArblArs.Items.AddChild(L_Acc_Treenode[i-1],Vartostr(dtamdlDts.ADOQryDts.Fields[i].Value));
                L_Acc_Treenode[i] := TreVewArblArs.Items.AddChild(L_Acc_Treenode[i-1],VarToStr(dtamdlDts.ADOQryDts.FieldByName('ca_area').Value));
 
            L_Acc_Value[i] := dtamdlDts.ADOQryDts.Fields[i].Value;
        end;
        L_Acc_Value[0] := dtamdlDts.ADOQryDts.Fields[0].Value;
 
    dtamdlDts.ADOQryDts.Next;
  end;
  dtamdlDts.ADOQryDts.First;
 
    TreVewArblArs.FullExpand;
end;

[andres1569]

Hola de nuevo,

Lo que pongo aquí es una forma recursiva de afrontar el asunto, teniendo en cuenta que los datos se toman de una consulta SQL y que por lo tanto tiene muchas columnas repetidas que hay que ir comparando desde la primera hasta la de mayor detalle (encargado). Esto condiciona la forma de abordarlo, ya que otras veces se tienen las 4 tablas por separado y con un master-detail se realiza todo de forma más cómoda.

No lo he probado ya que no tengo ahora una tabla donde hacer probaturas, así que ya me dirás qué resultado arroja (si hay algún cuelgue o bucle inifinito, mis excusas de antemano    )

Le he añadido un parámetro CampoClave, donde se le puede pasar el campo que actúa de clave de encargados, en caso de ser numérico se almacena también en el último nodo de cada rama para que al hacer click puedas localizar el registro en la tabla.

delphi

function TfrmPrncpl.AnadeNodo(NodoPadre: TTreeNode; Table: TDataSet;
  NivelActual: Word; CampoClave: TField; Campos: array of TField;
  var Valores: array of variant) : Integer;
var
  i : Integer;
  Nodo : TTreeNode;
begin
  result := NivelActual;
  while (result = NivelActual) AND NOT Table.EOF do
  begin
    // creamos un nuevo nodo dependiente del NodoPadre y le asignamos el valor
    // del campo actual.
    // NOTA: En caso de que haya un CampoClave y que estemos situados en el
    //       último campo, utilizamos el método AddChildObject para asignarle
    //       además un valor (mapeando de Integer a Pointer) que represente a la
    //       la clave primaria del registro actual y que nos servirá para que cuando
    //       el usuario pinche en dicho nodo podamos desplazarnos hasta esa posición
    //       en el Dataset, suponiendo que dicha clave exista y que sea numérica ?¿
    with TreVewArblArs.Items do
      if (CampoClave <> nil) AND (result = High(Campos)) then
        Nodo := AddChildObject(NodoPadre, Campos[result].AsString, Pointer(CampoClave.AsInteger))
      else Nodo := TreVewArblArs.Items.AddChild(NodoPadre, Campos[result].AsString);
    // Si no estamos aún en el último nivel, icrementamos result y nos vamos al
    // siguiente nivel mediante una llamada recursiva, enviándole como NodoPadre
    // el Nodo que acabamos de crear ...
    if result < High(Campos) then
    begin
      Inc(result);
      result := AnadeNodo(Nodo, Table, result, CampoClave, Campos, Valores);
    end
    // ... y si estamos ya en el último nivel, memorizamos los valores anteriores,
    // luego avanzamos un registro en la tabla y recorremos la lista de campos
    // desde el primero comparando con los valores anteriores para averiguar a
    // qué nivel debemos descender para crear el siguiente nodo
    else begin
      for i:=0 to High(Campos) do Valores[i] := Campos[i].Value;
      Table.Next;
      if NOT Table.EOF then
        for result:=0 to High(Campos) do
          if Campos[result].Value <> Valores[result] then break;
    end;
  end;
end;
 
procedure TfrmPrncpl.LlnrArblArs;
var
  i : Integer;
  tnSuperior, tnPadre : TTreeNode;
  FldClave, FldInsttcn, FldDrccnGnrl, FldDrccn, FldSubDrccn : TField;
  Valores: array of variant;
begin
  TreVewArblArs.Items.BeginUpdate;  // para evitar que se actualice el TreeView a cada nodo creado
  try
    TreVewArblArs.Items.Clear;
    tnSuperior := TreVewArblArs.Items.Add(NIL, 'Gobierno del Distrito Federal');
    dtamdlDts.ADOQryDts.First;
    tnPadre := TreVewArblArs.Items.AddChild(tnSuperior, dtamdlDts.ADOQryDts.FieldByName('Ca_area').AsString);
 
 // almacenamos en variables las referencias a los campos involucrados, para
 // ganar en velocidad
    FldClave := dtamdlDts.ADOQryDts.FieldByName('ID_CLAVE');
 
    FldInsttcn := dtamdlDts.ADOQryDts.FieldByName('Ca_institucion');
    FldDrccnGnrl := dtamdlDts.ADOQryDts.FieldByName('Ca_DirG');
    FldDrccn := dtamdlDts.ADOQryDts.FieldByName('Ca_Dir');
    FldSubDrccn := dtamdlDts.ADOQryDts.FieldByName('Ca_Sub'); 
 
 // inicializamos la matriz de valores
    SetLength(Valores, 4);
    for i:= 0 to 3 do Valores[i] := null;
 // lanzamos la función recursiva pasándole 0 como nivel inicial, y el nodo padre
    AnadeNodo(tnPadre, dtamdlDts.ADOQryDts, 0, FldClave, [FldInsttcn,
              FldDrccnGnrl, FldDrccn, FldSubDrccn], Valores);
  finally
    TreVewArblArs.Items.EndUpdate;
  end;
  TreVewArblArs.FullExpand;
end;

[TiammatMX]

...Lo que pongo aquí es una forma recursiva de afrontar el asunto, teniendo en cuenta que los datos se toman de una consulta SQL y que por lo tanto tiene muchas columnas repetidas que hay que ir comparando desde la primera hasta la de mayor detalle (encargado). Esto condiciona la forma de abordarlo, ya que otras veces se tienen las 4 tablas por separado y con un master-detail se realiza todo de forma más cómoda.
...

Gracias..., es una excelente idea. Voy a probarlo de inmediato y te platico los resultados. Ya me urge terminar con ésto para avanzar, que me están bufando para que me apure... 

[TiammatMX]

Lo que pongo aquí es una forma recursiva de afrontar el asunto...

Gracias por el esfuerzo, andres1569..., pero el resultado es igual a lo que tengo desde ayer...

Archivos adjuntos

•  1299_84de1c5c63403201431698248f1e9287eabb4640.jpg   30,68KB   7 descargas