9 respuestas en este tema

[JoAnCa]

Hola a todos
Quisiera hacer un pequeño programita que borre el contenido de la carpeta Windows\Temp, pues a veces se acumulan muchos archivos ocupando espacio innecesario y no se borran automaticamente
Pero esos usuarios no son muy duchos en informatica y uno incluso me dijo que era muy complicado por las herramientas de liberar espacio 

Con Deletefile borra los archivos pero no me borra las carpetas

[cadetill]

Buenas,

delphi

function EmptyDir(Dir: string; Ask: Boolean): Boolean;
var
  Files: integer;
  Search: TSearchRec;
  FileNames: TStringList;
  NFiles: integer;
begin
  Result := False;
 
  if Ask then
  begin
    FileNames := TStringList.Create;
    try
      GetNameFilesFromFolder(Dir, FileNames, '*.*', True);
      NFiles := FileNames.Count;
    finally
      if Assigned(FileNames) then FreeAndNil(FileNames);
    end;
    if (NFiles > 0) and (Application.MessageBox(PChar('Se borrará el contenido de la carpeta seleccionada'#13#13 + Dir + #13#13'Esta carpeta contiene ' + IntToStr(NFiles) + ' ficheros.'#13#13'¿Realmente desea continuar?'), 'Atención', MB_ICONQUESTION + MB_YESNO + MB_DEFBUTTON2) = mrNo) then
      Exit;
  end;
 
  Result := True;
  Dir := IncludeTrailingPathDelimiter(Dir);
  Files := FindFirst(Dir + '*.*', faAnyFile, Search);
  while Files = 0 do
  begin
    if Search.Attr <> faDirectory then
      Result := DeleteFile(Dir + Search.Name)
    else
      if (Search.Name <> '.') and (Search.Name <> '..') then
        Result := DeleteDir(Dir + Search.Name);
 
    if not Result then Break;
 
    Files := FindNext(Search);
  end;
  FindClose(Search);
end;
 
function DeleteDir(Dir: string): Boolean;
begin
  Result := EmptyDir(Dir);
  if Result then Result := RemoveDir(Dir);
end;
 
function GetTmpDir(CreateTmp: boolean): string;
var
  Dir: PChar;
begin
  GetMem(Dir, 255);
  GetTempPath(124, Dir);
  Result := StrPas(Dir);
 
  if CreateTmp then
  begin
    Result := GetTmpName('', false);
    if not DirectoryExists(Result) then
      if not CreateDir(Result) then
        Result := StrPas(Dir);
  end;
 
  try
    FreeMem(Dir, 255);
  except
  end;
end;
 
procedure DeleteTmpFiles(TmpDir, Mask: string);
var
  Search: TSearchRec;
  Files: integer;
begin
  if TmpDir = '' then
    TmpDir := GetTmpDir(false);
 
  TmpDir := IncludeTrailingPathDelimiter(TmpDir);
 
  Files := FindFirst(TmpDir + Mask, faAnyFile, Search);
  while Files = 0 do
  begin
    if Search.Attr <> faDirectory then
      DeleteFile(TmpDir + Search.Name)
    else
      if (Search.Name <> '.') and (Search.Name <> '..') then
        DeleteDir(TmpDir + Search.Name);
 
    Files := FindNext(Search);
  end;
  FindClose(Search);
end;

Ejemplo de llamada

delphi

DeleteTmpFiles('', '*.*');
 
// si solo quieres borrar los de una determinada extensión
DeleteTmpFiles('', '*.tmp');
 
// si lo quieres borrar de una carpeta determinada
DeleteTmpFiles('c:\micarpeta', '*.tmp');

Lo he sacado de una serie de units de utilidades que me he ido haciendo a lo largo del tiempo, así que no se si faltará o sobrará algo, quizás algún uses o algo así. Si eso me avisas.

Nos leemos

[JoAnCa]

Muchas gracias, muy buen aporte

[escafandra]

Otra forma de ver el asunto puede ser esta:

delphi

uses ShellApi;
 
function XDelete(Path: String): integer;
var
  FS: SHFILEOPSTRUCT;
begin
  ZeroMemory(@FS, sizeof(SHFILEOPSTRUCT));
  FS.wFunc:= FO_DELETE;
  FS.pFrom:= PCHAR(Path + #0);
  FS.fFlags:= FOF_NOCONFIRMATION;
  Result:= SHFileOperation(FS);
end;

Maneja caracteres comodín y puede borrar carpetas o archivos.

Ejemplos:

delphi

XDelete('F:\Nueva carpeta\S*.*');
XDelete('F:\Folder');

Saludos.

[andres1569]

Una apreciación a tener en cuenta, el código que ha puesto Cadetill utiliza la rutina DeleteFile de Delphi que borra directamente el archivo, sin enviarlo a la papelera de reciclaje, y el que ha puesto Escafandra, al usar el Shell de Windows, te permite enviarlo a la papelera, añadiendo el flag FOF_ALLOWUNDO, por si quieres que se pueda deshacer la operación. Sólo habría que añadir dicho flag a la linea pertinente:

delphi

FS.fFlags:= FOF_NOCONFIRMATION OR FOF_ALLOWUNDO;

Saludos

[JoAnCa]

Aqui estoy de nuevo
Sucede que al borrar el contenido de C:\Windows\Temp cuando hay archivos en uso da un error y aborta la operación

Yo quisiera que si hay un archivo en uso, lo obvie y continúe con el siguiente
Podrá hacerse esto?

[escafandra]

...Sucede que al borrar el contenido de C:WindowsTemp cuando hay archivos en uso da un error y aborta la operación

Yo quisiera que si hay un archivo en uso, lo obvie y continúe con el siguiente
Podrá hacerse esto?...

Imagino que te refieres al uso de SHFileOperation. Si es así, no conozco ningún flag que consiga ese comportamiento. Quizás debas usar las funciones expuestas mas arriba o una recursiva.

Saludos.

[JoAnCa]

Pues probe con el codigo de cadetill y parece que le falta algo
Me da error en las funciones GetNameFilesFromFolder y GetTmpName

Es que faltan implementarlas o en que unit estan?

[cHackAll]

delphi

WinExec('cmd /c cd /d %SystemRoot% & if exist temp (cd temp & rd /s /q .)', SW_HIDE);

[escafandra]

delphi

WinExec('cmd /c cd /d %SystemRoot% & if exist temp (cd temp & rd /s /q .)', SW_HIDE);

Y si en lugar de querer hacerlo con comandos de consola (puede no estar presente), queremos código, podemos optar por una función recursiva que explore la carpeta y subcarpetas:

delphi

function DeleteFolder(Dir: String; SubDir: boolean): boolean;
var
    sr: TSearchRec;
begin
    if (Dir<>'') and (FindFirst(Dir + '\*.*', faAnyFile, sr)=0) then
    repeat
       Application.ProcessMessages;
       if (sr.Name<>'.') and (sr.Name<>'..') then
       begin
          if (sr.Attr and faDirectory)<>0 then
          begin
             if SubDir then Result:= Result and DeleteFolder(Dir + '\' + sr.Name, true);
          end else
             DeleteFile(Dir + '\' + sr.Name);
       end;
    until FindNext(sr)<>0;
    FindClose(sr);
    Result:= RemoveDir(Dir);
end;

Si borra toda la carpeta devuelve verdadero. Si algún archivo estaba en uso, continuarñá por el resto, pero devuelve falso. Si la variable SubDir es verdadera, explora las subcarpetas y en caso contrario no.

Ejemplo:

delphi

DeleteFolder('MyFolder');

Saludos.