8 respuestas en este tema

[Desart]

Hola compañeros, como siempre rrecurro a vosotros ya que llevo un  día perdido por culpa de la siguiente funcion

delphi

[pre]function TFMenuPrincipal.AbrirForms(Unidad:TClass;NivelAcceso:TAction;ModoAbrir:Integer;NomModulo:string):Boo  lean;
//------------------------------------------------------------------------------
//****************************************[ Funcion para Abrir Los Form ]*******
// -----------------------------------------------------------------------------
//Unidad:         Nombre del Form a abrir   
//NivelAcceso:    Segun La Propiedad TAG de la action nos permite pasar o no
//ModoAbrir:      Abre el Form 1 En Showmodal 0 en Show
//NomModulo:      Nombre del modulo para mensajes de error
//------------------------------------------------------------------------------
var Modulo:TForm;
    Modf:string;
begin
   if CompruebaNivel(NivelAcceso.Tag,VarNivelUsusario)=true then
   begin
        try
          Modf:= Copy(Unidad.ClassName,2,Length(Unidad.ClassName));
          Modulo:=tform(Modf);
          if not Assigned(&Modulo) then
          begin
           Modulo:=TForm(Unidad).Create(nil);
            if ModoAbrir=1 then Modulo.ShowModal
                           else Modulo.show;
          end
          else
          begin
            if ModoAbrir=1 then Modulo.ShowModal
                           else Modulo.show;
          end;
          Result:=True;
        except
           ShowMessage('Se ha producido un error al intentar abrir el modulo [  '+NomModulo +'  ]'+#13
                       +#13+#13+#13+
                       'Si persiste el Error, por favor pongase en contacto con el servicio Técnico');
           Result:=False;
        end;
    end
    else
    begin
       ShowMessage('Debe se un usuario con nivel '+IntToStr(NivelAcceso.Tag)+' para entrar en esta opción');
       Result:=False;
    end;
end;[/pre]

  La llmada la hago de la siguiente manera

delphi

[pre]AbrirForms(TFFamilias,A_AFamilias,1,'Familias');[/pre]

La funcion Compruebanivel es
 

delphi

[pre]//------------------------------------------------------------------------------
//******************************************************[ CompruebaNivel ]******
//  16/02/2011  JLGT compara un nivel con otro si es igual o mayo devuelve true
//------------------------------------------------------------------------------
//  En pricipio para comprobar niveles de ususario segun el tag y un nivel dado
//------------------------------------------------------------------------------
//
//------------------------------------------------------------------------------
function CompruebaNivel(tag, nivel:Integer):Boolean;
begin
  if tag<=nivel then Result:=True
                else Result:=False;
end;[/pre]

  y el proyecto ya he probado con

delphi

  y el prollecto ya he probado con

y con

delphi

[pre]//  Application.CreateForm(TFFamilias, FFamilias);[/pre]

  El problema que detecto es que cunado pasa por la unidad de asignación  no entra, pasa por lo tanto al else y aún asi me da el error de las  lineas

delphi

[pre]      ShowMessage('Se ha producido un error al intentar abrir el modulo [  '+NomModulo +'  ]'+#13
                       +#13+#13+#13+
                       'Si persiste el Error, por favor pongase en contacto con el servicio Tecnico');[/pre]

Se supone que al leer la variable modulo, deberia desirme si esta asignada o no, pero ni idea, si pongo el código que uso normalmente funciona, os pongo el código

delphi

[pre]procedure TFMenuPrincipal.A_AFamiliasExecute(Sender: TObject);
//------------------------------------------------------------------------------
//*************************************************[ LLAMADA A FAMILIAS ]*******
//------------------------------------------------------------------------------
begin
   if CompruebaNivel(A_AFamilias.Tag,VarNivelUsusario)=true then
   begin
        try
          if not Assigned(FFamilias) then
          begin
           FFamilias:=TFFamilias.Create(nil);
            FFamilias.ShowModal;
          end else FFamilias.ShowModal;
        except
           ShowMessage('Se ha producido un error al intentar abrir el modulo [  Familias  ]'+#13
                       +#13+#13+#13+
                       'Si persiste el Error, por favor pongase en contacto con el servicio Técnico');
        end;
    end
    else
    begin
       ShowMessage('Debe se un usuario con nivel '+IntToStr(A_AFamilias.Tag)+' para entrar en esta opción');
    end;
end;[/pre]

[Wilson]

Amigo Desart, te propongo una técnica mucho mas limpia para lograr lo que quieres, parto de la base que lo que quieres es que, con base en la variable VarNivelUsuario, se pueda abrir o no cierto formulario, también veo que le pasas un parámetro de nombre NomMoudulo que no usas en la función, en fín en el ejemplo que te propongo lo conservo por si lo usas en otra parte.

Mi idea es diseñar una clase base de la  cual heredarás las otras, esta tiene una función de clase de tipo booleano, que toma como parámetros el nivel de usuario, el modo de abrir, el NomModulo(que no se para que lo usas, pero allí lo dejé) y por último parámetro el propietario del form. También tiene un campo protegido que debe asignarse  a la hora de crear el form con el nivel de acceso que permite ese determinado formulario, este posteriormente se comparará con el recibido en el parámetro de creación.

La clase base es así:

delphi

unit UBase;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs;
 
type
  TBase = class(TForm)
  protected
    FNivelAcceso: Integer;
  private
 
    { Private declarations }
  public
    class function Ejecutar(NivelAcceso, ModoAbrir: Integer; NomModulo: string;
      AOwner: TComponent = nil): Boolean;
 
  end;
 
  TBaseClass = class of TBase;
 
implementation
 
{$R *.dfm}
{ TBase }
 
class function TBase.Ejecutar(NivelAcceso, ModoAbrir: Integer;
  NomModulo: string; AOwner: TComponent = nil): Boolean;
begin
  Result := False;
  if AOwner = nil then
    AOwner := Application.MainForm;
  with Create(AOwner) do
  begin
    Result := (FNivelAcceso <= NivelAcceso);
    if not Result then
      Free
    else
    begin
      if ModoAbrir = 1 then
        ShowModal
      else
        Show
    end;
  end;
end;
 
end.

La siguiente es una clase heredada de TBase, le he puesto como nombre prueba y he asignado en su creación el nivel de acceso := 1;

delphi

unit UPrueba;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, UBase;
 
type
  TPrueba = class(TBase)
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;
 
implementation
 
{$R *.dfm}
 
procedure TPrueba.FormCreate(Sender: TObject);
begin
  inherited;
  FNivelAcceso := 1;
end;
 
end.

Finalmente en la unidad principal del ejemplo he implementado la función para llamar a cuantos descendientes de Tbase quieras y he llamado a la clase heredada TPrueba  con la  función  en la implementación del click del botón.

delphi

unit UMaim;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, UBase, ActnList;
 
type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    function AbrirForms(Unidad: TBaseClass; ModoAbrir: Integer;
      NomModulo: string): Boolean;
  public
    { Public declarations }
  end;
 
var
  Form1: TForm1;
  VarNivelusuario: Integer;
 
implementation
 
uses UPrueba;
{$R *.dfm}
 
function TForm1.AbrirForms(Unidad: TBaseClass; ModoAbrir: Integer;
  NomModulo: string): Boolean;
begin
  Result := Unidad.Ejecutar(VarNivelusuario, ModoAbrir, NomModulo);
end;
 
procedure TForm1.Button1Click(Sender: TObject);
begin
  if not AbrirForms(TPrueba, 1, '') then
    ShowMessage('Tu mensaje')
end;
 
procedure TForm1.FormCreate(Sender: TObject);
begin
  VarNivelusuario := 1;
end;
 
end.

Adjunto el ejemplo, espero te sea de ayuda, estaré atento a cualquier duda.

Saludos

[Wilson]

Si no te quieres complicar y solo quieres depurar tus funciones originales, quedarían así:

delphi

function CompruebaNivel(tag, nivel:Integer):Boolean;
begin
  result :=  tag <= nivel ;
end

delphi

  function TFMenuPrincipal.AbrirForms(Unidad: TClass; NivelAcceso: TAction;
    ModoAbrir: Integer; NomModulo: string): Boolean;
  // ------------------------------------------------------------------------------
  // ****************************************[ Funcion para Abrir Los Form ]*******
  // -----------------------------------------------------------------------------
  // Unidad:         Nombre del Form a abrir
  // NivelAcceso:    Segun La Propiedad TAG de la action nos permite pasar o no
  // ModoAbrir:      Abre el Form 1 En Showmodal 0 en Show
  // NomModulo:      Nombre del modulo para mensajes de error
  // ------------------------------------------------------------------------------
  var
    Modulo: TForm;
    Modf: string;
  begin
    result := False;
    if CompruebaNivel(NivelAcceso.Tag, VarNivelUsusario) then
    begin
      Modf := Copy(Unidad.ClassName, 2, Length(Unidad.ClassName));{El error podría estar aquí, si esta cadena no te devuelve el nombre correcto del form}
      Modulo := TForm(Modf);
      if not Assigned(Modulo) then
        Modulo := TForm(Unidad).Create(nil);
      try
        if ModoAbrir = 1 then
          Modulo.ShowModal
        else
          Modulo.show;
        result := true;
      except
        ShowMessage
          ('Se ha producido un error al intentar abrir el modulo [  '
            + NomModulo + '  ]' + #13 + #13 + #13 + #13 +
            'Si persiste el Error, por favor pongase en contacto con el servicio Técnico');
      end;
    end
    else
      ShowMessage('Debe se un usuario con nivel ' + IntToStr(NivelAcceso.Tag)
          + ' para entrar en esta opción');
  end;

Saludos.

[Desart]

gracias Wilson probare a partir de  mañana en el trabajo, en cuanto tenga un hueco y te digo.

[Sergio]

He visto en tu codigo que cuando salta un error, lo reportas con un texto fijo, en lugar de incluir dentro el mensaje de error original, que te podría aclarar mucho lo que ocurre.

delphi

        except
           ShowMessage('Se ha producido un error al intentar abrir el modulo [  Familias  ]'+#13
                       +#13+#13+e.messaje+#13+
                       'Si persiste el Error, por favor pongase en contacto con el servicio Técnico');
        end;

Ojo, lo de e.messaje es de memoria, igual era e.msg o algo del estilo

[Desart]

Gracias Sergio, pero el código que expuse y con el que hice las pruebas no es el que uso definitivamente, ya que uso mensajes de error, más completos, envió por email y faltan el campo para  claves de acceso según el Tag del Action seleccionado.

[luk2009]

Wilson  me salta este error al momento de compilar tu prueba.
[Error] prDesart.dpr(13): Undeclared identifier: 'MainFormOnTaskbar'

[Wilson]

Wilson  me salta este error al momento de compilar tu prueba.
[Error] prDesart.dpr(13): Undeclared identifier: 'MainFormOnTaskbar'

Comenta la línea (Application.MainFormOnTaskbar := True;) en el source del proyecto (Project > View Source). Es por la versión diferente de Delphi (yo estoy usando Delphi 2010).

Saludos

[egostar]

Wilson  me salta este error al momento de compilar tu prueba.
[Error] prDesart.dpr(13): Undeclared identifier: 'MainFormOnTaskbar'

Comenta la línea (Application.MainFormOnTaskbar := True;) en el source del proyecto (Project > View Source). Es por la versión diferente de Delphi (yo estoy usando Delphi 2010).

Saludos

Solo para comentar que ésta propiedad aparece a partir de Delphi2007 que hasta donde tengo conocimiento era para proporcionar un mejor soporte al tema Aero de Windows Vista, especialmente en los efectos que se producen cuando la aplicación se minimiza, se restaura o se cierra.

Salud OS